How to know external application exit

[sheauyun]

Hi there,

I want to automate something with vb.net and display my output on message box or text box.

I came across another similar forum that matched what I wanted to do and try the method but it will not work for me:
http://bytes.com/topic/visual-basic-net/answers/721260-how-know-when-external-process-has-exited

I am not sure why rather than displaying my output, it close my form when the external program exited/closed.

Private WithEvents p As Process = New Process()
Private Sub RunProgram()
p.StartInfo.FileName = cm
p.StartInfo.UseShellExecute = False
p.StartInfo.CreateNoWindow = True
p.StartInfo.RedirectStandardOutput = True
p.StartInfo.RedirectStandardInput = True
p.StartInfo.RedirectStandardError = True
 
p.Start()
 
p.StandardInput.WriteLine("dir")
p.StandardInput.WriteLine("help")
End Sub()
 
Private Sub processExited(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles winscp.Exited
TextBox3.Text = "Console Output: " & vbCrLf & winscp.StandardOutput.ReadToEnd()
End Sub

Anyone please help.

Thanks.

[sheauyun]

No one can advice? I really need to know how to do this....

[IronRazer]

Hi,
I don`t know if this will help you or not but, here is a way to make the process wait until it has exited and then write the StandardOutput to a textbox.

Public Class Form1
 
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        StartMyProcess()
    End Sub
 
    Sub StartMyProcess()
        Dim proc As New Process
        proc.StartInfo.FileName = "cmd.exe"
        proc.StartInfo.WindowStyle = ProcessWindowStyle.Normal
        proc.StartInfo.CreateNoWindow = False
        proc.StartInfo.UseShellExecute = False
        proc.StartInfo.RedirectStandardOutput = True
        proc.StartInfo.RedirectStandardInput = True
        proc.Start()
 
        proc.StandardInput.WriteLine("echo This is a test to see the feedback from the cmd window")
        proc.StandardInput.WriteLine("exit") 'This line will make the cmd window close
 
        proc.WaitForExit() 'This makes the process wait untill the cmd window has exited
 
        Dim output() As String = proc.StandardOutput.ReadToEnd.Split(CChar(vbLf))
        For x As Integer = 3 To output.Length - 1
            If Not output(x).StartsWith("C:\") Then
                TextBox1.Text &= output(x).Trim(CChar(vbCr)) & vbNewLine
            End If
        Next
    End Sub
 
End Class
 

[sheauyun]

Thanks, but, I do not wanted to use the until exit method is causing the whole thing is hanging there - i still need to do something else in between.

@IronRazer

[IronRazer]

Hi,
If you want to display the StandardOutput in a messagebox you can do it like this without freezing the program thread. However you may want to filter the output string before displaying it.

Public Class Form1
    Dim proc As Process
 
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        StartMyProcess()
    End Sub
 
    Private Sub StartMyProcess()
        proc = New Process
        proc.StartInfo.FileName = "cmd.exe"
        proc.StartInfo.WindowStyle = ProcessWindowStyle.Normal
        proc.StartInfo.CreateNoWindow = False
        proc.StartInfo.UseShellExecute = False
        proc.StartInfo.RedirectStandardOutput = True
        proc.StartInfo.RedirectStandardInput = True
 
        'Added these two lines of code to enable the process to raise events
        proc.EnableRaisingEvents = True
        AddHandler proc.Exited, AddressOf ProcExited
 
        proc.Start()
        proc.StandardInput.WriteLine("echo This is a test to see the feedback from the cmd window")
        proc.StandardInput.WriteLine("exit") 'This line will make the cmd window close
    End Sub
 
    Private Sub ProcExited(ByVal sender As Object, ByVal e As System.EventArgs)
        MessageBox.Show(proc.StandardOutput.ReadToEnd)
    End Sub
End Class
 

If you want to display the StandardOutput in a TextBox which is a control it will cause a cross thread error unless you use a Delegate like this

Public Class Form1
    Dim proc As Process
 
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        StartMyProcess()
    End Sub
 
    Private Sub StartMyProcess()
        proc = New Process
        proc.StartInfo.FileName = "cmd.exe"
        proc.StartInfo.WindowStyle = ProcessWindowStyle.Normal
        proc.StartInfo.CreateNoWindow = False
        proc.StartInfo.UseShellExecute = False
        proc.StartInfo.RedirectStandardOutput = True
        proc.StartInfo.RedirectStandardInput = True
 
        'Added these two lines of code to enable the process to raise events
        proc.EnableRaisingEvents = True
        AddHandler proc.Exited, AddressOf ProcExited
 
        proc.Start()
        proc.StandardInput.WriteLine("echo This is a test to see the feedback from the cmd window")
        proc.StandardInput.WriteLine("exit") 'This line will make the cmd window close
    End Sub
 
    Private Sub ProcExited(ByVal sender As Object, ByVal e As System.EventArgs)
        DisplayMessage(proc.StandardOutput.ReadToEnd)
    End Sub
 
    Private Delegate Sub DisplayMessageDel(ByVal outputstring As String)
 
    Private Sub DisplayMessage(ByVal outputstring As String)
        If TextBox1.InvokeRequired Then
            Dim D As New DisplayMessageDel(AddressOf DisplayMessage)
            TextBox1.Invoke(D, outputstring)
            Exit Sub
        End If
        Dim output() As String = outputstring.Split(CChar(vbLf))
        For x As Integer = 3 To output.Length - 1
            If Not output(x).StartsWith("C:\") Then
                TextBox1.Text &= output(x).Trim(CChar(vbCr)) & vbNewLine
            End If
        Next
    End Sub
End Class
 

Hope this helps. :)

[sheauyun]

Razor, Thank you so much. You gave me exactly what I need! Thanks! :)