.BackStyle Missing

[NeoPa]

I have a project I'm working on where I want to disable editing on a form in certain circumstances. To avoid confusing the operator, I would like to change the appearance of the form so that is visually different between the two modes. A sort of visual clue if you like.

I developed the following code, but I find that this won't compile (to my surprise) :

Private Sub chkLocked_AfterUpdate()
    Dim ctl As Object     'Same problem if done As Control
 
    With Me
        .AllowEdits = (Not .chkLocked)
        For Each ctl In .Detail.Controls
            .BackStyle = .chkLocked
        Next ctl
    End With
End Sub

The error message is "Method or data member not found" and the .BackStyle on line #7 is highlighted (yellow).

Does anyone have any explanation? I have checked various of the controls (TextBox; Label; ComboBox; CheckBox) and only CheckBox doesn't have this property.

[FishVal]

Hi, NeoPa.

Your code invoke BackStyle property of current form.
Compiler knows that since it knows type of Me object.

[OldBirdman]

Why not change the form's .BackColor ? I use 3 colors 1)View, 2)Edit, 3)New/Adding to provide this visual clue. I use another set of 3 colors if form is filtered, to avoid frustration of not finding a record that is known to exist.

[NeoPa]

@FishVal
It seems kicking myself is a recurring theme today :(

At least it got me to look at why the Form object doesn't have such a property (I expected it should). It turns out that the various sections of the form (Header; Detail; Footer; etc) have the property (which shows the colour of the form if - as in my case - they are always set the same).

Thanks for being a reliable pair of eyes Fish :)

[NeoPa]

@OldBirdman
I'm giving this some careful consideration OB.

It's always harder to change direction midstream, but this idea seems to have such promise that I may take it up (or a version of it at least). With my character unfortunately, it pretty well means revisiting all my old code to bring those up to spec. I may get away without the third colour, but I also like your filtering idea.

I will have to go away and cogitate on it for a bit.

Thank you for this idea :)

[ADezii]

NeoPa makes a valuable point in Post #4, whereas you can programmaticall y set the BackColor Property of individual Form Sections, as in:

Forms!Orders.Section(acDetail).BackColor = QBColor(9)
Forms!Orders.Section(acHeader).BackColor = QBColor(10)
Forms!Orders.Section(acFooter).BackColor = QBColor(11)
Forms!Orders.Section(acPageHeader).BackColor = QBColor(12)
Forms!Orders.Section(acPageFooter).BackColor = QBColor(13)
 

[NeoPa]

Indeed ADezii, but unfortunately the .Section property, even though it appears to be an array or collection, does not seem to support the For ... Each construct.

Any tips or clues on that one would be helpful. My current code includes :

With Me
    lngColour = IIf(.chkLocked, conEditNo, conEditYes)
    .FormHeader.BackColor = lngColour
    .Detail.BackColor = lngColour
    .FormFooter.BackColor = lngColour
End With

This works fine, but itemising each section like this seems pretty messy to me :(

[ADezii]

@NeoPa

.Section property, even though it appears to be an array or collection, does not seem to support the For ... Each construct.

1. The For...Each Construct requires that you iterate through various Objects contained within their respective Collection, usually the plural of the Object's Name (Control...Cont rols, TableDef...Tabl eDefs, etc.). Unfortunately, to the best of my knowledge, a Sections Collection does not exist, ergo (you like that?), you cannot iterate a Collection that simply isn't there. Here is syntax, however, that you use:
   

   Dim sec As Section
    
   Set sec = Forms!Orders.Section(acDetail)
    
   sec.BackColor = QBColor(4)
    

2. You could also:
   

   On Error Resume Next
   Dim intSectionCounter As Integer
   Randomize
    
   For intSectionCounter = 0 To 4
     Me.Section(intSectionCounter).BackColor = QBColor(Int(Rnd * 16))
   Next

[FishVal]

Oh, ye. Access object model doesn't have any method or property which gives reference to "Sections" collection.
Sure it could be easily obtained with a simple reusable global function like the following.

Public Function FormSections(frm As Access.Form) As VBA.Collection
 
    Dim col As New VBA.Collection
 
    On Error Resume Next
 
    For i = 0 To 4             'sections with indexes 0 to 4 are available in form
        col.Add frm.Section(i), frm.Section(i).Name
    Next i
 
    Set FormSections = col
 
End Function
 

Then in form module:

.....
    For Each obj In FormSections(Me)
        .....
    Next
.....
 

The same function could set Section.Backcol or in accordance with additional argument(s) and/or global settings and/or predefined form properties.

Ultimately, if high level of tuneability is required, then it could be implemented as custom class or a part of existing (if existing) class extending Access.Form class functionality.

[ADezii]

@FishVal

1. Hell FishVal, I'm just confused on 1 point so kindly point me in the right direction. If I understand you correctly, the Public Function is returning a Collection of Form Section Objects, so couldn't Line #8 above simply be:
   

   col.Add frm.Section(i)

2. And any Reference to these Objects could be obtained via something similar to:
   

   Dim obj As Object
    
   For Each obj In FormSections(Me)
      Debug.Print obj.Name, obj.BackColor, obj.Height, ...
   Next

3. I thank you in advance for your explanation in this matter.
4. Very interesting and informative Comments, as is always the case from you.