Save image in database

[johnemisylpaler]

can you teach me how to convert to binary the picture in a picture box in order to save and retrieve to database acces ? help me plsss

[Killer42]

can you teach me how to convert to binary the picture in a picture box in order to save and retrieve to database acces ?

Just have a look in the index of VB articles, at the top of the forum. There are a couple of entries there about storing and retrieving images in BLOBs, which are large binary database fields (Binary Large OBject, I believe).

[kentgorrell]

To store an image from a file use this -

Dim cn As ADODB.Connection, rs As ADODB.Recordset, SQL As String
Dim ps As New ADODB.Stream
ps.Type = adTypeBinary
 
Set cn = New ADODB.Connection
Set rs = New ADODB.Recordset
cn.CursorLocation = adUseServer
cn.Open "dsn=SQLDatabase"
 
SQL = "SELECT * FROM Student WHERE Student_ID = " & 1002
rs.Open SQL, cn, adOpenStatic, adLockOptimistic
'rs.addnew
ps.Open
ps.LoadFromFile "C:\My Documents\My Pictures\Student1002.JPG"
rs!Student_Photo = ps.Read
rs.Update

Note - this uses the streaming object so you need a reference to ADO (MS Data ActiveX Data Objects) 2.6 or greater
To read it back out to a file that you can then reference as the source for a picture control -

Dim cn As ADODB.Connection
Dim rs As ADODB.Recordset
Dim ps As New ADODB.Stream
Dim SQL As String
 
ps.Type = adTypeBinary
Set cn = New ADODB.Connection
Set rs = New ADODB.Recordset
 
cn.CursorLocation = adUseServer
cn.Open "dsn=SQL Database"
 
SQL = "SELECT * FROM Student WHERE Student_ID = " & Me.txtStudent_ID
rs.Open SQL, cn, adOpenStatic, adLockReadOnly
ps.Open
 
ps.Write rs!Student_Photo
ps.SaveToFile "C:\Student_Photo.JPG", adSaveCreateOverWrite