Implementing a custom control with a typed collection for use at design time.

[David Gluth]

I am having a problem with the Visual Basic property collection editor .

I have created a Custom Type

Public Class Field
         Private Item As Integer
        Private Name As String = "FieldName"
 
          Public Property FieldName() As String
            Get
                Return Name
            End Get
            Set(ByVal value As String)
                Name = value
            End Set
        End Property
End Class
 

And a collection

Public Class Fields
        Inherits CollectionBase
 
        Default Public Property Item(ByVal Index As Integer) As Field
            Get
                Return CType(List.Item(Index), Field)
            End Get
            Set(ByVal value As Field)
                List.Item(Index) = value
            End Set
        End Property
        Public Sub Add(ByVal Item As Field)
            If List.Count = 0 Then
                List.Add(Item)
            Else
                For i = 0 To List.Count - 1
                    Dim myField As New Field
                    myField = List(i)
                    If myField.FieldName = Item.FieldName Then
                        Item.FieldName += "1"
                    End If
                Next
                List.Add(Item)
            End If
        End Sub
 
    End Class
 

My property declaration uses an instance of the collection:

Public TableFields As New Fields
 
    Public Property Evarus_Fields() As Fields
        Get
            Return TableFields
        End Get
        Set(ByVal value As Fields)
            TableFields = value
        End Set
    End Property
 

In the designer I am able to access my class and save the items in the collection, but then entries in the designer are incorrect. The created entry actually causes a syntax error on the command ‘New’

Field1.FieldName = "ColumnA"
New ProjectName.ControlName.Fields.Add(Field1)
 

Modification to the created codes as follows (reference the control instance and the instantiated collection) cures the syntax errors and works as desired.

Field1.FieldName = "ColumnA"
ControlInstanceName.TableFields.Add(Field1)
 

Any ideas about what my coding error is?

[David Gluth]

I have resolved my issue.
I needed to provide a “customized” collection editor for my typed class (Field).

Public Class FieldCollection
        Inherits CollectionEditor
        Public Sub New()
            MyBase.New(GetType(List(Of Field)))
        End Sub
    End Class
 

And then supplied an attribute to the collection property instructing it to use this editor.

<Editor(GetType(FieldCollection), GetType(UITypeEditor))> _
    <DesignerSerializationVisibility(DesignerSerializationVisibility.Content)> _
    <Description("Fields Collection")> _
    <Category("Behaviour")> _
    Public Property Evarus_Fields() As Fields
        Get
            If TableFields Is Nothing Then
                TableFields = New Fields
            End If
            Return TableFields
        End Get
        Set(ByVal value As Fields)
            TableFields = value
        End Set
    End Property