"dj" <dj@discussions.microsoft.com> wrote in message
news:31**********************************@microsof t.com...
:
: I know seasoned OOP-savvy developers will roll their eyes at this one,
: but can anyone provide a clear explanation as to *why* one would need
: to use an Interface in a VB.NET application?
:
: Every book and article I seem to run across jumps right into "and
: here's how Interfaces are implemented..." followed by a block of
: meaningless (to me) code without explaining why this is being used
: in the first place. e.g. Why not use a Class object?
:
: TIA,
: dj
Interfaces are not intended to be used directly - rather, they describe
the behavior and traits a class implementing the interface can be
expected to exhibit. They do not provide their own implemention details
however, which is what differentiates them from classes or structures.
According to the documentation:
"Interfaces are reference types that other types implement
to guarantee that they support certain operations. An interface
is never directly created and has no actual representation - other
types must be converted to an interface type.
"An interface defines a contract. A class or structure that
implements an interface must adhere to its contract."
If a class implements a given interface, it can be treated as an
instance of that interface by anything that needs to use it. The example
that follows is a little contrived, but it is loosely based on an actual
situation I had to deal with once.
In this case, I want a component that can process different types of
payments. To do this, I've defined a generic payment handler interface
that defined a single method: process payment. Three separate classes
implement this interface: a credit card payment handler, a check payment
handler and a cash payment handler. These classes handle the actual
details for processing the different payment types.
When a payment is submitted, a single class is available that handles
all payments regardless of type. Consumers of the class don't need to
worry about having to call one class for credit card payments, another
for checks and a third for cash. They simply call a single class that
handles all of the details. If I decide to add another type of payment
in the future (e.g.: money orders), existing consumers of the class
won't be impacted.
This exposed class in turn checks the payment type and calls the
appropriate child class. Since each of the child classes implement the
payment handler interface, I can use a single type that calls the
process payment function of the appropriate payment handler.
Hopefully the code example below will clear this up a bit (please
forgive the use of line continuation characters - they are there get the
code to display correctly in this format):
'-----------------------------------------------
Option Strict
Imports Microsoft.VisualBasic
Imports System
Imports System.XML
Public Module [module]
Public Sub Main
Dim Details As String
Dim PH As New PaymentHandler
Details = "<Request>" _
& "<Payment Type='CreditCard'/>" _
& "<CCDetails />" _
& "</Request>"
PH.ProcessPayment(details)
Details = "<Request>" _
& "<Payment Type='Check'/>" _
& "<CheckDetails />" _
& "</Request>"
PH.ProcessPayment(details)
Details = "<Request>" _
& "<Payment Type='Cash'/>" _
& "<CashDetails />" _
& "</Request>"
PH.ProcessPayment(details)
End SUb
End Module
Public Class PaymentHandler
'XML String with payment details
'Available Types = "CreditCard", "Check", "Cash"
'
'<Request>
' <Payment Type="" Date="" Amount=""/>
'
' <!-- As appropriate below -->
' <CCDetails Name="" Type="" Number="" Expires="" Date="" Amount=""/>
' <CheckDetails Routing="" Account="" Number="" Date="" Amount=""/>
' <CashDetails Date="" Amount=""/>
'
'</Request>
'
Public Sub ProcessPayment(Details As String)
Dim PaymentType As String
Dim PmtHandler As IPaymentHandler
With New XMLDocument
.LoadXML(Details)
PaymentType = _
.SelectSingleNode( _
"/Request/Payment/@Type").InnerText
'*************************************************
Select Case PaymentType
Case "CreditCard"
PmtHandler = New CCPaymentHandler
Case "Check"
PmtHandler = New CheckPaymentHandler
Case "Cash"
PmtHandler = New CashPaymentHandler
End Select
'*************************************************
End With
PmtHandler.ProcessPayment(Details)
End Sub
Private Class CCPaymentHandler
Implements IPaymentHandler
Private Sub ProcessPayment( _
Details As String) _
Implements IPaymentHandler.ProcessPayment
Console.WriteLine("Process CreditCard")
End Sub
End Class
Private Class CheckPaymentHandler
Implements IPaymentHandler
Private Sub ProcessPayment( _
Details As String) _
Implements IPaymentHandler.ProcessPayment
Console.WriteLine("Process Check")
End Sub
End Class
Private Class CashPaymentHandler
Implements IPaymentHandler
Private Sub ProcessPayment( _
Details As String) _
Implements IPaymentHandler.ProcessPayment
Console.WriteLine("Process Cash")
End Sub
End Class
Private Interface IPaymentHandler
Sub ProcessPayment(Details As String)
End Interface
End Class
'-----------------------------------------------
Ralf
--
----------------------------------------------------------
* ^~^ ^~^ *
* _ {~ ~} {~ ~} _ *
* /_``>*< >*<''_\ *
* (\--_)++) (++(_--/) *
----------------------------------------------------------
There are no advanced students in Aikido - there are only
competent beginners. There are no advanced techniques -
only the correct application of basic principles.
