help with extracting contents from HTML file

[priscilla]

Hi,

I am a beginer in perl programming , my task is to extract content with in form tags from a HTML file.I tried doing it using Regular expression but could not get the desired result as the HTML is not properly formatted in a webpage.

can you do it using HTML-parser or HTML-Tree builder?
I found out so many tutorials but i am not able to do it using those tutorials. can some one help regarding this?

Thank you in advance,
Priscilla.

[miller]

I would focus your efforts at HTML::Parser. There is an example for extracting the contents of a title tag directly in the pod documentation:

http://search.cpan.org/~gaas/HTML-Parser-3.55/Parser.pm#EXAMP LES

Even more importantly though, that is actually an example that they provide for decoding the form contents of a html page. It can be found in the /eg/ directory of the cpan dist for this module.

http://search.cpan.org/src/GAAS/HTML-Parser-3.55/eg/

You need to be able to do this on your own from this point though. If you have any specific trouble, feel free to ask, but you have plenty of specific resources at your disposal now to be able to solve this problem.

[priscilla]

thank you for your suggestion
I tried running this example in the link you have given
use HTML::Parser ();

sub start_handler
{
return if shift ne "title";
my $self = shift;
$self->handler(text => sub { print shift }, "dtext");
$self->handler(end => sub { shift->eof if shift eq "title"; },
"tagname,self") ;
}

my $p = HTML::Parser->new(api_versio n => 3);
$p->handler( start => \&start_handler , "tagname,self") ;
$p->parse_file(shi ft || die) || die $!;
print "\n";


its giving me a message " died at line 15"

Can you please tell me what shift here means?

I am unable to understand where this program is taking the input to get the content of the title elment

[miller]

The line that is dying for you is this:

$p->parse_file(shift || die) || die $!;
 

This is because this example is meant to be run as a script with a html file as a parameter.

IE:
./yourScript.pl yourHtmlFile.ht ml

The shift command in the above code is shifting the first element off the @ARGV array and parsing that file.

[miller]

Today is your lucky day. As a learning project I decided to try to get a working version of this code for you. The below script will accept an html file as a parameter, and then parses out the raw text of all forms found within that file. It saves them in the @forms array, which is then printed out at the end of the form.

You'll have to decode how this is done on your own, and of course adapt it to your own purposes since you did not more explicitly state what your end goal was. If you have some quick questions, I might answer them, but I will not be waste me time trying to teach you what this does. I was able to figure it out by simply going through all of the examples that they provided, and of course by reading the documentation. Although, I admit it could definitely use a little more verbose explaining.

http://search.cpan.org/src/GAAS/HTML-Parser-3.55/eg/
http://search.cpan.org/~gaas/HTML-Parser-3.55/Parser.pm

use HTML::Parser;
 
use strict;
 
my $file = shift || '20061101form.html';
 
my @forms = ();
 
sub start_form {
    my ($tagname, $self, $text) = @_;
 
    return if $tagname ne 'form';
 
    # Setup Handlers
    # - No longer look for start conditions, instead let the
    # default handler pick those up.
    $self->handler(start => undef);
    $self->handler(default => \&save_form, "text");
    $self->handler(end => \&end_form, "tagname,self,text");
 
    # Start New Form
    push @forms, '';
    save_form($text);
}
 
sub save_form {
    # Save all raw text in the current form.
    $forms[-1] .= shift;
}
 
sub end_form {
    my ($tagname, $self, $text) = @_;
 
    save_form($text);
 
    # End Processing, Wait for new Start Form
    if ($tagname eq 'form') {
        $self->handler(start => \&start_form, "tagname,self,text");
        $self->handler(default => undef);
        $self->handler(end => undef);
    }
}
 
 
my $p = HTML::Parser->new(api_version => 3);
$p->handler( start => \&start_form, "tagname,self,text");
$p->parse_file($file) || die $!;
 
# Prints all found forms.
print @forms;
 
1;
 
__END__
 

[priscilla]

thanks a lot