Modes for opening files !?

[yjulien]

Hello guys,

I have not figure out how to properly use the read/write mode for opening files +>, +<, +>>

I tried it but always got unpredicatable output.

I usually do this for standard read/write operation:

open(NEW_DATABASE, ">$file2");
open(DATABASE, "<$file1");
 
while (<DATABASE>) {
    $line = $_;
    chop $line;
 
    # Some operations on the line
 
    print NEW_DATABASE  "line\n";
} # end of while (<DATABASE>)
 
close(DATABASE);
close(NEW_DATABASE);
 
rename($file2, $file1);

Which work fine

Then I tried this code bellow. Not really to save 3 lines of code but to understand how to use the R/W mode...

open(DATABASE, "+>$file1");  
 
while (<DATABASE>) {
    $line = $_;
    chop $line;
 
    # Some operations on the line
 
    print  DATABASE  "line\n";
} # end of while (<DATABASE>)
 
close(DATABASE);

The output was very unpredicatable. It did not do what I wanted.

Is there a way to use these read/write mode to rewrite a single line in one pass or should I stick to the first design, which work?

Thanks,

Yves

PS: I did not forgot the tag this time ;-)

[numberwhun]

Ha ha, I noticed. Thank you! :)

For a good understanding of this topic, you may want to check out this tutorial. Hopefully it will help with your understanding.

Regards,

Jeff

[miller]

Well, to start off with I have a few thoughts/suggestions concerning your first method of translating the file:

1. use strict;
2. Use Lexical filehandles in three part form.
3. Add error checking to your file open operations
4. use chomp over chop since you're only wanting to remove return characters
5. chomp first before assigning to a variable, just makes things simpler

Anyway, to test out the code I created the following data file called foo.dat

This is just testing if we can translate some numbers.
 
It will taking any digits like 1 2 3 and perform some
operation on them.  The whole idea is that we are 
just able to test out modes of reading and writing.
It will ideally be a lossless translation that is also
it's own inverse.
 
More numbers like 45 and 79 for no particular reason.
 

I then came up with a translation we could do on the file. I decided on taking any digit and adding 5 to it and then modulus 10. This way all numbers will be changed back to their original value by doing the translation a second time.

use File::Copy qw(move);
 
use strict;
 
my $file = 'foo.dat';
 
my $newfile = $file . '.new';
 
open my $oh, '>', $newfile or die "Can't open file, $newfile: $!";
open my $ih, $file or die "Can't open file, $file, $!";
 
while (<$ih>) {
    chomp;
    my $line = $_;
 
    #       Some operations on the line
    $line =~ s/(\d)/($1 + 5) % 10/eg;
 
    print $oh "$line\n";
}      # end of while    while (<$ih>)
 
close $oh;
close $ih;
 
move($newfile, $file) or die "Can't move $newfile -> $file: $!";
 
1;
 
__END__

Finally, the whole point of this question was that you were curious about read/write mode for open. I'd actually discourage you from using that as it's only really useful for binary files. If you want to do read/write operations on a text file then check out Tie::File, as it will do all the hard work for you.

use Tie::File;
 
use strict;
 
my $file = 'foo.dat';
 
tie my @data, "Tie::File", $file, autochomp => 0
    or die "Can't open file, $file: $!";
 
for (@data) {
    #       Some operations on the line
    s{(\d)}{($1 + 5) % 10}eg;
}
 
untie @data;
 
1;
 
__END__

- Miller

[RonB]

while (<$ih>) {
    chomp;
    my $line = $_;
 

Is better written as:

while ( my $line = <$ih> ) {
    chomp $line;
 

And I'd also add the warnings pragma.

use warnings;

[yjulien]

Wooooow !

I think that I will stick with my original method, which is quite simple after all… and works :D

There is an American "say" I love and use all the time. It goes "if it ain't broken, don't fix it!"

Thanks guys,

Yves