How do you save ListBox Text to FIle

[VincentWiebe]

Ok well this is the script that i am using to save a normal textbox.

Private Sub CmdAdd_Click()
Dim strNameScript As String
 strNameScript = "RuneScapePalScript" + FrmScripts2.TxtScriptName.Text
 Open strNameScript For Output As #1
 Print #1, FrmScripts2.TxtScripty.Text
 Close #1
ErrHandler:
End Sub

But i am having a lot of trouble finding a way that i can save ListBoxes... i can manage to get it to save one line from the list box but not all of the lines. If anyone can help me out here i would greatly appreciateit.. Thanks.

[hariharanmca]

Ok well this is the script that i am using to save a normal textbox.

Private Sub CmdAdd_Click()
Dim strNameScript As String
 strNameScript = "RuneScapePalScript" + FrmScripts2.TxtScriptName.Text
 Open strNameScript For Output As #1
 Print #1, FrmScripts2.TxtScripty.Text
 Close #1
ErrHandler:
End Sub

But i am having a lot of trouble finding a way that i can save ListBoxes... i can manage to get it to save one line from the list box but not all of the lines. If anyone can help me out here i would greatly appreciateit.. Thanks.

Private Sub CmdAdd_Click()
    Dim strNameScript As String
    strNameScript = "RuneScapePalScript" + FrmScripts2.TxtScriptName.Text
    For i = 1 To <ListBox.ListCount> ' i am not sure about get listbox list count (<ListBox.ListCount>)
        Open strNameScript For Output As #1
            Print #1, FrmScripts2.ListBox.List(i)
        Close #1
    Next i
ErrHandler:
    <E.Handler ode>
End Sub

Try the above code. I think this will help you

[VincentWiebe]

Im Still having trouble getting it to work i made myself a little program just to test everything, and heres the code from it,, it works fine. but when i open up the saved file in notepad It does not show anything that should of been saved

heres the script

Private Sub Command1_Click()
 List1.AddItem (Text1.Text)
    Dim strNameScript As String
    On Error GoTo ErrHandler
    strNameScript = "Test"
    For i = 1 To List1.ListCount
        Open strNameScript For Output As #1
            Print #1, List1.List(i)
        Close #1
    Next i
ErrHandler:
End Sub

[fplesco]

Im Still having trouble getting it to work i made myself a little program just to test everything, and heres the code from it,, it works fine. but when i open up the saved file in notepad It does not show anything that should of been saved

heres the script

Private Sub Command1_Click()
 List1.AddItem (Text1.Text)
    Dim strNameScript As String
    On Error GoTo ErrHandler
    strNameScript = "Test"
    For i = 1 To List1.ListCount
        Open strNameScript For Output As #1
            Print #1, List1.List(i)
        Close #1
    Next i
ErrHandler:
End Sub

Try this VincentWiebe -

Private Sub Command1_Click()
    List1.AddItem ("1")
    List1.AddItem ("2")
    Dim strNameScript As String
    On Error GoTo ErrHandler
    strNameScript = "Test"
    For i = 0 To List1.ListCount - 1
        Open strNameScript For Output As #1
            Print #1, List1.List(i)
        Close #1
    Next i
ErrHandler:
End Sub

You might have confused with the array index. It suppose to start at 0 and it happens that you have only 1 test data. Maybe that explains why your file doesnt have text on it.

Godspeed!

[fplesco]

Hello there VincentWiebe -

Please disregard my first post. Try this instead.

I put the opening of the file
Open strNameScript For Output As #1
and closing of the file
Close #1
outside the For statement block.

Private Sub Command1_Click()
    List1.AddItem ("1")
    List1.AddItem ("2")
    Dim strNameScript As String
    On Error GoTo ErrHandler
    strNameScript = "Test"
    Open strNameScript For Output As #1
    For i = 0 To List1.ListCount - 1    
           Print #1, List1.List(i)
    Next i
    Close #1
ErrHandler:
End Sub

You might have confused with the array index. It suppose to start at 0 and it happens that you have only 1 test data. Maybe that explains why your file doesnt have text on it.

Godspeed!

[Killer42]

The main problem was that opening and closing the file each time around the loop caused the data to be overwritten each time. Of course, the loop does need to start and finish at the right values.

[hariharanmca]

The main problem was that opening and closing the file each time around the loop caused the data to be overwritten each time. Of course, the loop does need to start and finish at the right values.

yha and sorry i missed that(opening and closing the file each time around the loop).

[VincentWiebe]

Alright Thanks a lot guys

It Works prefectly, but before i get all confused as to make it load i was wondering if there is a certain way i have to do that as well?

Thanks

[Killer42]

Not sure what you mean about loading.

However, here's a simple Sub you can place in a code module and call from anywhere...

Public Sub SaveListBox(ByVal Src As ListBox, ByVal FileName As String)
  Dim FileNum As Long, I As Long
  FileNum = FreeFile
  Open FileName For Output As #FileNum
  With Src
    For I = 0 To .ListCount - 1
      Print #FileNum, .List(I)
    Next
  End With
  Close #FileNum
End Sub

[fplesco]

Alright Thanks a lot guys

It Works prefectly, but before i get all confused as to make it load i was wondering if there is a certain way i have to do that as well?

Thanks

If you need to OPEN and CLOSE the file several times in the loop and you want content of the FILE not overwritten, you can use APPEND.

[VincentWiebe]

Sorry by load i mean, i want it to put the text, from the file i saved previously, into the list box.

Herses the script i use to load/open, a file and put the text that is in the file into a textbox

Private Sub Form_Load()
Dim strNamePassword As String, strFilePassword As String, strTempPassword As String
On Error GoTo ErrHandler
strNamePassword = "RuneScapePalPassword"
Open strNamePassword For Input As #1
strFilePassword = ""
Do Until EOF(1)
Line Input #1, strTempPassword
strFilePassword = strFilePassword & strTempPassword & vbCrLf
Loop
TxtPassHide.Text = strFilePassword
Close #1
ErrHandler:
If TxtPassHide.Text = "" Then
FrmLogin.Hide
FrmUserData.Show
End If
End Sub

I'm just not sure how to do this with a listbox seeing how there are multiple lines of text.

[Killer42]

Just do an AddItem for each line. And in this case, skip the vbCrLf.

[VincentWiebe]

I tried a bunch of different things but i cant get it to work.

[VincentWiebe]

Alright i did a bit of messing around and found something that works, here it is..

Private Sub Form_Load()
Dim strNameListScript As String, strFileListScript As String, strTempListScript As String
On Error GoTo ErrHandler
strNameListScript = "RuneScapePalListScript"
Open strNameListScript For Input As #1
Do Until EOF(1)
 strFileListScript = ""
 Line Input #1, strTempListScript
 strFileListScript = strFileListScript & strTempListScript
 LstScripts.AddItem (strFileListScript)
Loop
Close #1
ErrHandler:
End Sub

Works Perfectly, thanks for all the help everyone

[Killer42]

... Works Perfectly

It does? To be honest, I'm very surprised. Because it looks to me as though you are adding each line onto the end of the previous one, and then sticking the ever-lengthening text into the listbox. In other words, let us assume the text file contained...

A
B
C
D

I would expect this code to produce the following in the listbox...

A
AB
ABC
ABCD

Here's a modified copy, which is closer to what I would have done...

Private Sub Form_Load()
  Dim strNameListScript As String, strTempListScript As String
  On Error GoTo ErrHandler
  strNameListScript = "RuneScapePalListScript"
  Open strNameListScript For Input As #1
  Do Until EOF(1)
    Line Input #1, strTempListScript
    LstScripts.AddItem (strTempListScript)
  Loop
  Close #1
  ErrHandler:
End Sub

Ah! My mistake. I missed the fact that you were clearing the value of strFileListScript each time around the loop. Which is a bit pointless, really. Why clear out a string, move the other one into it, then use that? Just use the original one.