How to Auto jump to the next TextBox after the restriction of MaxLength?

[starting]

I am using 5 text boxes and each box enter 2 characters.I enter 2 char and automatically cursor jump to next text box How?
please help me..
thank u..

[IronRazer]

Use each TextBoxes TextChanged event to check if its TextLength is equal to it`s MaxLength which is 2 in your case. If it is then set focus to the next TextBox using the Select or Focus method.

Here is an example of just 3 TextBoxes. You should be able to get the idea and implement this for all 5 of your TextBoxes.

Public Class Form1
 
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        TextBox1.MaxLength = 2
        TextBox2.MaxLength = 2
        TextBox3.MaxLength = 2
    End Sub
 
    Private Sub TextBox1_TextChanged(ByVal sender As Object, ByVal e As System.EventArgs) Handles TextBox1.TextChanged
        If TextBox1.TextLength = TextBox1.MaxLength Then
            TextBox2.Select()
        End If
    End Sub
 
    Private Sub TextBox2_TextChanged(ByVal sender As Object, ByVal e As System.EventArgs) Handles TextBox2.TextChanged
        If TextBox2.TextLength = TextBox2.MaxLength Then
            TextBox3.Select()
        End If
    End Sub
 
    Private Sub TextBox3_TextChanged(ByVal sender As Object, ByVal e As System.EventArgs) Handles TextBox3.TextChanged
        If TextBox3.TextLength = TextBox3.MaxLength Then
            ' select the next textbox
        End If
    End Sub
End Class
 

[starting]

Ok now i got
Thanks for your replay..

[starting]

I saw another one method. There some doubt please help me

Public Class Form1  
 
    Dim MaxLength As Integer = 2  
 
    Private Sub TextBoxes_KeyPress(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyPressEventArgs) Handles TextBox1.KeyPress, TextBox2.KeyPress, TextBox3.KeyPress  
 
        Dim aTextBox As TextBox = CType(sender, TextBox)  
        If aTextBox.Text.Length >= MaxLength Then 
            Select Case aTextBox.Name  
                Case "TextBox1" 
                    TextBox2.Select()  
                Case "TextBox2" 
                    TextBox3.Select()  
                Case "TextBox3" 
                    If TextBox3.Text.Length > MaxLength Then e.Handled = True 
            End Select 
        End If 
 
    End Sub 
End Class 

Here how to create that name function TextBoxes

[IronRazer]

Yes you can use the KeyPress event but, i would use the TextChanged event because, a user could right click and paste 100 characters of text into any of the the textboxes and that would not raise the KeyPress event. The TextChanged event is raised if they type or paste anything in the textboxes.

Also, you don`t need to use a variable for the MaxLength. TextBoxes have a MaxLength property that you can set to 2 which will stop the user from typing or pasting more than 2 characters into them. You can set that in the TextBoxes properties on the Form`s [Design] tab Or you can do it in code like i showed in my first example.

I set the MaxLength property of the 3 textboxes to 2 in the properties on the Design tab for this example.

    Private Sub TextBox_TextChanged(ByVal sender As Object, ByVal e As System.EventArgs) Handles TextBox1.TextChanged, TextBox2.TextChanged, TextBox3.TextChanged
        Dim tb As TextBox = DirectCast(sender, TextBox)
        If tb.TextLength = tb.MaxLength Then
            Select Case tb.Name
                Case "TextBox1"
                    TextBox2.Select()
                Case "TextBox2"
                    TextBox3.Select()
                Case "TextBox3"
                    'data full, you can do whatever now. Maybe you need to set focus to a button or something...
            End Select
        End If
    End Sub
 

[starting]

Thank u for your replay..
Two Doubt this program, please solve this doubt

1)How to create TextBox_TextChanged.In form side came only single text box name (ex: TextBox1_TextChanged or TextBox2_TextChanged).

2)why use DirectCast. what showing DirectCast

[IronRazer]

"1)How to create TextBox_TextChanged.In form side came only single text box name (ex: TextBox1_TextChanged or TextBox2_TextChanged)."

I am not sure what you are asking there.


"2)why use DirectCast. what showing DirectCast"

If you notice, the "sender" parameter of the TextChanged event sub is of type Object. The TextBox that raises the event is assigned to the "sender" Object.

An Object is the base class for all .Net classes, meaning it can be assigned any class. However, an Object type does not let you directly access the specific properties and methods of the class that was assigned to it.

That is why you need to cast the Object to a TextBox type, so you can access the specific properties of the TextBox class that was assigned to the Object.

Using DirectCast is faster and more preferable for instances like this than using the CType operator. You can read the second post down in the link below to get an idea of the difference between DirectCast and CType.

http://stackoverflow.com/questions/3...type-in-vb-net