convert rows into columns

[pushkaraj]

hi,
I have a text file containing 2 rows of data points ....these data points are separated by 4 spaces in between and there are n number of such points where n can be 200-500.....i want a new text file to be created such that these 2 rows get converted to 2 columns( i need this file as a input file for gnuplot)......c an anybody please help me in writing the code in vb....i have used vba in autocad and am a complete newbie ............ple ase reply asap

eg.

1 2 3 4 5 6
7 8 9 10 11 12

to

1 7
2 8
3 9
4 10
5 11
6 12

[kadghar]

hi,
I have a text file containing 2 rows of data points ....these data points are separated by 4 spaces in between and there are n number of such points where n can be 200-500.....i want a new text file to be created such that these 2 rows get converted to 2 columns( i need this file as a input file for gnuplot)......c an anybody please help me in writing the code in vb....i have used vba in autocad and am a complete newbie ............ple ase reply asap

eg.

1 2 3 4 5 6
7 8 9 10 11 12

to

1 7
2 8
3 9
4 10
5 11
6 12

Sure, just use a cupple of arrays and you are done; something like:

'Put your text in TextBox1 and the new text willl appear in TextBox2
 
dim OurText() as string
dim nCols as integer
dim nRows as integer
dim i as integer
dim j as integer
dim k as long
dim Str1 as string
 
nCols = 200
nRows = 2
 
redim ourtext(1 to nrows, 1 to ncols)
 
i=1
j=1
k=1
str1 = textbox1.text
 
    do
        if  mid(str1,k,4)="    " then
            j = j +1
            k = k+4
        elseif mid(str1,k,1) = chr(10) then
            j=1
            i = i+1
            k=k+1
        else
             ourtext(i , j) = ourtext (i , j) & mid(str1,k,1)
             k = k+1
         end if
         if k >= len(str1) then exit do
     loop
 
str1 = ""
for i = 1 to ncols
    for j = 1 to nrows
        str1 = str1 & ourtext( i , j ) & "    "
    next
    str1 = str1 & chr(10)
next
 
textbox2.text=str1

Im afraid im at my job right now so i didnt have time to check it out carefully, it might have many mistakes, but i think the idea is clear.

If you have doubts with the file importation and exportation, im pretty sure that's a question that have been answered many times before, if not PM me and i'll send it back to you as soon as i can (thats not a warranty of speed).

Good Luck

[danp129]

Was working on this before Kadghar's reply so I'll go ahead and post what I got

Option Explicit
Private Sub Command1_Click()
    Dim sFileIn As String, sFileOut As String
    sFileIn = "c:\in.txt"
    sFileOut = "c:\out.txt"
    Call Convert2Columns(sFileIn, sFileOut)
End Sub
 
 
Private Function PrepLine(sIn As String) As String
    While InStr(1, sIn, "  "): sIn = Replace(sIn, "  ", " "): Wend
    PrepLine = sIn
End Function
 
 
Sub Convert2Columns(sfIn As String, sfOut As String)
 
    'Set how many lines should be converted to columns
    Const lngExpectedLines As Long = 2
 
    Dim FF_in As Long, FF_Out As Long
    Dim sLine As String
    Dim arLines(), arValues
    ReDim Preserve arLines(lngExpectedLines - 1, 0)
    Dim lngLine As Long
    Dim i As Long
 
    FF_in = FreeFile
 
    'open file and lock it so no other apps can write while we're using it
    Open sfIn For Input Lock Write As #FF_in
 
    'read each line of the file
    Do While Not EOF(FF_in)
 
        'set sLine variable to the line of text VB reads from file
        Line Input #FF_in, sLine
 
        If sLine <> "" Then
            If lngLine > lngExpectedLines - 1 Then
                MsgBox "More lines then expected, continuing with what's already parsed."
                Exit Do
            End If
 
            'remove extra spaces
            sLine = PrepLine(sLine)
 
            'create array of numbers
            arValues = Split(sLine)
 
            'add each number to arLines array
            For i = 0 To UBound(arValues)
                If i > UBound(arLines, 2) Then
                    ReDim Preserve arLines(lngExpectedLines - 1, i)
                End If
                arLines(lngLine, i) = arValues(i)
            Next 'i
 
            lngLine = lngLine + 1
        End If
    Loop
    Close #FF_in
 
    FF_Out = FreeFile
    Open sfOut For Output Lock Write As #FF_Out
 
    Dim x As Long
    Dim y As Long
    Dim sLineOut As String
    Dim sDelim As String
 
    For x = 0 To UBound(arLines, 2)
        For y = 0 To UBound(arLines)
            sLineOut = sLineOut & sDelim & arLines(y, x)
            sDelim = " "
        Next 'y
        Print #FF_in, sLineOut
        sLineOut = ""
        sDelim = ""
    Next 'x
    Close #FF_Out
End Sub

[pushkaraj]

thx guys....it was great help