Replacing the default system message box

[Megalog]

Hey guys-

I've implemented this replacement MsgBox (that I found through the Access Developer blog) in the current database I'm working on. It works great for error handling, or anywhere that I'm calling on a message box in VBA. Basically all you do is install a few modules, one form, and replace 'MsgBox' with the new 'Box' function wherever it's to be used.

But it's not working for native system messages, and I'm wondering if any of you know a way to get Access to default to this new message box for these types of messages as well? The only reason I ask, is this replacement message box allows to copy and paste, or save the error message as a file. It's saving the users all the hassle of writing it down or making screenshots of the errors they sometimes get. I realize this probably isnt possible, but thought I'd throw it out here to let some of you flex your mental muscles.

Thanks!

Mega

[missinglinq]

I'm guessing that there's not going to be an easy way of doing this! I think the only way you're going to be able to do this is to use the Form_Error event, trap every trappable error you think is likely to be generated, and write custom error messages using the addin. Being able to copy and paste the error code is a very nice feature; I can understand you wanting to use it.

Linq ;0)>

[ADezii]

The only reason I ask, is this replacement message box allows to copy and paste, or save the error message as a file. It's saving the users all the hassle of writing it down or making screenshots of the errors they sometimes get.

Why not mimic this behavior entirely within Access?

1. Create a Public Sub-Routine
   

   Public Sub LogErrors(dteWhen As Date, lngErrNum As Long, strDesc As String, strUser As String, _
                        strSource As String, strLocation As String)
   Dim intNextFreeFile As Integer
    
   intNextFreeFile = FreeFile
    
   Open CurrentProject.Path & "\Errors.txt" For Append As #intNextFreeFile
    
   Print #intNextFreeFile, "Error on:"; Tab(20); dteWhen
   Print #intNextFreeFile, "Error Number:"; Tab(19); lngErrNum
   Print #intNextFreeFile, "Error Description:"; Tab(20); strDesc
   Print #intNextFreeFile, "Source of Error:"; Tab(20); strSource
   Print #intNextFreeFile, "Location of Error:"; Tab(20); strLocation
   Print #intNextFreeFile, "Current User:"; Tab(20); strUser
   Print #intNextFreeFile, "*************************************************************************"
    
   Close #intNextFreeFile
   End Sub

2. Place an additional, single line of code, in your Error Handlers that calls the Routine (Line Numbers 12, 11, and 12 below:
   

   Private Sub cmdTestErrorLog_Click()
   On Error GoTo Err_cmdTestErrorLog_Click
    
   'Test the Sub-Routine
   Err.Raise 16
    
   Exit_cmdTestErrorLog_Click:
     Exit Sub
    
   Err_cmdTestErrorLog_Click:
     MsgBox Err.Description, vbExclamation, "Error in cmdTestErrorLog_Click()"
     Call LogErrors(Now(), Err.Number, Err.Description, CurrentUser(), Err.Source, "cmdTestErrorLog_Click()")
       Resume Exit_cmdTestErrorLog_Click
   End Sub

   Private Sub cmdTestAnotherError_Click()
   On Error GoTo Err_cmdTestAnotherError_Click
    
   Err.Raise 37
    
   Exit_cmdTestAnotherError_Click:
       Exit Sub
    
   Err_cmdTestAnotherError_Click:
       MsgBox Err.Description
       Call LogErrors(Now(), Err.Number, Err.Description, CurrentUser(), Err.Source, "cmdTestAnotherError_Click()")
         Resume Exit_cmdTestAnotherError_Click
   End Sub

   Private Sub cboTestAgain_AfterUpdate()
   On Error GoTo Err_cboTestAgain_AfterUpdate
    
   'Test the Sub-Routine
   Err.Raise 97
    
   Exit_cboTestAgain_AfterUpdate:
     Exit Sub
    
   Err_cboTestAgain_AfterUpdate:
     MsgBox Err.Description, vbExclamation, "Error in cmdTestErrorLog_Click()"
     Call LogErrors(Now(), Err.Number, Err.Description, CurrentUser(), Err.Source, "cboTestAgain_AfterUpdate()")
       Resume Exit_cboTestAgain_AfterUpdate:
   End Sub

3. Errors.txt in your Current Project Path will not contain a complete History of every Error generated as long as the Routine is called. It will list exactly when the Error occurred, the Error Number and Description, the exact location of the Error, the Source of the Error, and the DB User for which the Error happened.
4. Sample OUTPUT listed below:
   

   Error on:          9/5/2008 7:43:17 PM 
   Error Number:      16 
   Error Description: Expression too complex
   Source of Error:   Northwind
   Location of Error: cmdTestErrorLog_Click()
   Current User:      Admin
   *************************************************************************
   Error on:          9/5/2008 7:45:45 PM 
   Error Number:      37 
   Error Description: Application-defined or object-defined error
   Source of Error:   Northwind
   Location of Error: cmdTestAnotherError_Click()
   Current User:      Admin
   *************************************************************************
   Error on:          9/5/2008 7:50:31 PM 
   Error Number:      97 
   Error Description: Can not call friend function on object which is not an instance of defining class
   Source of Error:   Northwind
   Location of Error: cboTestAgain_AfterUpdate()
   Current User:      Admin
   *************************************************************************

[Megalog]

Thanks for the replies guys, and the code too Adezii. I'm going to work that into this db today. This still doesnt trap the native messages that are occuring outside of the error handling that I already have in place, but it will help take care of the error reporting that some of the lazy users arent doing!