Help I am new to VB and have a program due

[meena76]

I have to write a program that will do the following
Write a reservation system for an airline flight (based on problem #7 pages 406). Assume the airplane has 10 rows with 4 seats in each row. Use a two dimensional array of strings to maintain a seating chart with passengers’ names and another two dimensional control array to show available seats on the form (see example 2 page 380). In addition, create an array to be used as a waiting list for in case the plane is full. The waiting list should be “first come, first serve,” that is, people who are added early to the list get priority over those added later. Allow the user the following options:
1) Add a passenger to the flight
· Request a passenger’s name, do not process unless something is entered into the textbox
· If seats are available, user chooses a seat, do not allow user to assign to a seat already taken, nor to exit the process without selecting a seat.
· If no seat available, place the passenger on the wait list. If the wait list is full (10 passengers waiting) display a message that the flight is full


the problem i am having is assigning the passenger to at seat once one passenger has already been assigned. I am using a two dimensional array and i am not sure how to place the next passenger in the correct position of the array?

My source code is below

passenger = txtPassName.Text & " Row " & rowpos + 1 & " " & "Seat " & colpos + 1
If rowcount >= 9 And colcount >= 3 Then
MsgBox("All seats are filled. Your name will be placed on a seating chart")
Else
Do While SeatingChart(rowpos, colpos) < passenger

For rowcount = 0 To rowcount
For colcount = 0 To colcount
SeatingChart(rowcount, colcount) = passenger

Next
Next

Loop
rowpos += 1
colpos += 1
If (SeatingChart(rowpos, colpos) = passenger) And ((rowpos < rowcount) And (colpos < colcount)) Then
MsgBox("Seat already taken choose another seat")
Else
For i As Integer = rowcount - 1 To rowpos Step -1
For j As Integer = colcount - 1 To colpos Step -1
SeatingChart(1 + 1, j + 1) = SeatingChart(i, j)

Next
Next
SeatingChart(rowpos, colpos) = passenger
rowcount += 1
colcount += 1
End If
txtPassName.Clear()
txtPassName.Focus()

End If

[albertw]

hi

made an example, maybe some use to you :)

[meena76]

Unfortunalty I was unable to download the zip file. Could you briefly explain the code for me.

[albertw]

hi

open a new project
place 3 textboxes, txtPassName, txtRow and txtSeat
place 1 listbox, lstWaiting
place 2 buttons, cmdProcess and cmdCancel

Option Base 1
Const maxRow = 10
Const maxSeat = 4
Const maxList = 10
Dim RowSeat(10, 4) As String
Dim Seats As Integer
Dim Waiting As Boolean
 
Private Sub cmdCancel_Click()
If txtpassName.Text = vbNullString Then Exit Sub
For r = 1 To maxRow
    For s = 1 To maxSeat
    p = InStr(1, RowSeat(r, s), "Row")
        If p > 0 Then
        passName = UCase(Left(RowSeat(r, s), p - 2))
            If passName = UCase(txtpassName.Text) Then
            r0 = Mid(RowSeat(r, s), p + 4, 1)
            txtRow.Text = r0
            p = InStr(1, RowSeat(r, s), "Seat")
            s0 = Mid(RowSeat(r, s), p + 5, 1)
            txtSeat.Text = s0
            If MsgBox("Cancel the flight for " & vbNewLine & _
            txtpassName.Text & " ?", vbYesNo + vbQuestion, "Cancel") = vbNo Then Exit Sub
            RowSeat(r, s) = vbNullString
            Reset
            Seats = Seats - 1
            Exit Sub
            End If
        End If
    Next s
Next r
 
End Sub
 
Private Sub cmdProcess_Click()
If txtpassName.Text = vbNullString Or txtRow.Text = vbNullString Or txtSeat.Text = vbNullString Then Exit Sub
    If Seats = (maxRow) * (maxSeat) Then
    MsgBox "All seats are taken. " & vbNewLine & _
    "This passenger will be put into" & vbNewLine & _
    " the waitinglist.", vbOKOnly + vbExclamation, "Seats"
        If lstWaiting.ListCount < maxList Then
        lstWaiting.AddItem txtpassName.Text
        Else
        MsgBox "This flight is full.", vbOKCancel + vbCritical, "Flight"
        End If
        Reset
        Exit Sub
    End If
passenger = txtpassName.Text & " Row " & txtRow.Text & " " & "Seat " & txtSeat.Text
For r = 1 To maxRow
    For s = 1 To maxSeat
    p = InStr(1, RowSeat(r, s), "Row")
        If p > 0 Then
        passName = UCase(Left(RowSeat(r, s), p - 2))
            If passName = UCase(txtpassName.Text) Then
            r0 = Mid(RowSeat(r, s), p + 4, 1)
            p = InStr(1, RowSeat(r, s), "Seat")
            s0 = Mid(RowSeat(r, s), p + 5, 1)
            MsgBox "This passenger has already been assigned to:" & vbNewLine _
            & "Row " & r0 & " Seat " & s0, vbOKOnly + vbExclamation, "Seat"
            txtRow.SetFocus
            Exit Sub
            End If
        End If
    Next s
Next r
 
If RowSeat(txtRow.Text, txtSeat.Text) = vbNullString Then
    RowSeat(txtRow.Text, txtSeat.Text) = passenger
    Reset
    Seats = Seats + 1
    If Waiting = True Then lstWaiting.RemoveItem 0
Else
    MsgBox "This seat is taken. Choose another one.", vbOKOnly + vbExclamation, "Seats"
    txtRow.SetFocus
End If
End Sub
 
Private Sub Form_Load()
Seats = 0
End Sub
 
Private Sub lstWaiting_Click()
If lstWaiting.ListCount > 0 Then
Reset
txtpassName.Text = lstWaiting.List(0)
Waiting = True
End If
End Sub
 
Private Sub txtpassname_Change()
txtRow.Enabled = IIf(Len(txtpassName.Text) > 0, True, False)
txtSeat.Enabled = IIf(Len(txtpassName.Text) > 0, True, False)
End Sub
 
Private Sub Reset()
txtpassName.Text = vbNullString
txtRow.Text = vbNullString
txtSeat.Text = vbNullString
txtpassName.SetFocus
End Sub
 
Private Sub txtRow_Change()
If Val(txtRow.Text) > maxRow Then Exit Sub
End Sub
 
Private Sub txtSeat_Change()
If Val(txtSeat.Text) > maxSeat Then Exit Sub
End Sub
 

the code is to be copied and pasted...
it does what you want it to do.

enter the passengersname into txtpassName
enter the row in txtrow and seatnumber in txtseat
then press cmdProcess
to cancel a booking from the plane, enter the name and press cmdcancel
(row and seatnumber are exposed)
if no seats are available, up to 10 passengers may be put into the waitinglist (lstwaiting)
if any seats are cancelled, you can click in the listbox, where the topmost name is selected and put into txtpassname.
add row and seatnumber and press cmdprocess
if this passenger was accepted, the name will be removed from the waitinglist.

warnings are given for 2nd assignment of same name and if seats are no more available.

you may expand this program with a lot of other options, like e.g. a graphic seatdisplay

success

[meena76]

WOW!!!!

This is great thank you soooo much. This is very helpful.

I actually constructed a contorl array of buttons to display seat assignments, thank you for the suggestion

[albertw]

WOW!!!!

This is great thank you soooo much. This is very helpful.

I actually constructed a contorl array of buttons to display seat assignments, thank you for the suggestion

hi

or you may create a number of labels (array - format) and give the label.background a different color when occupied. ?

[meena76]

yea i started of with lables but then I thought it would be great if user could click the seat wanting to seat in and once clicked the locationof the button in the button array would be assigned to the seatassign array, but I have know clue how to do that I tried to add a click event to buttons but i didn't know how to pull out the buttons loc in array

[albertw]

yea i started of with lables but then I thought it would be great if user could click the seat wanting to seat in and once clicked the locationof the button in the button array would be assigned to the seatassign array, but I have know clue how to do that I tried to add a click event to buttons but i didn't know how to pull out the buttons loc in array

yes, you can use buttons, but label have a click-function also :)
you can make a single array of labels say from 1 to 40 and assign a tag as row/seatnumber
e.g: lblSeat(2) has a tag 0102, meaning row 01 and seat 02
lblSeat(23) has a tag 0503 etc
have your program look for tags and not indexnumbers

[tabloidster]

Howdy,

Sorry for intruding, but I've got a similar problem:

I've got a VB6 assignment which uses Arrays and an Access dbase.

It's a six seater plane (two columns, 3 rows each.) I've got to display a seating chart (this is where the array probably comes in?) at all times, and I've got to do bookings (Fname, Lname and Seat no.)

The data must be stored in Access 2K (I'm guessing we use the ADO control here?)

The seating chart can use labels, RED for taken, GREEN for open. It doesn't have to display the passenger name.

When I exit the VB app, the data in the array will obviously go, that's why I hvae to save the seat assignments in Access. When I run the app, it should populate the chart with the seat assigments stored in the dbase.

We also have to have a passwd login screen, which was simple to do and is workng just fine. Call forms such as an about form which is easy.

Any ideas?

yes, you can use buttons, but label have a click-function also :)
you can make a single array of labels say from 1 to 40 and assign a tag as row/seatnumber
e.g: lblSeat(2) has a tag 0102, meaning row 01 and seat 02
lblSeat(23) has a tag 0503 etc
have your program look for tags and not indexnumbers