HTA CPU Usage monitor - Microsoft Windows

115 100+

This is an HTML application that allows you to monitor the CPU Usage (as seen in task manager) for any one task either on the local computer or a remote computer using vbscript. It then alerts you when that process has gone idle. I put it together this morning because I was tired of starting a program on remote computer, and continuously reconnect to see if the job was finished. This code could easily be modified into a full fledged “Task Manager” for a remote computer..in fact..i think I might just do that. I will, and I will make a step by step article for it. Because I’m bored.

(You need a username and password for the remote computer)
(copy this code into a blank text document and save it with the extension ".hta")

Expand|Select|Wrap|Line Numbers

 <!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.0 Transitional//EN">

<html>

<head>

<title>Teh Waiter</title>

<HTA:APPLICATION id="prjIS" MINIMIZEBUTTON="yes" MAXIMIZEBUTTON="no" INNERBORDER="yes" BORDER="thin" SINGLEINSTANCE="yes" APPLICATIONNAME="Waiting Script">

<SCRIPT language="VBScript">

<!--
 
Sub Window_onLoad
 
Dim objWMISer, objItem

Dim colItems

Dim intLeft, intTop
 
Set objWMISer = GetObject("winmgmts:\\.\root\cimv2")

Set colItems = objWMISer.ExecQuery("Select * From Win32_DesktopMonitor")
 
'Set Window Size

For Each objItem in colItems

intWidth = objItem.ScreenWidth

intHeight = objItem.ScreenHeight

Exit For 

Next
 
intLeft = (intWidth - 385) / 2

intTop = (intHeight - 230) / 2

window.resizeTo 385,230

window.MoveTo intLeft, intTop 

End Sub
 
Function IsValidIp(sIpAddress)'Well..is it?
 
Dim aTmp

IsValidIp = False

aTmp = split(sIpAddress,".")
 
If UBound(aTmp) <> 3 Then Exit Function

For Each field In aTmp

If field > 255 Then Exit Function

Next

IsValidIp = True
 
End Function
 
'This was complicated..

'Sets cursor to end of text when focus is gained

Sub txtIP_OnFocus 

Set it = document.Selection.CreateRange()

it.moveStart "Character", 15

it.select
 
End Sub
 
Dim sObjectPath, strIPAddress, strUser, strPass, strName

Dim blnIdle, blnIsDone, blnFocus

Dim intWait, intTime

Dim wmi_service, perf_instance1

Dim N1, N2, D1, D2

Dim TimerID, TimerWork
 
Sub btnDoIt_OnClick

document.getElementById("btnDoIt").disabled = "disabled"
 
strIPAddress = document.getElementById("txtIP").value

strUser = "remoteuser"

strPass = "secretpassword"

strName = document.getElementById("txtName").value

intTime = CInt(document.getElementById("txtTime").value)
 
blnIsDone = false

blnIdle = false
 
intWait = 0
 
If trim(strName) = "" Then

msgbox "Enter a process to wait for!"

document.getElementById("btnDoIt").disabled = ""

Exit Sub

End If
 
sObjectPath = "Win32_PerfRawData_PerfProc_Process.Name=" & chr(34) & strName & chr(34)
 
If strIPAddress = "." Then

Set wmi_service = GetObject("winmgmts:{impersonationlevel=impersonate}!\\.\root\cimv2")

Else 

If IsValidIp(strIPAddress) Then

Set objSWbemLocator = CreateObject("WbemScripting.SWbemLocator")

Set wmi_service = objSWbemLocator.ConnectServer(strIPAddress, "root\cimv2", strUser, strPass)

Else

msgbox "Invalid Ip Address"

document.getElementById("btnDoIt").disabled = ""

Exit Sub

End If

End If 
 
Set perf_instance1 = wmi_service.get( sObjectPath )
 
N1 = perf_instance1.PercentProcessorTime

D1 = perf_instance1.TimeStamp_Sys100NS
 
TimerID = window.setInterval("TehLoop", 1000)

TimerWork = window.setInterval("StillWorking", 400)
 
If strIPAddress <> "." Then 

document.getElementById("divTitle").innerText = "Waiting for " & strName & " on " & strIPAddress

Else

document.getElementById("divTitle").innerText = "Waiting for " & strName

End If
 
document.getElementById("divMain").style.display = "none"

document.getElementById("divStatus").style.display = ""

document.title = "Waiting.."

End Sub
 
Sub TehLoop

Dim perf_instance2
 
Set perf_instance2 = wmi_service.get( sObjectPath )

N2 = perf_instance2.PercentProcessorTime

D2 = perf_instance2.TimeStamp_Sys100NS
 
'Found This formula somewhere on the interwebs

' CounterType - PERF_100NSEC_TIMER

' Formula = ((N2 - N1) / (D2 - D1)) x 100
 
If ( 0 = (D2-D1) ) Then

msgbox "process " & strName & " was not found"

blnIsDone = true

Else

PercentProcessorTime = ((N2 - N1) / (D2 - D1)) * 100
 
document.getElementById("divUsage").innerText = "Usage: " & PercentProcessorTime
 
If PercentProcessorTime = 0 Then

intWait = intWait + 1

Progress 

If intWait >= intTime Then

blnIsDone = true

blnIdle = true

End If

Else

Progress

intWait = 0

End If
 
End If
 
N1 = N2

D1 = D2
 
If blnIsDone Then

btnCancel_OnClick

End If

End Sub
 
Sub Progress

document.getElementById("divIdle").innerText = "Idle Seconds: " & intWait & " of " & intTime
 
If blnFocus Then

document.title = "Waiting.."

Else

document.title = strName & " - " & intWait & " of " & intTime & " seconds"

End If
 
End Sub
 
Sub StillWorking
 
Set div = document.getElementById("divWait")
 
If div.innerText <> "Waiting...." Then

div.innerText = div.innerText & "."

Else

div.innerText = "Waiting."

End If
 
End Sub
 
Sub btnCancel_OnClick

Set wmi_service = nothing
 
If blnIdle Then

document.title = strName & " is idle"

Set objWC = window.document.getElementById("sndWC")

If Not objWC Is Nothing Then

objWC.src = "WorkCom.wav"

End If
 
msgbox strName & " is idle"

End If 
 
window.clearInterval(TimerID)

window.clearInterval(TimerWork)

document.getElementById("btnDoIt").disabled = ""
 
document.getElementById("divMain").style.display = ""

document.getElementById("divStatus").style.display = "none"

document.title = "Teh Waiter"

End Sub
 
Sub FocusOut

blnFocus = False

End Sub
 
Sub FocusIn

blnFocus = True

End Sub

-->

</SCRIPT>

</head>

<body onfocusin="FocusIn" onfocusout="FocusOut" bgcolor="black">

<form id="frmExecute">

<center><font face="Comic Sans MS" color="blue">

<bgsound src="" id="sndWC" />

<div id="divMain">

IP Address ("." for local):

<br>

<INPUT id="txtIP" tabIndex="1" type="text" maxLength="15" size="13" value="." name="txtIP" />

<br>

Process name (exp. "explorer"):

<br>

<INPUT id="txtName" tabIndex="2" type="text" size="13" value="explorer" name="txtName" />

<br>

Idle Time in seconds:

<br>

<INPUT id="txtTime" tabIndex="3" type="text" size="13" value="4" name="txtTime" />

<br>

<INPUT id="btnDoIt" tabIndex="4" type="button" value="Start" name="btnDoIt" />

<br>

</div>
 
<div id="divStatus" style="display: none">

<INPUT id="btnCancel" tabIndex="4" type="button" value="Stop" name="btnCancel" />

<br><br>

<div id="divTitle"></div>

<div id="divUsage">Usage: </div>

<div id="divIdle">Idle Seconds: </div>

<div id="divWait" style="color: red">Waiting...</div>

</div>

</font></center>

</form>

</body>

</html>

Jan 3 '08 #1

Subscribe Post Reply

7997

ShadowLocke

115

100+

Ah, theres an error when you copy and paste from this. On line 86 somehow got an extra space or two after "root"

it should be

Expand|Select|Wrap|Line Numbers

 Set wmi_service = GetObject("winmgmts:{impersonationlevel=impersonate}!\\.\root\cimv2")
 

with no spaces after "root"

Apr 7 '08 #2

Similar topics

UDB V8 FP9a "log data" monitor elements

by: Phil Sherman | last post by:

What is the relationship between the snapshot elements: Log pages written Number write log IOs Number partial page log IOs There doesn't appear to be any information in my PDF System monitor...

DB2 Database

Very high memory usage?

by: Brad Markisohn | last post by:

I want to be notified when a PnP device is added or removed. To accomplish this task, I added two occurrences of a System.Management.ManagementEventWatcher. I've included a snippet of code that...

Visual Basic .NET

how to get CPU usage of inidividual process in VB.NET

by: Shan Yong | last post by:

I am trying to monitor the CPU usage of a particualar process in VB.NET, and the best that I can come up with is get the TotalProcessor time using the System.Diagnostic.Process object. Is there...

Visual Basic .NET

How to track memory usage?

by: Adrian | last post by:

Hi I have a JS program that runs localy (under IE6 only) on a PC but it has a memory leak (probably the known MS one!) What applications are there that I could use to look at the memory usage of...

Javascript

Thread - CPU usage

by: Michael Moreno | last post by:

Hello, I have a C# server which has 4 worker threads running all the time. When I let the server runs for several hours, for some reasons the CPU usage of the application will shoot to 100% and...

C# / C Sharp

threading - Monitor.Wait/Pulse

by: Perecli Manole | last post by:

I am having some strange thread synchronization problems that require me to better understand the intricacies of Monitor.Wait/Pulse. I have 3 threads. Thread 1 does a Monitor.Wait in a SyncLock...

.NET Framework

internet usage monitor

by: Reny | last post by:

Hi, I want to develop an internet usage monitor program in vb.net and monitor the time the user spend on internet etc. Can any one give me a clue on how to code it? Reny

Visual Basic .NET

using VBA to monitor Excel usage

by: mrpincer21 | last post by:

Could anyone help me by telling me how to create an excel document that monitors usage of many others by using visual basic program? I currently produce excel reports for my company but need to...

Visual Basic 4 / 5 / 6

How to monitor CPU and RAM usage using Python

by: soulofstar | last post by:

I want to monitor the CPU and RAM usage using Python, Now, I know how to monitor RAM usage by Python from ctypes import * from ctypes.wintypes import * class MEMORYSTATUS(Structure): ...

Python

How to turn on java script in a villaon keypad mobile phone

by: Charles Arthur | last post by:

How do i turn on java script on a villaon, callus and itel keypad mobile phone

Java

Migrating Website to Cloud - Emmanuel Katto

by: emmanuelkatto | last post by:

Hi All, I am Emmanuel katto from Uganda. I want to ask what challenges you've faced while migrating a website to cloud. Please let me know. Thanks! Emmanuel

General

Navigating the Data Structures and Algorithms (DSA)

by: BarryA | last post by:

What are the essential steps and strategies outlined in the Data Structures and Algorithms (DSA) roadmap for aspiring data scientists? How can individuals effectively utilize this roadmap to progress...

Algorithms / Advanced Math

Looking to do Android software development, any suggestions? Is flutter better?

by: nemocccc | last post by:

hello, everyone, I want to develop a software for my android phone for daily needs, any suggestions?

General

How to build RAID in BIOS?

by: Hystou | last post by:

There are some requirements for setting up RAID: 1. The motherboard and BIOS support RAID configuration. 2. The motherboard has 2 or more available SATA protocol SSD/HDD slots (including MSATA, M.2...

Computer Hardware

What is ONU?

by: marktang | last post by:

ONU (Optical Network Unit) is one of the key components for providing high-speed Internet services. Its primary function is to act as an endpoint device located at the user's premises. However,...

General

Changing the language in Windows 10

by: Hystou | last post by:

Most computers default to English, but sometimes we require a different language, especially when relocating. Forgot to request a specific language before your computer shipped? No problem! You can...

Windows Server

Maximizing Business Potential: The Nexus of Website Design and Digital Marketing

by: jinu1996 | last post by:

In today's digital age, having a compelling online presence is paramount for businesses aiming to thrive in a competitive landscape. At the heart of this digital strategy lies an intricately woven...

Online Marketing

The easy way to turn off automatic updates for Windows 10/11

by: Hystou | last post by:

Overview: Windows 11 and 10 have less user interface control over operating system update behaviour than previous versions of Windows. In Windows 11 and 10, there is no way to turn off the Windows...

Windows Server