How can I change the name of file being downloaded

[coetzecc]

I'm new to HTML.

What is the HTML <a href> code/syntax to download a file to a different name than what is on the server?

I have many files stored on the server with cryptic file names, but I would like the files to be downloaded and saved with a "friendly name".

Is there a way to do this just by using the <a href> command?

[drhowarddrfine]

html cannot do this. In fact, it is not a function of the browser at all.

[JamieHowarth0]

Hi coetzecc,

If you are using ASP or PHP to serve up your file, you can use HTTP headers to add the following info:

Content-Disposition:attachment;filename:yourfile.ext

.

If you have no idea what PHP or ASP are then let us know and we might be able to help you further.

Best regards,

medicineworker

[coetzecc]

hi medicineworker,

Thanks for your reply.

Let me give you a bit more info.

I'm trying to extract files form WSUS. I found a utility on the web to do exactly that. Now I'm trying to improve it a little.

The page is written in ASP. It uses SQL to query a database and returns one or more results. I am then able to download the file but the filename is long and cryptic.

The search results include the long cryptic name plus the "friendly name".
I'd like to use that friendly for the downloads instead of the cryptic name.

Here is a excerpt of the ASP code:

Dim objConn, sqlString
 Set objConn = Server.CreateObject("ADODB.Connection")    
 objConn.Open "HotfixInfo"
 
 Dim rs
 sqlString = "SELECT FileName, MUURL, FileDigest " & _
            "FROM tbFile " & _
          "WHERE FileName like '%" & sSearch & "%' " & _
            "and FileName not like '%psf%' " & _
            "and FileName not like '%express%' " & _
          "ORDER BY FileName"
 
 set rs = objConn.Execute(sqlString)
 
 If Not rs.eof Then
  Do While Not rs.eof 
   Dim sFileName, sFileLocation, sFourtyChr, sFileDir,sFileDirFull, sFileFull, sFileWeb
     sFileName     = rs(0)
     sFileLocation = rs(1)
     sFourtyChr    = right(sFileLocation, 44)        
     sFileDir      = right(sFileLocation, 6)
     sFileDir      = left(sFileDir, 2)
     sFileDirFull  = sWSUSContentDir+sFileDir
     sFileFull     = sFileDirFull+"\"+sFourtyChr
     sFileWeb      = sWSUSContentSrv+sFileDir+"/"+sFourtyChr
 
     'Checks if the hotfix file exist
     If (fso.FileExists(sFileFull)) Then
       Dim sLink
       sLink = ("<a href="""+sFileWeb+""">"+sFileName+"</a>"
       %>
       <tr>
            <td colspan="2" class="content"><%= sLink %></td>
            <td colspan="2" class="content"><%= sFourtyChr %></td>
            <td colspan="2" class="content"><%= sFileDigest %></td>
       </tr>
       <%
     End If
     rs.MoveNext
   Loop
 Else
   %>
     <tr>
        <td colspan="6" class="content" align="center"><br>
            <h2>There are no files with the search string [<%= sSearch %>] available<br>
                Tip: Search with the KB article number.</h2><br>          
     </td>
     </tr>
   <%
 End If

I'm not sure where to insert you suggested code.
Any suggestions?

[drhowarddrfine]

Since this is an asp question, you would get more help on that board, where I can transfer this, but I need to know if it's ASP or ASP.NET.

[coetzecc]

Since this is an asp question, you would get more help on that board, where I can transfer this, but I need to know if it's ASP or ASP.NET.

Well WSUS setup requires ASP to be installed on the server. So I presume it's ASP.

[coetzecc]

Can anyone help me with this, please?

[JamieHowarth0]

Hi coetzecc,

I am unfortunately a bit busy today working on other projects but I will look into your query tomorrow morning and work out some kind of solution (which will involve an intermediary ASP file to parse the filenames from the WSUS database).

Best regards,

medicineworker

[coetzecc]

Hi coetzecc,

I am unfortunately a bit busy today working on other projects but I will look into your query tomorrow morning and work out some kind of solution (which will involve an intermediary ASP file to parse the filenames from the WSUS database).

Best regards,

medicineworker

Thanks medicineworker. (eagerly awaiting your reply)

[JamieHowarth0]

Hi coetzecc,

This is the code provision I came up with. Notice the comments (marked here in

'green

) which explains what I have done and how I have done it.

This is your current code:

Dim objConn, sqlString
Set objConn = Server.CreateObject("ADODB.Connection") 
objConn.Open "HotfixInfo"
 
Dim rs
sqlString = "SELECT FileName, MUURL, FileDigest " & _
"FROM tbFile " & _
"WHERE FileName like '%" & sSearch & "%' " & _
"and FileName not like '%psf%' " & _
"and FileName not like '%express%' " & _
"ORDER BY FileName"
 
set rs = objConn.Execute(sqlString)
 
If Not rs.eof Then
Do While Not rs.eof 
Dim sFileName, sFileLocation, sFourtyChr, sFileDir,sFileDirFull, sFileFull, sFileWeb
sFileName = rs(0)
sFileLocation = rs(1)
sFourtyChr = right(sFileLocation, 44) 
sFileDir = right(sFileLocation, 6)
sFileDir = left(sFileDir, 2)
sFileDirFull = sWSUSContentDir+sFileDir
sFileFull = sFileDirFull+"\\"+sFourtyChr
sFileWeb = sWSUSContentSrv+sFileDir+"/"+sFourtyChr
 
'Checks if the hotfix file exist
If (fso.FileExists(sFileFull)) Then
Dim sLink
'Added link to ASP file (code further down) which will parse your link value and rename the "attachment" as such into a friendly name
sLink = ("<a href=""filedownloader.asp?fn="+sFileWeb+"&ffn="+sFileName+""">"+sFileName+"</a>"
%>
<tr>
<td colspan="2" class="content"><%= sLink %></td>
<td colspan="2" class="content"><%= sFourtyChr %></td>
<td colspan="2" class="content"><%= sFileDigest %></td>
</tr>
<%
End If
rs.MoveNext
Loop
Else
%>
<tr>
<td colspan="6" class="content" align="center"><br>
<h2>There are no files with the search string [<%= sSearch %>] available<br>
Tip: Search with the KB article number.</h2><br> 
</td>
</tr>
<%
End If
 

Code for filedownloader.asp:

<%@Language="VBScript"%>
<%Option Explicit%>
<%Response.Buffer = True%>
<%
On Error Resume Next
Dim strPath
'Get web path to file from "fn" QueryString
strPath = CStr(Request.QueryString("fn"))
'-- do some basic error checking for the QueryString
If strPath = "" Then
Response.Clear
Response.Write("No file specified.")
Response.End
ElseIf InStr(strPath, "..") > 0 Then
Response.Clear
Response.Write("Illegal folder location.")
Response.End
ElseIf Len(strPath) > 1024 Then
Response.Clear
Response.Write("Folder path too long.")
Response.End
Else
Call DownloadFile(strPath)
End If
 
Private Sub DownloadFile(file)
'--declare variables
Dim strAbsFile
Dim strFileExtension
Dim objFSO
Dim objFile
Dim objStream
'-- set absolute file location
strAbsFile = Server.MapPath(file)
'-- create FSO object to check if file exists and get properties
Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
'-- check to see if the file exists
If objFSO.FileExists(strAbsFile) Then
Set objFile = objFSO.GetFile(strAbsFile)
'-- first clear the response, and then set the appropriate headers
Response.Clear
'-- the filename you give it will be the one that is shown
' to the users by default when they save
' med: added "friendly" file name capability (passed from "ffn" QueryString)
Response.AddHeader "Content-Disposition", "attachment; filename=" & Request.QueryString("ffn")
Response.AddHeader "Content-Length", objFile.Size
Response.ContentType = "application/octet-stream"
Set objStream = Server.CreateObject("ADODB.Stream")
objStream.Open
'-- set as binary
objStream.Type = 1
Response.CharSet = "UTF-8"
'-- load into the stream the file
objStream.LoadFromFile(strAbsFile)
'-- send the stream in the response
Response.BinaryWrite(objStream.Read)
objStream.Close
Set objStream = Nothing
Set objFile = Nothing
Else 'objFSO.FileExists(strAbsFile)
Response.Clear
Response.Write("No such file exists.")
End If
Set objFSO = Nothing
End Sub
%>
 

Note that this code was taken and modified from
http://www.xefteri.com/articles/show.cfm?id=7 and they deserve
the credit for this code - I simply modified it for your usage.

Hope it helps.

Best regards,
medicineworker

[coetzecc]

Thank you so much medicineworker.
I will try to implement your code and let you know if I get it to work.

[coetzecc]

IT WORKS!!!
Thanks a million medicineworker! You're the MAN!

[JamieHowarth0]

You're very welcome :-)
Any further questions on this subject, you are welcome to PM me anytime.

medicineworker