XSL to XML &lt; to < problem

[ajc308]

I am using C# to transform an XML document which actually outputs another XML document using XslCompiledTran sform and an XmlTextWriter.

The code I am using is:

XslCompiledTransform myXslTrans = new XslCompiledTransform();
myXslTrans.Load("sortByExtension.xsl");
XmlTextWriter myWriter = new XmlTextWriter("result.xml", null);
myXslTrans.Transform(tvXML, null, myWriter);
myWriter.Close();
 

The problem is, when I open the new XML document, "result.xml " I recieve an error because in my XSL I use the following to declare a node.

&lt;root name="PlanRepos itory"&gt;
&lt;/root&gt;

and the output in the XML file still has the &ltl and &gt; instead of the < and >.

Is there any setting I can change in the XmlTextWriter or any way to change this within the actual XSL Document?

Hope to find an answer soon, thanks!

[jkmyoung]

Is there any reason you can't use < and > in your xsl?

[ajc308]

It gives me an error because its expects the "<" to start an xsl or html element, much like using a " in some languages expects a string to be started. In other languages, there is usually an escape character, such as a /or \, but I can't seem to find anything that works in XSL.

[jkmyoung]

Aren't you declaring a node here?

<root name="PlanRepository">
</root>

Might help if we could see the rest of your xslt.

[ajc308]

This is my XSL:

 <xsl:template match="root">
  &amp;lt;root name="PlanRepository"&amp;gt;
  <xsl:apply-templates />
  &amp;lt;/root&amp;gt;
</xsl:template>
 
<xsl:template match="directory">
  &amp;lt;directory name="<xsl:value-of select="@name"/>"&amp;gt;
  <xsl:choose>
    <xsl:when test="@name = 'SAFE_Output'">
      <xsl:for-each select="file">
        <xsl:sort select="substring-after(substring-after(.,'.'),'.')" />
        &amp;lt;file&amp;gt;<xsl:value-of select="."/>&amp;lt;/file&amp;gt;
      </xsl:for-each>
    </xsl:when>
    <xsl:otherwise>
      <xsl:for-each select="file">
        <xsl:sort select="substring-after(.,'.')" />
        &amp;lt;file&amp;gt;<xsl:value-of select="."/>&amp;lt;/file&amp;gt;
      </xsl:for-each>
    </xsl:otherwise>
  </xsl:choose>
  <xsl:apply-templates select="directory"/>
  &amp;lt;/directory&amp;gt;
</xsl:template>

When I apply this to an HTML file using an XmlTextWriter the < and > show up. But when I apply it to an XML file using an XmlTextWriter, the &lt; and &gt; show up, causing it to be an invalid XML file.

[jkmyoung]

Does using this not work in both cases?

<xsl:template match="root">
    <root name="PlanRepository">
        <xsl:apply-templates/>
    </root>
</xsl:template>
<xsl:template match="directory">
    <directory>
        <xsl:copy-of select="@name"/>
        <xsl:choose>
            <xsl:when test="@name = 'SAFE_Output'">
                <xsl:for-each select="file">
                    <xsl:sort select="substring-after(substring-after(.,'.'),'.')"/>
                    <xsl:copy-of select="."/>
                </xsl:for-each>
            </xsl:when>
            <xsl:otherwise>
                <xsl:for-each select="file">
                    <xsl:sort select="substring-after(.,'.')"/>
                    <xsl:copy-of select="."/>
                </xsl:for-each>
            </xsl:otherwise>
        </xsl:choose>
        <xsl:apply-templates select="directory"/>
    </directory>
</xsl:template>

[ajc308]

Yes, in both cases, replacing the &lt; and &gt; with < and > causes errors.

This is the error I get:

 
System.Xml.Xsl.XslLoadException: XSLT compile error. ---> System.Xml.XmlException: '<', hexadecimal value 0x3C, is an invalid attribute character. Line 11, position 22.
 
 

[jkmyoung]

The validator is unfortunately incorrect then. Try using this, it uses <xsl:copy> instead.

<xsl:template match="root">    
    <xsl:copy>
        <xsl:attribute name="name">PlanRepository</xsl:attribute>
        <xsl:apply-templates/>
    </xsl:copy>
</xsl:template>
<xsl:template match="directory">
    <xsl:copy>
        <xsl:copy-of select="@name"/>
        <xsl:choose>
            <xsl:when test="@name = 'SAFE_Output'">
                <xsl:for-each select="file">
                    <xsl:sort select="substring-after(substring-after(.,'.'),'.')"/>
                    <xsl:copy-of select="."/>
                </xsl:for-each>
            </xsl:when>
            <xsl:otherwise>
                <xsl:for-each select="file">
                    <xsl:sort select="substring-after(.,'.')"/>
                    <xsl:copy-of select="."/>
                </xsl:for-each>
            </xsl:otherwise>
        </xsl:choose>
        <xsl:apply-templates select="directory"/>
    </xsl:copy>
</xsl:template>

? "invalid attribute character." ?
I didn't see the attribute.

[ajc308]

That worked! Thanks so much for going through this process with me and helping me figure it out. I really appreciate it.

Andrew