Validation of Inputs to Text Boxes

[Akinyemi]

In the Tax computation Software I am developing, I want only numeric characters to be accepted by the Text Boxes. Bellow is my sample code that refuses to work:
Private Sub txtBasicSalary_KeyPress(keyAscii As Integer)
If IsNumeric(txtBasicSalary.Text) = True Then
txtBasicSalary.Locked = False
Else
txtBasicsalary.Locked = True
End If
End Sub

Thank You.

Akinyemi

[devonknows]

Ok you can you the Text1_KeyPress(KeyAscii as Integer) that will stop people pressing cerain keys in your text box

Example:

Private Sub txtdelay_keypress(KeyAscii As Integer)
'check to see if keyascii is between 48 & 57 (0-9)
'and allow 8 (Backspace)
If Not ( _
        (KeyAscii >= "48" And KeyAscii <= "57") Or _
        (KeyAscii = "8") _
    ) Then
        ' Cancel the character.
        KeyAscii = 0
    End If
End Sub
 

but the problem is with that people can still use paste in text which can play hell with coding, as it took me a long time to figure out <lol>.
(CRTL+V / Shift + Ins / Right Click + Paste)

so i would suggest removing your Text1_KeyPress Code and use something along these lines...

Private Sub Text1_Change()
 Static OldText As String
 Static InRoutineFlag As Boolean
 
 If InRoutineFlag Then Exit Sub
 InRoutineFlag = True
 
 Select Case LS_FailNumeric(Text1.Text)
 Case True: Text1.Text = OldText
 Case False: OldText = Text1.Text
 End Select
 
 InRoutineFlag = False
End Sub
 
Private Function LS_FailNumeric(Text$) As Boolean
 Dim L9%
 ' Note: "" passes the test
 For L9 = 1 To Len(Text)
'Insert Characters you want to allow just after the instr
'Current set up to allow 0123456789 and . (Period)
 If InStr("0123456789.", Mid$(Text$, L9, 1)) = 0 Then
 LS_FailNumeric = True
 Exit Function
 End If
 Next
 
End Function
 

Hope this helps you

Kind Regards
Devon.

[devonknows]

Slight Update on the code above

just replace this segment of code

 Select Case LS_FailNumeric(Text1.Text)
 Case True: Text1.Text = OldText
 Case False: OldText = Text1.Text
 End Select
 

with

Select Case LS_FailNumeric(Text1.Text)
 Case True: Text1.Text = OldText: Text1.SelStart = Len(OldText)
 Case False: OldText = Text1.Text
 End Select
 

This change will move the cursor to the end of the text in in the text box instead of reseting to the begining everytime of the text LS_FailNumeric = True so that the client/user doesnt have to move to the end again everytime.

Kind Regards
Devon

[Killer42]

You might also investigate the use of the "masked edit control". It allows you to specify a mask for the input (Eg. phone number, etc.) and I think you can limit it to only numeric input.