How to Declare a Default Property in a Class Module

[ADezii]

The motivation for this Tip was a question asked by one of our Resident Experts, FishVal. The question was: How to Declare Default Method/Property in a Class Module? My response to the question was inadequate to say the least, but I was determined to come up with the correct answer, especially since my primary background is Visual Basic, and I knew that there was an answer. Well, I did come up with an answer and I decided to incorporate it into this week's Tip. I have created a Link to the initial question and response for your reference, after which I'll elaborate on the solution:
Declare a Default Method/Property in a Class Module

VBA does not give you a simple mechanism by which you can specify a Property to be the Default. VBA does, however, support Default Properties but you'll simply have to jump through several hoops to get there. The following steps will describe exactly how to create a Default Property in your Classes:

1. Create the following simple Class named MyClass. MyClass will consist of just 2 Properties: Value (Default) and MyName. It does not contain any Methods.
   
   

   Private pValue As Long
   Private pMyName As String
    
   Property Get Value() As Variant 
     Value = pValue
   End Property
    
   Property Let Value(ByVal vNewValue As Variant) 
     pValue = vNewValue
   End Property
    
   Property Get MyName() As Variant 
     MyName = pMyName
   End Property
    
   Property Let MyName(ByVal vNewName As Variant) 
     pMyName = vNewName
   End Property

2. Save your Class Module (MyClass) after creating it.
3. From the File menu, choose Remove MyClass.
4. When prompted to Export the File First, choose Yes and save the Module.
5. Open the exported file (*.cls) in Notepad, or any Text Editor.
6. In Notepad, find your Property Get Procedure, in this case Value. Add the following line of code on a blank line immediately following the Property Get Statement.
   
   

   Attribute Value.VB_UserMemId = 0

7. The Property Get Procedure should now look like the following:
   
   

   Property Get Value() As Variant
     Attribute Value.VB_UserMemId = 0 
     Value = pValue
    End Property

8. Save the file in Notepad, then exit.
9. In VBA choose Import File and select the file you just modified (MyClass.cls).. You will not see the 'Attribute' Statement in the VBA Editor. The Editor reads and processes Attribute Statements, but does not display them, nor does it allow them to be entered in the Editor.
10. The following code block will now work where it previously would not have because Value was not the Default Property of the MyClass Object.
    
    

    'Declare a Variable to refer to the New Instance of
    'MyClass (a MyClass Object) 
    Dim clsMyClass As MyClass
     
    'Instantiate the Class 
    Set clsMyClass = New MyClass
     
    'Can do this because Value is now the Default Property 
    clsMyClass = 9999
     
    'Must use standard syntax since MyName is not a Default Property
    clsMyClass.MyName = "Fred Flintstone"
     
    MsgBox clsMyClass           'returns 9999
    MsgBox clsMyClass.MyName    'returns Fred Flintstone

11. The above code has been tested and is fully operational. To the best of my knowledge, it requires Access 2000 and above to work.
12. Should you have any questions feel free to ask.