> >I have developed dictionary (Eng, Ger, Fra, Ita) in Access. The word
list
for each is in separate table (Eng_Ger), (Eng_Fra), (Eng_Ita).
I want to protect my dict from unlegal copying with next procedure:
examine and save the serial number of the hard drive using API calls.
Q: Does anybody know this procedure to help me finish this project.
Get the Downloadable API Guide from www.AllAPI.net
Look at the example for: GetVolumeInformation
(The serial number is returned as Decimal, you'll need to look at it
as Hex to prove that it is correct)
Although I wouldn't recommend using the hard drive serial number for
copy protection purposes (what happens when the user decides to upgrade
his hard drive to a larger size), perhaps this old post of mine will
help the OP out in getting the Hex value of the hard drive's serial
number.
Rick - MVP
Try using this declaration and function (you can pass the drive letter
in as a letter by itself, a letter followed by a colon or a letter
followed by a colon followed by a backslash). The serial number is
returned in Hex format. If the drive letter doesn't exist, the function
returns the string 00000000.
Private Declare Function GetVolumeInformation _
Lib "kernel32.dll" _
Alias "GetVolumeInformationA" _
(ByVal lpRootPathName As String, _
ByVal lpVolumeNameBuffer As String, _
ByVal nVolumeNameSize As Integer, _
lpVolumeSerialNumber As Long, _
lpMaximumComponentLength As Long, _
lpFileSystemFlags As Long, _
ByVal lpFileSystemNameBuffer As String, _
ByVal nFileSystemNameSize As Long) As Long
Function GetSerialNumber(DriveLetter As String) As String
Dim SerialNum As Long
Dim VolNameBuf As String
Dim FileSysNameBuf As String
If LCase(DriveLetter) Like _
Left$("[a-z]:\", 4 + Len(DriveLetter)) Then
DriveLetter = DriveLetter & Mid$(":\", Len(DriveLetter))
End If
If Len(GetSerialNumber) = 0 Then
VolNameBuf = String$(255, Chr$(0))
FileSysNameBuf = String$(255, Chr$(0))
GetVolumeInformation DriveLetter, VolNameBuf, _
Len(VolNameBuf), SerialNum, 0, 0, _
FileSysNameBuf, Len(FileSysNameBuf)
GetSerialNumber = Right$("00000000" & Hex$(SerialNum), 8)
End If
End Function
