i want to send data from microsoft office excel 2007 to msflexgrid?

[ashaka]

hi all,

how can send data from microsoft office excel 2007 to msflexgrid?
example i want send data form A1-D1 in excel to msflexgrid.

help me from this code. thanks

[Guido Geurs]

EXCEL=
Copy the cells to the clipboard with command or macro in Excel:

Private Sub CommandButton1_Click()
    Range("a1: d3").Copy
End Sub

VB6 form=
Paste the clipboard in a hidden textbox (Text1) in VB6.
Split the Text1.text in lines in an array and add the lines in the MSflexgrid.

Private Sub Command1_Click()
Dim ARRAYLINES As Variant ' array with the lines
Dim ARRAYCELLS As Variant ' array with the cells of 1 line to count the cols needed
Dim LINES As Integer
   With Text1
      .Text = Clipboard.GetText
      ARRAYLINES = Split(.Text, vbNewLine)
   End With
   ARRAYCELLS = Split(ARRAYLINES(0), vbTab)
   With MSFlexGrid1
      .Cols = UBound(ARRAYCELLS) + 1
      For LINES = LBound(ARRAYLINES) To UBound(ARRAYLINES)
         .AddItem (ARRAYLINES(LINES))
      Next
   End With
End Sub
 

[ashaka]

thanks for your responded but there is problem when i click command button appears debug "method range of object_global failed" and when i click command1 appears error in "arraycells = split(arraylines (0), vbtab)". sorry, i am still new with vb. thanks for responded.

[Guido Geurs]

This is working for me: Office 2003 and vb6 SP6. (see attachment).
Added some clears and error traps.
AXCEL=

Private Sub CommandButton1_Click()
    Application.CutCopyMode = False
    Range("a1: d3").Copy
End Sub

VB6=

Private Sub Com_Clear_Click()
   Text1.Text = ""
End Sub
 
Private Sub Com_ClearGrid_Click()
   MSFlexGrid1.Rows = 1
End Sub
 
Private Sub Com_Paste_Click()
Dim ARRAYLINES As Variant ' array with the lines
Dim ARRAYCELLS As Variant ' array with the cells of 1 line to count the cols needed
Dim ARRAYLINESidx As Integer
   '§ put clipboard in textbox
   With Text1
      .Text = Clipboard.GetText
      If .Text = "" Then
         MsgBox "No data in clipboard"
         Exit Sub
      Else
         ARRAYLINES = Split(.Text, vbNewLine)
      End If
   End With
   '§ put textbox in grid
   If ARRAYLINES(0) = "" Then
      MsgBox "No data"
      Exit Sub
   Else
      ARRAYCELLS = Split(ARRAYLINES(0), vbTab)
      With MSFlexGrid1
         .Cols = UBound(ARRAYCELLS) + 1
         .Rows = 1 '§ keep header
         For ARRAYLINESidx = LBound(ARRAYLINES) To UBound(ARRAYLINES) - 1
            .AddItem (ARRAYLINES(ARRAYLINESidx))
         Next
      End With
   End If
   '§ clear array
   ReDim ARRAYLINES(0)
   ReDim ARRAYCELLS(0)
End Sub
 
Private Sub Com_Show_Click()
   Text1.Visible = True
End Sub
 
Private Sub Com_Hide_Click()
   Text1.Visible = False
End Sub