Code Run Dynamically From Textbox in Vb.Net

[Navzsingh]

Hello Friends

I run dynamically code from text-box in vb.net
only one text-box txtoutput can be access in dynamically run code

while get input from another text-box compiler show error
"txtbox1 is not declared .it may be inaccessible due to its protection level"


Please help me how to resolve this error

Thanks in Advance

[SioSio]

Add textBox1 and txtBox2 to the array of objects representing the arguments passed to the method (UpdateText).
And add textBox1 and txtBox2 to the argument of subroutine UpdateText.

Public Sub runCode()
        ' Read code from file  
        '  Dim input = My.Computer.FileSystem.ReadAllText("Code1.txt")
        Dim input = TextBox3.Text
        ' Create "code" literal to pass to the compiler.  
        '  
        ' Notice the <% = input % > where the code read from the text file (Code.txt)   
        ' is inserted into the code fragment.  
        Dim code = <code>  
                       Imports System  
                       Imports System.Windows.Forms  
                       Public Class TempClass  
                           Public Sub UpdateText(ByVal txtOutput As TextBox, ByVal txtbox1 As TextBox, ByVal txtbox2 As TextBox)  
                               <%= input %>  
                           End Sub
                       End Class 
                   </code>
        ' Create the VB.NET compiler.  
        Dim vbProv = New VBCodeProvider()
            ' Create parameters to pass to the compiler.  
            Dim vbParams = New CompilerParameters()
            ' Add referenced assemblies.  
            vbParams.ReferencedAssemblies.Add("mscorlib.dll")
            vbParams.ReferencedAssemblies.Add("System.dll")
            vbParams.ReferencedAssemblies.Add("System.Windows.Forms.dll")
            vbParams.GenerateExecutable = False
            ' Ensure we generate an assembly in memory and not as a physical file.  
            vbParams.GenerateInMemory = True
            ' Compile the code and get the compiler results (contains errors, etc.)  
            Dim compResults = vbProv.CompileAssemblyFromSource(vbParams, code.Value)
            ' Check for compile errors  
            If compResults.Errors.Count > 0 Then
                ' Show each error.  
                For Each er In compResults.Errors
                    MessageBox.Show(er.ToString())
                Next
            Else
                ' Create instance of the temporary compiled class.  
                Dim obj As Object = compResults.CompiledAssembly.CreateInstance("TempClass")
            ' An array of object that represent the arguments to be passed to our method (UpdateText).  
            Dim args() As Object = {Me.txtoutput,Me.txtbox1,Me.txtbox2}
            ' Execute the method by passing the method name and arguments.  
            Dim t As Type = obj.GetType().InvokeMember("UpdateText", BindingFlags.InvokeMethod, Nothing, obj, args)
        End If
    End Sub