help me with my buttons.

[bagstoper]

I have a button that when clicked once it loads a picture in an image box. i want it to do that but when it is clicked twice i want it to goto a form 3. Can anyone right some code for this problem.

[akoymakoy]

try declaring a global variable ctr
then per click increment ctr then if ctr = 2
form3.show or the likes

[bagstoper]

that would work but i want people to be able to viw the image more than once. is it posible to do something like use something like the dbl click.

[Killer42]

that would work but i want people to be able to viw the image more than once. is it posible to do something like use something like the dbl click.

The command button doesn't have a double-click event, but you might try simulating it. For example, when it is clicked, you could set a flag and start a timer. When the timer event fires (after half a second, for example) you can check whether the button was clicked again within that time. Also, in the click event, if the flag is already set, don't do anything except increment the "number of times clicked" counter.

[bagstoper]

could someone write the code for that i wouldn't know where to start with that one.

[Killer42]

could someone write the code for that i wouldn't know where to start with that one.

If I can find the time, I'll have a shot at it when I get home (in a couple of hours).

However, if you think about it for a while you can probably work it out. It's not really a terribly complicated concept, just awkward to describe.

[bagstoper]

i don't know how to use the check function let alone the check function with a timer.

[Killer42]

i don't know how to use the check function let alone the check function with a timer.

Well, I'm leaving work now. If someone else doesn't beat me to it, I'll give it a shot when I get home.

[bagstoper]

alrighty then. drive safe

[Killer42]

alrighty then. drive safe

Hi again.

I'm home, and I've thrown together the first two options that came to mind, to produce the equivalent of a double-click on a command button. To use them, just create a new project, add a form, and place a timer and a command button on the form. Then go to the code window for that form, erase absolutely everything and paste in the following.

This is the one which I described earlier...

Option Explicit
DefLng A-Z
 
Dim Click_Count As Long
 
Private Sub Command1_Click()
  Click_Count = Click_Count + 1
  If Timer1.Enabled Then Exit Sub
  Timer1.Enabled = True
End Sub
 
Private Sub Timer1_Timer()
  If Click_Count > 1 Then
    MsgBox "Hey, you clicked " & Format(Click_Count) & " times."
  End If
  Click_Count = 0
  Timer1.Enabled = False
End Sub

This one works, but it's not very responsive, and doesn't really feel like a double-click. While writing it, I thought of a better way, which would respond immediately like a "real" double-click. Try this alternative...

Option Explicit
DefLng A-Z
 
Dim Click_Count As Long
 
Private Sub Command1_Click()
  If Click_Count Then
    ' Consider this a double-click, and go do something.
    MsgBox "Hey, you double-clicked the button!"
    Click_Count = 0
  Else
    Click_Count = Click_Count + 1
    Timer1.Enabled = True
  End If
 
End Sub
 
Private Sub Timer1_Timer()
  Click_Count = 0
  Timer1.Enabled = False
End Sub

[bagstoper]

thanks that will help alot. i wont be able to try it until wednesday because that is when i goto my dad's house.

[Killer42]

Oops! While I believe both those methods provide a double-click equivalent, I think I failed to handle the single-click. Here are modified versions of both which should work.

Note that the Interval property of the timer will affect the "double-click speed" - adjust it to suit yourself. I found 250 was a good setting.

Method 1

Option Explicit
DefLng A-Z
 
Dim Click_Count As Long
 
Private Sub Command1_Click()
  Click_Count = Click_Count + 1
  If Timer1.Enabled Then Exit Sub
  Timer1.Enabled = True
End Sub
 
Private Sub Timer1_Timer()
  If Click_Count > 1 Then
    ' Do your double-click processing here.
    Debug.Print "Double-click"
  Else
    ' Do your single-click processing here.
    Debug.Print "Click"
  End If
  Click_Count = 0
  Timer1.Enabled = False
End Sub

Method 2

Option Explicit
DefLng A-Z
 
Dim Click_Count As Long
 
Private Sub Command1_Click()
  If Click_Count Then
    ' Do your double-click processing here.
    Debug.Print "Double-click"
    Click_Count = 0
  Else
    Click_Count = Click_Count + 1
    Timer1.Enabled = True
  End If
 
End Sub
 
Private Sub Timer1_Timer()
  Timer1.Enabled = False
  If Click_Count = 1 Then
    ' Do your single-click processing here.
    Debug.Print "Click"
  End If
  Click_Count = 0
End Sub

[bagstoper]

but i cant create a new project it needs to go in the middle of a 1/2 complete project. if you can wait till wednesday i can show you the code i have on the form already and you could right around it. till then i wont know if this code will work.:(

[Killer42]

but i cant create a new project it needs to go in the middle of a 1/2 complete project. if you can wait till wednesday i can show you the code i have on the form already and you could right around it. till then i wont know if this code will work.:(

The ideal way to do this would be to create a new project and use it to try out these ideas. Once you understand what's going on, you can include it into your real code much more easily.

[bagstoper]

ok i will do that.

[bagstoper]

got it to work with my program. thanks so much

[Killer42]

got it to work with my program. thanks so much

Glad we could help. :)