Script to grab web page

[drhowarddrfine]

I have a web application that will generate a web page and tuck it in a top secret location on the server. I need a Windows XP box to be able to run a program in the background to check to see if the page is there and fetch this page from the server and print it on the Windows printer. It should poll the server every minute or two.

XP Pro is available but would rather it run on XP Home. The page is located in an unpublished area of the server but does not need to be secured. The page would be html, text only for now, but I could tolerate plain text (for now).

If this was a 'nix box, I could use a shell script and wget and write a script in 10 lines to do this but none of that is installed on Windows. I reeeaaaallly don't want to have to install anything on the Windows box to do that so I'm wondering if there is an equivalent scripting method that would work with something in Windows and do what I want.

From googling a little, all I see is everything done in VB. I reeeaallly don't want to have to learn VB to do what should be a trivial task, and I'm concerned what I would have to download and install just to develop the code.

Can someone give me a clue, please?
Send me the code.
It's URGENT!!!
;)

[Curtis Rutland]

Working on it....
here's some things I've picked up:

code to download and display html from a website

url = "http://www.espn.com/main.html" 
set xmlhttp = CreateObject("MSXML2.ServerXMLHTTP") 
xmlhttp.open "GET", url, false 
xmlhttp.send ""
'this line pops up a dialog and shows the response from the website
WScript.Echo(xmlhttp.responseText)
 

I'll either edit this post with more or add more in new posts

[Nepomuk]

I guess this is a VB question then? Should I move it to the VB Forum?

Greetings,
Nepomuk

[Curtis Rutland]

Not VB, VBscript. I don't know where it would go....windows might be as good as any place.

[KevinADC]

write a DOS/batch file and run it using a task. Nothing to install but you will have to learn batch file scripting. I guess what you would have to figure out is how to fetch an internet document using the windows commands, possibilites are Ftp and telnet but maybe there is a wget type of command. Then use the Print command to print it.

[Curtis Rutland]

Well, here you go:

' VBScript source code
url = "http://www.google.com" 
path = "C:\dev\vbs\temp.txt"
set xmlhttp = CreateObject("MSXML2.ServerXMLHTTP") 
xmlhttp.open "GET", url, false 
xmlhttp.send ""
Set fso = CreateObject("Scripting.FileSystemObject")
Set txtfile = fso.OpenTextFile(path, 2, True)
txtfile.WriteLine(xmlhttp.responseText)
txtfile.Close
Set txtfile = nothing
set xmlhttp = nothing
Set oWS = WScript.CreateObject("WScript.Shell")
oWS.Run "NotePad.exe /p " + path
set oWS = nothing
set fso = nothing
 

Paste this into a text file named whatever.vbs. Then you should be able to double-click it and run it. Make sure to change the url and path.

I learned something new today...this was the first VBScript "program" I wrote. What this will do is get the HTML response from a website, create a text file, copy the response to file, then print it. It's pretty rough, and an experienced scripter could probably do worlds better, but it's a start.

[drhowarddrfine]

Thanks! I'll give it a try later today and let you know.

[Curtis Rutland]

One thing I forgot to mention is that script isn't conditional...i t will print the response, no matter what the response was. You might want to implement some if-then-else logic.

Also, you might want to add this line after line 6:

xmlhttp.waitForResponse()
 

If you do decide to do it conditionally, you might be interested in this article, which shows all the members and methods of the MSXML2.ServerXM LHTTP object.

[Curtis Rutland]

Here, slightly more refined:

'define vars
url = "http://bytes.com" 
path = "C:\dev\vbs\temp.txt"
'instantiate
Set xmlhttp = CreateObject("MSXML2.ServerXMLHTTP") 
Set fso = CreateObject("Scripting.FileSystemObject")
Set txtfile = fso.OpenTextFile(path, 2, True)
Set oWS = WScript.CreateObject("WScript.Shell")
'make request
xmlhttp.open "GET", url, false 
xmlhttp.send ""
'wait for response
xmlhttp.waitForResponse()
'if status is 200, then it's OK
if xmlhttp.status = 200 then
    txtfile.WriteLine(xmlhttp.responseText)
    txtfile.Close
    'enable this to print
    'oWS.Run "NotePad.exe /p " + path
    'enable this to just display
    oWS.Run "notepad.exe " + path    
else
    'popup bad response, or just omit to end
    WScript.Echo("bad response")
end if
'destroy objects.  I'm not sure this is necessary
Set txtfile = nothing
Set xmlhttp = nothing
Set oWS = nothing
Set fso = nothing

It's a bit longer because I've included comments.

Now, the program will check that the HTTP status is 200 before proceeding. Right now it will let you know it failed, but if you remove lines 22-24, you will get rid of the popup.

If you want it to print, uncomment 19 and comment 21.

Hope this helps.

[drhowarddrfine]

Thanks again. I'm floating around right now and that's why I haven't tried it yet.

[drhowarddrfine]

Success! That's just alright, man. I need to put this on my wife's desktop with the printer to test that part out but Notepad opens the file automatically as is.

The only thing I need to add would be a timer to make it fetch every minute or two. It would be nice if it could print a rendered html page but that can wait.

I'll look later but if you know where the docs are for the timer, I can look it up. Also, if you already know what I should look into for rendering the html for the printer, that would be just great. For now, plain text will be good enough.

Saved me some grief. Thanks again!