By using this site, you agree to our updated Privacy Policy and our Terms of Use. Manage your Cookies Settings.
459,272 Members | 1,452 Online
Bytes IT Community
+ Ask a Question
Need help? Post your question and get tips & solutions from a community of 459,272 IT Pros & Developers. It's quick & easy.

read BIOS or HDD or Machine Serial Number

P: n/a
Hi, I'm a newbie to programming of any kind. I have posted this to other
groups in a hope to get a response from anyone.

Can any one tell me how to make my VB program read the Bios serial number
(or would HDD be better, or both?) and put that info into VB prog so the
program won't work on another computer. My program uses an MSAccess table.

Much appreciated if you can help!

Thanks
Gavin


Jul 17 '05 #1
Share this Question
Share on Google+
21 Replies


P: n/a
There is a api call to return the HD serial number. I cant remember it
off the top of my head, maybe someone else can help...
Jul 17 '05 #2

P: n/a
On 8 Aug 2003 09:09:51 -0700, no*****@samuelhon.co.uk (Samuel Hon)
wrote:
There is a api call to return the HD serial number. I cant remember it
off the top of my head, maybe someone else can help...


GetVolumeInformation
Jul 17 '05 #3

P: n/a
There's an undocumented VB function:

Declare Sub GetMem1 Lib "msvbvm60.dll" (ByVal MemAddress As Long, var As
Byte)

It lets you read one byte of memory at a time. Since the BIOS is loaded
into RAM at startup you could read, say, 50 bytes of BIOS to get a string.
I don't remember offhand what the area is reserved for BIOS, but I do know
that you can pick out the BIOS date on 9x by reading 8 bytes starting with
&HFFFF5 (ex.: 04/06/99 ).

I don't think that NT lets you read that area, but I'm not sure about
that.
I did see a small system info. program awhile back that, among other things,
would spit out the entire BIOS as text. You'd have to play around with it
to
see if something like that would be a possible solution.

--
--
André Joubert <ja****@sympatico.ca> wrote in message
news:Fi********************@news20.bellglobal.com. ..
That API DOES NOT return the HDD serial no. but only the volume serial
as selected by the format command. It will change every time you format your disk. There will be one volume serial no. per partition. So on single HDD
with
3 volumes (3 partitions) you get 3 volume serial no.

André
"J French" <er*****@nowhere.com> wrote in message
news:3f***************@news.btclick.com...
On 8 Aug 2003 09:09:51 -0700, no*****@samuelhon.co.uk (Samuel Hon)
wrote:
There is a api call to return the HD serial number. I cant remember it
off the top of my head, maybe someone else can help...


GetVolumeInformation


Jul 17 '05 #4

P: n/a
er*****@nowhere.com (J French) wrote in message news:<3f**************@news.btclick.com>...
On Fri, 8 Aug 2003 14:51:09 -0400, "André Joubert"
<ja****@sympatico.ca> wrote:
That API DOES NOT return the HDD serial no. but only the volume serial
as selected by the format command. It will change every time you format your
disk. There will be one volume serial no. per partition. So on single HDD
with
3 volumes (3 partitions) you get 3 volume serial no.


Totally agreed, but that sounds like the API Samuel Hon was thinking
about

The only other method I've heard of, is for SMART complient drives

Private Function OpenSmart(drv_num As IDE_DRIVE_NUMBER) As Long
If IsWindowsNT Then
OpenSmart = CreateFile("\\.\PhysicalDrive" _
& CStr(drv_num), _
GENERIC_READ Or GENERIC_WRITE, _
FILE_SHARE_READ Or FILE_SHARE_WRITE, _
ByVal 0&, OPEN_EXISTING, 0, 0)
Else
OpenSmart = CreateFile("\\.\SMARTVSD", _
0, 0, ByVal 0&, CREATE_NEW, 0, 0)
End If
End Function

And then do some hefty DeviceIOControl


This is the code I use:

Private Declare Function GetVolumeInformation Lib "kernel32" _ Alias
"GetVolumeInformationA" (ByVal lpRootPathName As String, ByVal _
lpVolumeNameBuffer As String, ByVal nVolumeNameSize As Long, _
lpVolumeSerialNumber As Long, lpMaximumComponentLength As Long, _
lpFileSystemFlags As Long, ByVal lpFileSystemNameBuffer As String,
ByVal _ nFileSystemNameSize As Long) As Long
Public lngVolumeID As Long

'I use this in my form load event
'Serial #
Dim nRet As Long
Dim VolName As String
Dim MaxCompLen As Long
Dim VolFlags As Long
Dim VolFileSys As String

VolName = Space$(256)
VolFileSys = Space$(256)

nRet = GetVolumeInformation("C:\", VolName, Len(VolName), lngVolumeID,
_
MaxCompLen, VolFlags, VolFileSys, Len(VolFileSys))
Text1.Text = lngVolumeID ' Serial Number
Jul 17 '05 #5

P: n/a
Hello gavin.
Try the code below.It doesn't need explanation.
Private Declare Function GetVolumeInformation Lib _
"kernel32.dll" Alias "GetVolumeInformationA" _
(ByVal lpRootPathName As String, _
ByVal lpVolumeNameBuffer As String, _
ByVal nVolumeNameSize As Integer, _
lpVolumeSerialNumber As Long, _
lpMaximumComponentLength As Long, _
lpFileSystemFlags As Long, _
ByVal lpFileSystemNameBuffer As String, _
ByVal nFileSystemNameSize As Long) As Long

Public Function DriveSerialNumber(ByVal Drive As String) As Long

'usage: SN = DriveSerialNumber("C:\")

Dim lAns As Long
Dim lRet As Long
Dim sVolumeName As String, sDriveType As String
Dim sDrive As String

'Deal with one and two character input values
sDrive = Drive
If Len(sDrive) = 1 Then
sDrive = sDrive & ":\"
ElseIf Len(sDrive) = 2 And Right(sDrive, 1) = ":" Then
sDrive = sDrive & "\"
End If

sVolumeName = String$(255, Chr$(0))
sDriveType = String$(255, Chr$(0))

lRet = GetVolumeInformation(sDrive, sVolumeName, _
255, lAns, 0, 0, sDriveType, 255)

DriveSerialNumber = lAns
End Function
Jul 17 '05 #6

P: n/a
d j tailor <dj**@rediffmail.com> schreef in berichtnieuws
15**************************@posting.google.com...

Hello d j,
Hello gavin.
Try the code below.It doesn't need explanation.

Private Declare Function GetVolumeInformation Lib _
"kernel32.dll" Alias "GetVolumeInformationA" _


[Snip]

Actually, it *does* need some explanation ... Not on how it works, but
rather on what it does. This function does not retrieve a serial-number as
ment by the OP.

The serial-number retrieved by the above call changes with every
Format-action you do. It allso does retrieve different numbers for every
logical drive in/on a physical disk, as well as floppies. With a bit of
work you can alter that serial-number to be whatever you want (just don't
give all your logical drives/floppies the same number :-)

Reading the places the OP wants to retrieve serial-numbers from, my, ahem
..., "guess" is that he's looking for numbers that do not change (easily).
Probably he's in the process of trying to lock some software to a specific
computer.

Alas, although a physical drive does have a fixed *manufacturers*
serial-number (which is quite easily retrieved from within DOS), I have not
found/seen/read of a method to retrieve it from within Windows.

Regards,
Rudy Wieser

Jul 17 '05 #7

P: n/a
On Fri, 08 Aug 2003 21:15:18 GMT, "mayayana"
<ma*******@mindspring.com> wrote:
There's an undocumented VB function:

Declare Sub GetMem1 Lib "msvbvm60.dll" (ByVal MemAddress As Long, var As
Byte)

It lets you read one byte of memory at a time. Since the BIOS is loaded
into RAM at startup you could read, say, 50 bytes of BIOS to get a string.
I don't remember offhand what the area is reserved for BIOS, but I do know
that you can pick out the BIOS date on 9x by reading 8 bytes starting with
&HFFFF5 (ex.: 04/06/99 ).


Mayayana,

That is really interesting
- sadly it is not supposed to work for NT, XP etc
- also it is really MoveMemory in Drag (example below)

However looking for it got me here:

http://www.xbeat.net/vbspeed/i_VBVM6...l#Introduction

Interesting ... there is some meat in that - Thanks

Demo to get BIOS Date - GetMem1 versus RTLMoveMemory

Option Explicit

Private Declare Sub GetMem1 _
Lib "msvbvm60.dll" _
(ByVal MemAddress As Long, _
var As Byte)

Private Declare Sub MoveMemory _
Lib "kernel32" _
Alias "RtlMoveMemory" _
(ByVal Dest As Any, _
ByVal Source As Any, _
ByVal Bytes As Long)

Private Sub Command1_Click()
Dim B As Byte, L9&
For L9 = 0 To 7
Call GetMem1(&HFFFF5 + L9, B)
Me.Print Chr$(B);
Next
Me.Print
For L9 = 0 To 7
Call MoveMemory(VarPtr(B), ByVal &HFFFF5 + L9, 1)
Me.Print Chr$(B);
Next

End Sub
Jul 17 '05 #8

P: n/a
On Sun, 10 Aug 2003 14:17:11 +0200, "R.Wieser"
<rw***************@xs4all.nl> wrote:

<snip>

Alas, although a physical drive does have a fixed *manufacturers*
serial-number (which is quite easily retrieved from within DOS), I have not
found/seen/read of a method to retrieve it from within Windows.


There is a method
- I do not recommend it - it relies on a level of technology that one
of my drives does not support

I do not know where I got the code, however I doubt that they will
mind it being re-posted ... if otherwise ... apologies

- I strongly recommend NOT using this stuff
- it is asking for support calls
- however it is worth *knowing* about
' 20th July 2002 from NG
' Works for Drive 0 - not 1

'Hi,
'
'Most hard disks sold in the last few years support SMART
(Self-Monitoring,
'Analysis, and Reporting Technology) using Microsoft scripting you can
use
'this to return the hard disk physical serial number, NOT the volume
serial
'number. This will not change with a reformat, re-install of OS etc,
etc. It
'will ONLY change if you replace the hard disk.
'
'To do this, use add a reference for Microsoft Scripting Runtime.
'
'Add the following to a .bas module (this was assembled from MSDN
online
'somewhere...)

'********************START OF BAS MODULE********************

Option Explicit

Private Type OSVERSIONINFO
dwOSVersionInfoSize As Long
dwMajorVersion As Long
dwMinorVersion As Long
dwBuildNumber As Long
dwPlatformId As Long
szCSDVersion As String * 128
End Type
Private Declare Function GetVersionEx Lib "kernel32" Alias
"GetVersionExA" (LpVersionInformation As OSVERSIONINFO) As Long

Private Type ATTR_DATA
AttrID As Byte
AttrName As String
AttrValue As Byte
ThresholdValue As Byte
WorstValue As Byte
StatusFlags As STATUS_FLAGS
End Type

Public Type DRIVE_INFO
bDriveType As Byte
SerialNumber As String
Model As String
FirmWare As String
Cilinders As Long
Heads As Long
SecPerTrack As Long
BytesPerSector As Long
BytesperTrack As Long
NumAttributes As Byte
Attributes() As ATTR_DATA
End Type

Public Enum IDE_DRIVE_NUMBER
PRIMARY_MASTER
PRIMARY_SLAVE
SECONDARY_MASTER
SECONDARY_SLAVE
End Enum

Private Declare Function CreateFile _
Lib "kernel32" Alias "CreateFileA" _
(ByVal lpFileName As String, ByVal dwDesiredAccess As Long,
ByVal dwShareMode As Long, ByVal lpSecurityAttributes As Long, _
ByVal dwCreationDisposition As Long, _
ByVal dwFlagsAndAttributes As Long, _
ByVal hTemplateFile As Long) As Long
Private Declare Function CloseHandle _
Lib "kernel32" (ByVal hObject As Long) As Long
Private Declare Function DeviceIoControl _
Lib "kernel32" (ByVal hDevice As Long, _
ByVal dwIoControlCode As Long, _
lpInBuffer As Any, _
ByVal nInBufferSize As Long, _
lpOutBuffer As Any, _
ByVal nOutBufferSize As Long, _
lpBytesReturned As Long, _
ByVal lpOverlapped As Long) As Long
Public Declare Sub CopyMemory _
Lib "kernel32" _
Alias "RtlMoveMemory" (Destination As Any, _
Source As Any, ByVal Length As Long)

Private Const GENERIC_READ = &H80000000
Private Const GENERIC_WRITE = &H40000000

Private Const FILE_SHARE_READ = &H1
Private Const FILE_SHARE_WRITE = &H2
Private Const OPEN_EXISTING = 3
Private Const FILE_ATTRIBUTE_SYSTEM = &H4
Private Const CREATE_NEW = 1

Private Const INVALID_HANDLE_VALUE = -1
Dim di As DRIVE_INFO

Public Const MAX_IDE_DRIVES = 4
' // Max number of drives assuming primary/secondary, master/slave
topology
Public Const READ_ATTRIBUTE_BUFFER_SIZE = 512
Public Const IDENTIFY_BUFFER_SIZE = 512
Public Const READ_THRESHOLD_BUFFER_SIZE = 512
Public Const OUTPUT_DATA_SIZE = IDENTIFY_BUFFER_SIZE + 16

'IOCTL commands
Public Const DFP_GET_VERSION = &H74080
Public Const DFP_SEND_DRIVE_COMMAND = &H7C084
Public Const DFP_RECEIVE_DRIVE_DATA = &H7C088

'---------------------------------------------------------------------
' GETVERSIONOUTPARAMS contains the data returned from the
' Get Driver Version function.
'---------------------------------------------------------------------
Public Type GETVERSIONOUTPARAMS
bVersion As Byte ' Binary driver version.
bRevision As Byte ' Binary driver revision.
bReserved As Byte ' Not used.
bIDEDeviceMap As Byte ' Bit map of IDE devices.
fCapabilities As Long ' Bit mask of driver capabilities.
dwReserved(3) As Long ' For future use.
End Type

'Bits returned in the fCapabilities member of GETVERSIONOUTPARAMS
Public Const CAP_IDE_ID_FUNCTION = 1 ' ATA ID command
supported
Public Const CAP_IDE_ATAPI_ID = 2 ' ATAPI ID command
supported
Public Const CAP_IDE_EXECUTE_SMART_FUNCTION = 4 ' SMART commannds
supported

'---------------------------------------------------------------------
' IDE registers
'---------------------------------------------------------------------
Public Type IDEREGS
bFeaturesReg As Byte ' // Used for specifying SMART "commands".
bSectorCountReg As Byte ' // IDE sector count register
bSectorNumberReg As Byte ' // IDE sector number register
bCylLowReg As Byte ' // IDE low order cylinder value
bCylHighReg As Byte ' // IDE high order cylinder value
bDriveHeadReg As Byte ' // IDE drive/head register
bCommandReg As Byte ' // Actual IDE command.
bReserved As Byte ' // reserved for future use. Must be
zero.
End Type

'---------------------------------------------------------------------
' SENDCMDINPARAMS contains the input parameters for the
' Send Command to Drive function.
'---------------------------------------------------------------------
Public Type SENDCMDINPARAMS
cBufferSize As Long ' Buffer size in bytes
irDriveRegs As IDEREGS ' Structure with drive register values.
bDriveNumber As Byte ' Physical drive number to send command
to(0,1,2,3).
bReserved(2) As Byte ' Bytes reserved
dwReserved(3) As Long ' DWORDS reserved
bBuffer() As Byte ' Input buffer.
End Type

' Valid values for the bCommandReg member of IDEREGS.
Public Const IDE_ATAPI_ID = &HA1 ' Returns ID sector for
ATAPI.
Public Const IDE_ID_FUNCTION = &HEC ' Returns ID sector for
ATA.
Public Const IDE_EXECUTE_SMART_FUNCTION = &HB0 ' Performs SMART cmd.
' Requires valid
bFeaturesReg,
' bCylLowReg, and
bCylHighReg

' Cylinder register values required when issuing SMART command
Public Const SMART_CYL_LOW = &H4F
Public Const SMART_CYL_HI = &HC2

'---------------------------------------------------------------------
' Status returned from driver
'---------------------------------------------------------------------
Public Type DRIVERSTATUS
bDriverError As Byte ' Error code from driver, or 0 if no
error.
bIDEStatus As Byte ' Contents of IDE Error register.
' Only valid when bDriverError is
SMART_IDE_ERROR.
bReserved(1) As Byte
dwReserved(1) As Long
End Type

' bDriverError values
Public Enum DRIVER_ERRORS
SMART_NO_ERROR = 0 ' No error
SMART_IDE_ERROR = 1 ' Error from IDE controller
SMART_INVALID_FLAG = 2 ' Invalid command flag
SMART_INVALID_COMMAND = 3 ' Invalid command byte
SMART_INVALID_BUFFER = 4 ' Bad buffer (null, invalid addr..)
SMART_INVALID_DRIVE = 5 ' Drive number not valid
SMART_INVALID_IOCTL = 6 ' Invalid IOCTL
SMART_ERROR_NO_MEM = 7 ' Could not lock user's buffer
SMART_INVALID_REGISTER = 8 ' Some IDE Register not valid
SMART_NOT_SUPPORTED = 9 ' Invalid cmd flag set
SMART_NO_IDE_DEVICE = 10 ' Cmd issued to device not present
' although drive number is valid
' 11-255 reserved
End Enum
'---------------------------------------------------------------------
' The following struct defines the interesting part of the IDENTIFY
' buffer:
'---------------------------------------------------------------------
Public Type IDSECTOR
wGenConfig As Integer
wNumCyls As Integer
wReserved As Integer
wNumHeads As Integer
wBytesPerTrack As Integer
wBytesPerSector As Integer
wSectorsPerTrack As Integer
wVendorUnique(2) As Integer
sSerialNumber(19) As Byte
wBufferType As Integer
wBufferSize As Integer
wECCSize As Integer
sFirmwareRev(7) As Byte
sModelNumber(39) As Byte
wMoreVendorUnique As Integer
wDoubleWordIO As Integer
wCapabilities As Integer
wReserved1 As Integer
wPIOTiming As Integer
wDMATiming As Integer
wBS As Integer
wNumCurrentCyls As Integer
wNumCurrentHeads As Integer
wNumCurrentSectorsPerTrack As Integer
ulCurrentSectorCapacity As Long
wMultSectorStuff As Integer
ulTotalAddressableSectors As Long
wSingleWordDMA As Integer
wMultiWordDMA As Integer
bReserved(127) As Byte
End Type

'---------------------------------------------------------------------
' Structure returned by SMART IOCTL for several commands
'---------------------------------------------------------------------
Public Type SENDCMDOUTPARAMS
cBufferSize As Long ' Size of bBuffer in
bytes(IDENTIFY_BUFFER_SIZE in our case)
DRIVERSTATUS As DRIVERSTATUS ' Driver status structure.
bBuffer() As Byte ' Buffer of arbitrary length in which
to store the data read from the drive.
End Type

'---------------------------------------------------------------------
' Feature register defines for SMART "sub commands"
'---------------------------------------------------------------------

Public Const SMART_READ_ATTRIBUTE_VALUES = &HD0
Public Const SMART_READ_ATTRIBUTE_THRESHOLDS = &HD1
Public Const SMART_ENABLE_DISABLE_ATTRIBUTE_AUTOSAVE = &HD2
Public Const SMART_SAVE_ATTRIBUTE_VALUES = &HD3
Public Const SMART_EXECUTE_OFFLINE_IMMEDIATE = &HD4
' Vendor specific commands:
Public Const SMART_ENABLE_SMART_OPERATIONS = &HD8
Public Const SMART_DISABLE_SMART_OPERATIONS = &HD9
Public Const SMART_RETURN_SMART_STATUS = &HDA

'---------------------------------------------------------------------
' The following structure defines the structure of a Drive Attribute
'---------------------------------------------------------------------

Public Const NUM_ATTRIBUTE_STRUCTS = 30

Public Type DRIVEATTRIBUTE
bAttrID As Byte ' Identifies which attribute
wStatusFlags As Integer 'Integer ' see bit definitions below
bAttrValue As Byte ' Current normalized value
bWorstValue As Byte ' How bad has it ever been?
bRawValue(5) As Byte ' Un-normalized value
bReserved As Byte ' ...
End Type
'---------------------------------------------------------------------
' Status Flags Values
'---------------------------------------------------------------------
Public Enum STATUS_FLAGS
PRE_FAILURE_WARRANTY = &H1
ON_LINE_COLLECTION = &H2
PERFORMANCE_ATTRIBUTE = &H4
ERROR_RATE_ATTRIBUTE = &H8
EVENT_COUNT_ATTRIBUTE = &H10
SELF_PRESERVING_ATTRIBUTE = &H20
End Enum

'---------------------------------------------------------------------
' The following structure defines the structure of a Warranty
Threshold
' Obsoleted in ATA4!
'---------------------------------------------------------------------

Public Type ATTRTHRESHOLD
bAttrID As Byte ' Identifies which attribute
bWarrantyThreshold As Byte ' Triggering value
bReserved(9) As Byte ' ...
End Type

'---------------------------------------------------------------------
' Valid Attribute IDs
'---------------------------------------------------------------------
Public Enum ATTRIBUTE_ID
ATTR_INVALID = 0
ATTR_READ_ERROR_RATE = 1
ATTR_THROUGHPUT_PERF = 2
ATTR_SPIN_UP_TIME = 3
ATTR_START_STOP_COUNT = 4
ATTR_REALLOC_SECTOR_COUNT = 5
ATTR_READ_CHANNEL_MARGIN = 6
ATTR_SEEK_ERROR_RATE = 7
ATTR_SEEK_TIME_PERF = 8
ATTR_POWER_ON_HRS_COUNT = 9
ATTR_SPIN_RETRY_COUNT = 10
ATTR_CALIBRATION_RETRY_COUNT = 11
ATTR_POWER_CYCLE_COUNT = 12
ATTR_SOFT_READ_ERROR_RATE = 13
ATTR_G_SENSE_ERROR_RATE = 191
ATTR_POWER_OFF_RETRACT_CYCLE = 192
ATTR_LOAD_UNLOAD_CYCLE_COUNT = 193
ATTR_TEMPERATURE = 194
ATTR_REALLOCATION_EVENTS_COUNT = 196
ATTR_CURRENT_PENDING_SECTOR_COUNT = 197
ATTR_UNCORRECTABLE_SECTOR_COUNT = 198
ATTR_ULTRADMA_CRC_ERROR_RATE = 199
ATTR_WRITE_ERROR_RATE = 200
ATTR_DISK_SHIFT = 220
ATTR_G_SENSE_ERROR_RATEII = 221
ATTR_LOADED_HOURS = 222
ATTR_LOAD_UNLOAD_RETRY_COUNT = 223
ATTR_LOAD_FRICTION = 224
ATTR_LOAD_UNLOAD_CYCLE_COUNTII = 225
ATTR_LOAD_IN_TIME = 226
ATTR_TORQUE_AMPLIFICATION_COUNT = 227
ATTR_POWER_OFF_RETRACT_COUNT = 228
ATTR_GMR_HEAD_AMPLITUDE = 230
ATTR_TEMPERATUREII = 231
ATTR_READ_ERROR_RETRY_RATE = 250
End Enum

Dim colAttrNames As Collection
'************************************************* **************************
' Open SMART to allow DeviceIoControl communications. Return SMART
handle
'************************************************* **************************
Private Function OpenSmart(drv_num As IDE_DRIVE_NUMBER) As Long
If IsWindowsNT Then
OpenSmart = CreateFile("\\.\PhysicalDrive" _
& CStr(drv_num), _
GENERIC_READ Or GENERIC_WRITE, _
FILE_SHARE_READ Or FILE_SHARE_WRITE, _
ByVal 0&, OPEN_EXISTING, 0, 0)
Else
OpenSmart = CreateFile("\\.\SMARTVSD", _
0, 0, ByVal 0&, CREATE_NEW, 0, 0)
End If
End Function

'************************************************* **************************
' CheckSMARTEnable - Check if SMART enable
' FUNCTION: Send a SMART_ENABLE_SMART_OPERATIONS command to the drive
' bDriveNum = 0-3
'************************************************* **************************

Private Function CheckSMARTEnable(ByVal hDrive As Long, _
DriveNum As IDE_DRIVE_NUMBER) As Boolean
'Set up data structures for Enable SMART Command.
Dim SCIP As SENDCMDINPARAMS
Dim SCOP As SENDCMDOUTPARAMS
Dim lpcbBytesReturned As Long
With SCIP
.cBufferSize = 0
With .irDriveRegs
.bFeaturesReg = SMART_ENABLE_SMART_OPERATIONS
.bSectorCountReg = 1
.bSectorNumberReg = 1
.bCylLowReg = SMART_CYL_LOW
.bCylHighReg = SMART_CYL_HI
'Compute the drive number.
.bDriveHeadReg = &HA0 ' Or (DriveNum And 1) * 16
.bCommandReg = IDE_EXECUTE_SMART_FUNCTION
End With
.bDriveNumber = DriveNum
End With
CheckSMARTEnable = DeviceIoControl(hDrive, _
DFP_SEND_DRIVE_COMMAND, SCIP, _
Len(SCIP) - 4, _
SCOP, Len(SCOP) - 4, lpcbBytesReturned, ByVal
0&)
End Function

'************************************************* **************************

' DoIdentify
' Function: Send an IDENTIFY command to the drive
' DriveNum = 0-3
' IDCmd = IDE_ID_FUNCTION or IDE_ATAPI_ID
'************************************************* **************************

Private Function IdentifyDrive(ByVal hDrive As Long, _
ByVal IDCmd As Byte, _
ByVal DriveNum As IDE_DRIVE_NUMBER) As
Boolean
Dim SCIP As SENDCMDINPARAMS
Dim IDSEC As IDSECTOR
Dim bArrOut(OUTPUT_DATA_SIZE - 1) As Byte
Dim sMsg As String
Dim lpcbBytesReturned As Long
Dim barrfound(100) As Long
Dim i As Long
Dim lng As Long
' Set up data structures for IDENTIFY command.
With SCIP
.cBufferSize = IDENTIFY_BUFFER_SIZE
.bDriveNumber = CByte(DriveNum)
With .irDriveRegs
.bFeaturesReg = 0
.bSectorCountReg = 1
.bSectorNumberReg = 1
.bCylLowReg = 0
.bCylHighReg = 0
' Compute the drive number.
.bDriveHeadReg = &HA0
If Not IsWindowsNT Then _
.bDriveHeadReg = .bDriveHeadReg _
Or (DriveNum And 1) * 16
' The command can either be IDE identify or ATAPI identify.
.bCommandReg = CByte(IDCmd)
End With
End With
If DeviceIoControl(hDrive, DFP_RECEIVE_DRIVE_DATA, _
SCIP, Len(SCIP) - 4, _
bArrOut(0), OUTPUT_DATA_SIZE, _
lpcbBytesReturned, ByVal 0&) Then
IdentifyDrive = True
CopyMemory IDSEC, bArrOut(16), Len(IDSEC)
di.Model = SwapStringBytes(StrConv(IDSEC.sModelNumber,
vbUnicode))
di.FirmWare = SwapStringBytes(StrConv(IDSEC.sFirmwareRev,
vbUnicode))
di.SerialNumber = SwapStringBytes(StrConv(IDSEC.sSerialNumber,
vbUnicode))
di.Cilinders = IDSEC.wNumCyls
di.Heads = IDSEC.wNumHeads
di.SecPerTrack = IDSEC.wSectorsPerTrack
End If
End Function

'************************************************* **************************
' ReadAttributesCmd
' FUNCTION: Send a SMART_READ_ATTRIBUTE_VALUES command to the drive
' bDriveNum = 0-3
'************************************************* **************************

Private Function ReadAttributesCmd(ByVal hDrive As Long, _
DriveNum As IDE_DRIVE_NUMBER) As
Boolean
Dim cbBytesReturned As Long
Dim SCIP As SENDCMDINPARAMS
Dim drv_attr As DRIVEATTRIBUTE
Dim bArrOut(OUTPUT_DATA_SIZE - 1) As Byte
Dim sMsg As String
Dim i As Long
With SCIP
' Set up data structures for Read Attributes SMART Command.
.cBufferSize = READ_ATTRIBUTE_BUFFER_SIZE
.bDriveNumber = DriveNum
With .irDriveRegs
.bFeaturesReg = SMART_READ_ATTRIBUTE_VALUES
.bSectorCountReg = 1
.bSectorNumberReg = 1
.bCylLowReg = SMART_CYL_LOW
.bCylHighReg = SMART_CYL_HI
' Compute the drive number.
.bDriveHeadReg = &HA0
If Not IsWindowsNT Then _
.bDriveHeadReg = .bDriveHeadReg Or _
(DriveNum And 1) * 16
.bCommandReg = IDE_EXECUTE_SMART_FUNCTION
End With
End With
ReadAttributesCmd = DeviceIoControl(hDrive, DFP_RECEIVE_DRIVE_DATA,
_
SCIP, Len(SCIP) - 4, _
bArrOut(0), _
OUTPUT_DATA_SIZE, _
cbBytesReturned, ByVal 0&)
On Error Resume Next
For i = 0 To NUM_ATTRIBUTE_STRUCTS - 1
If bArrOut(18 + i * 12) > 0 Then
di.Attributes(di.NumAttributes).AttrID = bArrOut(18 + i * 12)
di.Attributes(di.NumAttributes).AttrName _
= "Unknown value (" & bArrOut(18 + i * 12) &
")"
' di.Attributes(di.NumAttributes).AttrName = colAttrNames
(CStr(bArrOut(18 + i * 12)))
di.NumAttributes = di.NumAttributes + 1
ReDim Preserve di.Attributes(di.NumAttributes)
CopyMemory di.Attributes(di.NumAttributes).StatusFlags, _
bArrOut(19 + i * 12), 2
di.Attributes(di.NumAttributes).AttrValue = bArrOut(21 + i *
12)
di.Attributes(di.NumAttributes).WorstValue = bArrOut(22 + i *
12)
End If
Next i
End Function

Private Function ReadThresholdsCmd(ByVal hDrive As Long, _
DriveNum As IDE_DRIVE_NUMBER) As Boolean
Dim cbBytesReturned As Long
Dim SCIP As SENDCMDINPARAMS
Dim IDSEC As IDSECTOR
Dim bArrOut(OUTPUT_DATA_SIZE - 1) As Byte
Dim sMsg As String
Dim thr_attr As ATTRTHRESHOLD
Dim i As Long, j As Long
With SCIP
' Set up data structures for Read Attributes SMART Command.
.cBufferSize = READ_THRESHOLD_BUFFER_SIZE
.bDriveNumber = DriveNum
With .irDriveRegs
.bFeaturesReg = SMART_READ_ATTRIBUTE_THRESHOLDS
.bSectorCountReg = 1
.bSectorNumberReg = 1
.bCylLowReg = SMART_CYL_LOW
.bCylHighReg = SMART_CYL_HI
' Compute the drive number.
.bDriveHeadReg = &HA0
If Not IsWindowsNT Then _
.bDriveHeadReg = .bDriveHeadReg Or _
(DriveNum And 1) * 16
.bCommandReg = IDE_EXECUTE_SMART_FUNCTION
End With
End With
ReadThresholdsCmd = DeviceIoControl(hDrive, _
DFP_RECEIVE_DRIVE_DATA, SCIP, _
Len(SCIP) - 4, bArrOut(0), _
OUTPUT_DATA_SIZE, cbBytesReturned, ByVal 0&)
For i = 0 To NUM_ATTRIBUTE_STRUCTS - 1
CopyMemory thr_attr, bArrOut(18 + i * Len(thr_attr)),
Len(thr_attr)
If thr_attr.bAttrID > 0 Then
For j = 0 To UBound(di.Attributes)
If thr_attr.bAttrID = di.Attributes(j).AttrID Then
di.Attributes(j).ThresholdValue =
thr_attr.bWarrantyThreshold
Exit For
End If
Next j
End If
Next i
End Function

Private Function GetSmartVersion(ByVal hDrive As Long, VersionParams
As GETVERSIONOUTPARAMS) As Boolean
Dim cbBytesReturned As Long
GetSmartVersion = DeviceIoControl(hDrive, _
DFP_GET_VERSION, ByVal 0&, 0, _
VersionParams, _
Len(VersionParams), _
cbBytesReturned, ByVal 0&)
End Function

Public Function GetDriveInfo(DriveNum As IDE_DRIVE_NUMBER) As
DRIVE_INFO
Dim hDrive As Long
Dim VerParam As GETVERSIONOUTPARAMS
Dim cb As Long

di.bDriveType = 0
di.NumAttributes = 0

ReDim di.Attributes(0)

hDrive = OpenSmart(DriveNum)
If hDrive = INVALID_HANDLE_VALUE Then Exit Function
If Not GetSmartVersion(hDrive, VerParam) Then Exit Function
If Not IsBitSet(VerParam.bIDEDeviceMap, DriveNum) Then Exit
Function
di.bDriveType = 1 + Abs(IsBitSet(VerParam.bIDEDeviceMap, DriveNum
+ 4))
If Not CheckSMARTEnable(hDrive, DriveNum) Then Exit Function
FillAttrNameCollection
Call IdentifyDrive(hDrive, IDE_ID_FUNCTION, DriveNum)
Call ReadAttributesCmd(hDrive, DriveNum)
Call ReadThresholdsCmd(hDrive, DriveNum)
GetDriveInfo = di
CloseHandle hDrive
Set colAttrNames = Nothing
End Function

Private Function IsWindowsNT() As Boolean
Dim verinfo As OSVERSIONINFO
verinfo.dwOSVersionInfoSize = Len(verinfo)
If (GetVersionEx(verinfo)) = 0 Then Exit Function
If verinfo.dwPlatformId = 2 Then IsWindowsNT = True
End Function

Private Function IsBitSet(iBitString As Byte, ByVal lBitNo As Integer)
As Boolean
If lBitNo = 7 Then
IsBitSet = iBitString < 0
Else
IsBitSet = iBitString And (2 ^ lBitNo)
End If
End Function

Private Function SwapStringBytes(ByVal sIn As String) As String
Dim sTemp As String
Dim i As Integer
sTemp = Space(Len(sIn))
For i = 1 To Len(sIn) - 1 Step 2
Mid(sTemp, i, 1) = Mid(sIn, i + 1, 1)
Mid(sTemp, i + 1, 1) = Mid(sIn, i, 1)
Next i
SwapStringBytes = sTemp
End Function

Public Sub FillAttrNameCollection()
Set colAttrNames = New Collection
With colAttrNames
.Add "ATTR_INVALID", "0"
.Add "READ_ERROR_RATE", "1"
.Add "THROUGHPUT_PERF", "2"
.Add "SPIN_UP_TIME", "3"
.Add "START_STOP_COUNT", "4"
.Add "REALLOC_SECTOR_COUNT", "5"
.Add "READ_CHANNEL_MARGIN", "6"
.Add "SEEK_ERROR_RATE", "7"
.Add "SEEK_TIME_PERF", "8"
.Add "POWER_ON_HRS_COUNT", "9"
.Add "SPIN_RETRY_COUNT", "10"
.Add "CALIBRATION_RETRY_COUNT", "11"
.Add "POWER_CYCLE_COUNT", "12"
.Add "SOFT_READ_ERROR_RATE", "13"
.Add "G_SENSE_ERROR_RATE", "191"
.Add "POWER_OFF_RETRACT_CYCLE", "192"
.Add "LOAD_UNLOAD_CYCLE_COUNT", "193"
.Add "TEMPERATURE", "194"
.Add "REALLOCATION_EVENTS_COUNT", "196"
.Add "CURRENT_PENDING_SECTOR_COUNT", "197"
.Add "UNCORRECTABLE_SECTOR_COUNT", "198"
.Add "ULTRADMA_CRC_ERROR_RATE", "199"
.Add "WRITE_ERROR_RATE", "200"
.Add "DISK_SHIFT", "220"
.Add "G_SENSE_ERROR_RATEII", "221"
.Add "LOADED_HOURS", "222"
.Add "LOAD_UNLOAD_RETRY_COUNT", "223"
.Add "LOAD_FRICTION", "224"
.Add "LOAD_UNLOAD_CYCLE_COUNTII", "225"
.Add "LOAD_IN_TIME", "226"
.Add "TORQUE_AMPLIFICATION_COUNT", "227"
.Add "POWER_OFF_RETRACT_COUNT", "228"
.Add "GMR_HEAD_AMPLITUDE", "230"
.Add "TEMPERATUREII", "231"
.Add "READ_ERROR_RETRY_RATE", "250"
End With
End Sub
'********************END OF BAS MODULE********************

'In the example assume a label called label2 on a form, could easily
be a
'string etc etc....

'Add the following to your code:

' Dim drv_info As DRIVE_INFO
'
' drv_info = GetDriveInfo(0)
' With drv_info
' If .bDriveType = 0 Then Label2.Caption = "[Not present]"
' If .bDriveType = 2 Then Label2.Caption = "[ATAPI drive - info
not available]"
' If .bDriveType = 1 Then
' Label2.Caption = Trim(.SerialNumber)
' End If
' End With
'
'Label2 will display the actual physical serial number of the drive,
NOT the
'volume number.

Jul 17 '05 #9

P: n/a
- sadly it is not supposed to work for NT, XP etc
Yes, I thought that memory range was off-limits in NT.
I suppose it's a good idea to wear a helmet when bike-riding
(or a WMI class when accessing system info.) but it does take
some of the fun out of it.
- also it is really MoveMemory in Drag (example below)

However looking for it got me here:

http://www.xbeat.net/vbspeed/i_VBVM6...l#Introduction


I hadn't thought of it being the same idea as MoveMemory;
that makes sense. I'd also never thought to research it, so thanks
to you, too! I downloaded that page. It's the only reference to GetMem1
that I've ever seen aside from the code snippet I had.

Jul 17 '05 #10

P: n/a
On Sun, 10 Aug 2003 13:52:58 GMT, "mayayana"
<ma*******@mindspring.com> wrote:

<snip>
I hadn't thought of it being the same idea as MoveMemory;
that makes sense. I'd also never thought to research it, so thanks
to you, too! I downloaded that page. It's the only reference to GetMem1
that I've ever seen aside from the code snippet I had.


For quite some time I have been trying to find the 'undocumented' VB
functions/subs

- that page looks as if it might have some more stuff in it
- but right now I've filed it for 'when sober'

Thanks - that was a good pointer
Jul 17 '05 #11

P: n/a
On Sun, 10 Aug 2003 16:28:47 +0200, "R.Wieser"
<rw***************@xs4all.nl> wrote:

<snip>
I've stored the (integral) message in my snippets-directory, to be found if
I ever need it :-)

Thanks for sharing it.

Regards,
Rudy Wieser


As did I, be careful using it ....
Jul 17 '05 #12

P: n/a
J French <er*****@nowhere.com> schreef in berichtnieuws
3f***************@news.btclick.com...

Hello J,
On Sun, 10 Aug 2003 16:28:47 +0200, "R.Wieser"
<rw***************@xs4all.nl> wrote:

<snip>
I've stored the (integral) message in my snippets-directory, to be found ifI ever need it :-)

Thanks for sharing it.

Regards,
Rudy Wieser


As did I, be careful using it ....


I will. I've stored the whole message, including the warning therein.
Whenever I will read the message I will read your warning too :-)

Regards,
Rudy Wieser

Jul 17 '05 #13

P: n/a
By the way I use SmartVSD.VXD on Windows XP without any problems, but for
some reason on Windows 98 SE I always get -1 (Invalid handle).
Any idea why?

André

P.S. Oops I think I previously sent this to the wrong address. Sorry for
that if you recognize yourself.
"J French" <er*****@nowhere.com> wrote in message
news:3f**************@news.btclick.com...

Totally agreed, but that sounds like the API Samuel Hon was thinking
about

The only other method I've heard of, is for SMART complient drives

Private Function OpenSmart(drv_num As IDE_DRIVE_NUMBER) As Long
If IsWindowsNT Then
OpenSmart = CreateFile("\\.\PhysicalDrive" _
& CStr(drv_num), _
GENERIC_READ Or GENERIC_WRITE, _
FILE_SHARE_READ Or FILE_SHARE_WRITE, _
ByVal 0&, OPEN_EXISTING, 0, 0)
Else
OpenSmart = CreateFile("\\.\SMARTVSD", _
0, 0, ByVal 0&, CREATE_NEW, 0, 0)
End If
End Function

And then do some hefty DeviceIOControl

Jul 17 '05 #14

P: n/a
On Sun, 10 Aug 2003 15:26:23 -0400, "André Joubert"
<ja****@sympatico.ca> wrote:
By the way I use SmartVSD.VXD on Windows XP without any problems, but for
some reason on Windows 98 SE I always get -1 (Invalid handle).
Any idea why?

André

P.S. Oops I think I previously sent this to the wrong address. Sorry for
that if you recognize yourself.


You definitely need a different .VXD for 95/98
- that may be the problem

- the other thing is the CreateFile

Private Function OpenSmart(drv_num As IDE_DRIVE_NUMBER) As Long
If IsWindowsNT Then
OpenSmart = CreateFile("\\.\PhysicalDrive" _
& CStr(drv_num), _
GENERIC_READ Or GENERIC_WRITE, _
FILE_SHARE_READ Or FILE_SHARE_WRITE, _
ByVal 0&, OPEN_EXISTING, 0, 0)
Else
OpenSmart = CreateFile("\\.\SMARTVSD", _
0, 0, ByVal 0&, CREATE_NEW, 0, 0)
End If
End Function

It is also possible that your 95/98 drive does not support SMART
- one of my drives certainly does not
- oddly enough it is the older one ....
Jul 17 '05 #15

P: n/a
On Mon, 11 Aug 2003 09:33:47 -0400, "André Joubert"
<ja****@sympatico.ca> wrote:
I am using the same code as you proposed.
The invalid handle comes from the createfile.
Is there a place where I could get good explanations
on the use of CREATEFILE. I am also interested to
know if it can be used to communicate between 2
programs and if so how.
André
P.S. In the mean time I will look for a different .VXD


Post again tomorrow
Jul 17 '05 #16

P: n/a
On Mon, 11 Aug 2003 09:33:47 -0400, "André Joubert"
<ja****@sympatico.ca> wrote:
I am using the same code as you proposed.
The invalid handle comes from the createfile.
Is there a place where I could get good explanations
on the use of CREATEFILE. I am also interested to
know if it can be used to communicate between 2
programs and if so how.
André
P.S. In the mean time I will look for a different .VXD


The best _initial_ source of info on CreateFile is the Win32
Programmer's Reference Help File

After that the Microsoft site

The error you are getting is: INVALID_HANDLE_VALUE

You need to look at Error.LastDllError to get more info

I would not use CreateFile to communicate between two programs,
Perhaps if you post how you want the communication to work ...
Jul 17 '05 #17

P: n/a
Thank you for this valuable information.

My question about communications between 2
programs came up because in the description
of CREATEFILE it says that it can be used to
open pipes. I am using pipes with another operating
system (FLEXOS) to communicate between programs
and I was wondering if CREATEFILE could do the same
thing. I don't have a need for it at this moment.

André
"J French" <er*****@nowhere.com> wrote in message
news:3f**************@news.btclick.com...
On Mon, 11 Aug 2003 09:33:47 -0400, "André Joubert"
<ja****@sympatico.ca> wrote:
I am using the same code as you proposed.
The invalid handle comes from the createfile.
Is there a place where I could get good explanations
on the use of CREATEFILE. I am also interested to
know if it can be used to communicate between 2
programs and if so how.
André
P.S. In the mean time I will look for a different .VXD


The best _initial_ source of info on CreateFile is the Win32
Programmer's Reference Help File

After that the Microsoft site

The error you are getting is: INVALID_HANDLE_VALUE

You need to look at Error.LastDllError to get more info

I would not use CreateFile to communicate between two programs,
Perhaps if you post how you want the communication to work ...

Jul 17 '05 #18

P: n/a
Again thanks,
I found the problem. For non NT windows the
SMARTVSD.VXD driver has to be moved from windows\system
to windows\system\iosubsys in order to be loaded properly.
I did and it solved the problem
André
"J French" <er*****@nowhere.com> wrote in message
news:3f**************@news.btclick.com...
On Sun, 10 Aug 2003 15:26:23 -0400, "André Joubert"
<ja****@sympatico.ca> wrote:
By the way I use SmartVSD.VXD on Windows XP without any problems, but for
some reason on Windows 98 SE I always get -1 (Invalid handle).
Any idea why?

André

P.S. Oops I think I previously sent this to the wrong address. Sorry for
that if you recognize yourself.


You definitely need a different .VXD for 95/98
- that may be the problem

- the other thing is the CreateFile

Private Function OpenSmart(drv_num As IDE_DRIVE_NUMBER) As Long
If IsWindowsNT Then
OpenSmart = CreateFile("\\.\PhysicalDrive" _
& CStr(drv_num), _
GENERIC_READ Or GENERIC_WRITE, _
FILE_SHARE_READ Or FILE_SHARE_WRITE, _
ByVal 0&, OPEN_EXISTING, 0, 0)
Else
OpenSmart = CreateFile("\\.\SMARTVSD", _
0, 0, ByVal 0&, CREATE_NEW, 0, 0)
End If
End Function

It is also possible that your 95/98 drive does not support SMART
- one of my drives certainly does not
- oddly enough it is the older one ....

Jul 17 '05 #19

P: n/a
In an other NG some was looking for HDD serial number and it was suggested
to try a driver that can be found on a site. I when to that site and
downloaded the driver. On the the same site (I don,t have the reference on
hand) there were some links on how to build a driver. On of the links was
about SMART driver and sent me to MSDN. I went there and there was a
document in the KB that describe the problem.
André
P.S. here is the reference

http://www.winsim.com/diskid32/diskid32.html
"J French" <er*****@nowhere.com> wrote in message
news:3f**************@news.btclick.com...
On Tue, 12 Aug 2003 12:54:55 -0400, "André Joubert"
<ja****@sympatico.ca> wrote:
Again thanks,
I found the problem. For non NT windows the
SMARTVSD.VXD driver has to be moved from windows\system
to windows\system\iosubsys in order to be loaded properly.
I did and it solved the problem
André


Good tip - how did you find the solution ?

Jul 17 '05 #20

P: n/a
On Wed, 13 Aug 2003 19:21:16 -0400, "André Joubert"
<ja****@sympatico.ca> wrote:
In an other NG some was looking for HDD serial number and it was suggested
to try a driver that can be found on a site. I when to that site and
downloaded the driver. On the the same site (I don,t have the reference on
hand) there were some links on how to build a driver. On of the links was
about SMART driver and sent me to MSDN. I went there and there was a
document in the KB that describe the problem.
André
P.S. here is the reference

http://www.winsim.com/diskid32/diskid32.html


Gottit - thanks - that is one to remember !
Jul 17 '05 #21

P: 1
Hi, I'm a newbie to programming of any kind. I have posted this to other
groups in a hope to get a response from anyone.

Can any one tell me how to make my VB program read the Bios serial number
(or would HDD be better, or both?) and put that info into VB prog so the
program won't work on another computer. My program uses an MSAccess table.

Much appreciated if you can help!

Thanks
Gavin

Gavin

following the routine for your request

Sub serial()

drvpath = "c:"

Dim fs, d, s, t
Set fs = CreateObject("Scripting.FileSystemObject")
Set d = fs.GetDrive(fs.GetDriveName(fs.GetAbsolutePathName (drvpath)))
Select Case d.DriveType
Case 0: t = "Desconocido"
Case 1: t = "Separable"
Case 2: t = "Fijo"
Case 3: t = "Red"
Case 4: t = "CD-ROM"
Case 5: t = "Disco RAM "
End Select
s = "Unidad " & d.DriveLetter & ": - " & t

' this is a comment next line print out the hdd serial number

s = s & vbCrLf & "NS: " & d.serialnumber
MsgBox s
End Sub
Oct 13 '05 #22

This discussion thread is closed

Replies have been disabled for this discussion.