How do I convert Hexadecimal to String in VB.NET

[SuperNovaa41]

I'm making a decoding app, and I made a Hexadecimal decoder, and now I need it to convert into text.
Here is my code to convert: Try

Sub convertHex()
         Dim byteArray() As Byte
         Dim hexNumbers As System.Text.StringBuilder = New System.Text.StringBuilder
 
         byteArray = System.Text.ASCIIEncoding.ASCII.GetBytes(input.Text)
 
        For i As Integer = 0 To byteArray.Length - 1
         hexNumbers.Append(byteArray(i).ToString("x"))
         Next
         output.Text = hexNumbers.ToString()
    Catch ex As Exception
        MessageBox.Show(ex.Message, Me.Text, MessageBoxButtons.OK, MessageBoxIcon.Error)
    End Try
End Sub

Now how do I convert it back into text?

[Luuk]

        Dim hexadecimalstring As String
        For x = 1024 To 1035
            hexadecimalstring = Hex(x).ToString()
            Console.WriteLine("{0} = {1}", hexadecimalstring, Convert.ToInt32(hexadecimalstring, 16).ToString())
        Next x
 

The 'Convert.ToInt32(hexadecimalstring, 16)' will make a integer from the string
Adding '.ToString()' wil make that a string again...

[SuperNovaa41]

I'm using WinForms so would I do

output.Text = "{0} = {1}", hexadecimalstring, Convert.ToInt32(hexadecimalstring, 16).ToString()

?

[Luuk]

no, try:

output.Text = Convert.ToInt32(hexadecimalstring, 16).ToString()
 

[SuperNovaa41]

Actually, that doesn't work. I changes it into 1035. Even if the textbox is empty.

[IronRazer]

When you read the string into a byte array the numbers will be between 0 and 255. Those numbers in Hex would be between 0 and FF.

If you notice, they are not always 2 characters long. 0 through 9 would throw it off being you are appending the hex strings one after the other leaving no way to tell where to split the hex values up when you need to convert them back to byte values 0 through 255.

You can fix that by padding the left with zeros "0" so that every Hex value would be 2 characters long. Then, you can read the hex string 2 characters at a time, convert that back to a Byte value and add it to an Array or List of bytes.

Then use the System.Text.Encoding.ASCII.GetString() method to convert the bytes back into a String. It is basically the same process you do to convert the String to Hex except, in reverse.

Try this in a new form project with 3 textboxes and 2 buttons. Type whatever you want in TextBox1 and press Button1. It converts it to Hex and puts it in TextBox2.

Then press Button2 and it will convert the hex back to the same string and put it in TextBox3.

Public Class Form1
 
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        Dim bts() As Byte = System.Text.Encoding.ASCII.GetBytes(TextBox1.Text)
 
        Dim sb As New System.Text.StringBuilder
        For Each b As Byte In bts
            sb.Append(b.ToString("X").PadLeft(2, "0"c))
        Next
 
        TextBox2.Text = sb.ToString
    End Sub
 
    Private Sub Button2_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button2.Click
        Dim bts As New List(Of Byte)
 
        For x As Integer = 0 To TextBox2.TextLength - 1 Step 2
            bts.Add(CByte(Convert.ToInt32(TextBox2.Text(x) & TextBox2.Text(x + 1), 16)))
        Next
 
        TextBox3.Text = System.Text.Encoding.ASCII.GetString(bts.ToArray)
    End Sub
End Class
 

[Luuk]

My code line #2

For x = 1024 To 1035

is just an example to get some numbers, in my case between 1024 and 1035 (inclusive)....

My line #3

hexadecimalstring = Hex(x).ToString()

converts this number to a hexadecimal string


My line #4

Console.WriteLine("{0} = {1}", hexadecimalstring, Convert.ToInt32(hexadecimalstring, 16).ToString())

converts this string back to a decimal using

Convert.ToInt32(hexadecimalstring, 16)

this deciman is converted to a string:

.ToString()

and finally written to Console, using Console.WriteLine()


which part of this example was unclear?

[SuperNovaa41]

Yes I saw that Luuk, but all it did was put 1035 into the textbox.

[SuperNovaa41]

THANK YOU SO MUCH IronRazer, IT WORKED, and it also helped that you explained it, because I'm not the best at VB.NET. Thank you so much.