How to detect selection of a radiobutton in an array

[Bryolm]

I'm fairly new to vb.net. At one time - many years ago I was reasonably competent GFA basic.I have written a basic banking program in vb.net which works well and I am now trying to tidy it up and improve it. At one point in my program I have a set of 5 radiobuttons to make a selection. These were placed on the form and of course there are 5 subs to detect when a selection is made. The result is that I have variable with five possible values which are processed by a 'case select'. Although this works it is a little messy and I would like to do it in far less code. The code below shows an example but I cannot create a sub which will detect and return the array number of the selected radiobutton. Any help would be much appreciated.

Public Class Form1
 
    Dim Choice(4) As RadioButton
    Public X As Integer
 
    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        Call TheButtons()
 
    End Sub
 
    Private Sub TheButtons()
 
        For I = 0 To 4
            Choice(I) = New RadioButton : Choice(I).Parent = Me
            Choice(I).Location = New Point(200, 100 + I * 50) : Choice(I).Text = "Button  " + I.ToString
        Next
 
    End Sub
 
    Private Sub SomeThingOrOther() ' Not clear about what to put here
        For I = 0 To 4
            If Choice(I).Checked = True Then
                X = I ' Captures the array number of the button selected
            End If
        Next
    End Sub
End Class

[!NoItAll]

Well - since you posted code I'm thinking you are not asking people to do your homework for you so...

The trick is to add the index of each button into the Tag property of each button, and then add your own eventhandler for all of the buttons in the array. There will be one event handler for all of your buttons. Do that like this:

For I = 0 to 4
   'put the index into the tag property
   Choice(I).Tag = I.ToString  
   AddHandler Choice(I).Click, AddressOf MyChoice_Click
Next I
 

Now you create a sub called MyChoice_Click

Private Sub MyChoice_Click(Sender as Object, e as Eventargs)
    Select Case CInt(Sender.Tag)
       Case 0
          'Do This
       Case 1
          'Do This
       Case 2
          'Do This
       Case 3
          'Do This
       Case 4
          'Do This
       Case Else
          'handle the error
   End Select
 
End Sub
 

Because the Tag property of each button in the array carries the objects index in the array (because you assigned it with Choice(I).Tag = I.ToString), that tag is now easily readable in the event you set up with the event handler. This allows you to know which radio button was selected and act accordingly.
What you needed to know is that each button you instantiated already had its own click event - so you could assign that to your event handler. Next you needed to know that the signature of the event you created (MyChoice_Click) used the common (Sender as object, e as EventArgs) - and the Sender as Object will contain the Tag property of the object that called the event handler. The Intellisense in VS does not show you the tag property, you have to know its there - and it is because the base Object class in .net contains the Tag property and the Radiobutton is derived from that class.
Hope this helps.
By the way - here's my code for the whole thing:

Public Class Form1
    Private MyButton(4) As RadioButton
 
    Private Sub Form1_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load
        Dim iTop As Integer = 0
        For I = 0 To 4
            iTop += 30
            MyButton(I) = New RadioButton With {.Top = iTop, .Left = 25, .Parent = Me, .Tag = I.ToString}
            Me.Controls.Add(MyButton(I))
            MyButton(I).Show()
            AddHandler MyButton(I).Click, AddressOf MyButton_Click
        Next
    End Sub
 
    Private Sub MyButton_Click(Sender As Object, e As EventArgs)
        Select Case CInt(Sender.tag)
            Case 0
                'Do this
            Case 1
                'Do this
            Case 2
                'Do this
            Case 3
                'Do this
            Case 4
                'Do this
            Case Else
                'handle the error
        End Select
    End Sub
End Class