help to print data with their corresponding value

[pallabtrue]

Hi I have two files. One file contains all my interested uniprot id and second file contains uniprot ID with their corresponding family. My aim or I am trying to create new file.

So from file1, I want compare all Id with file2's Id. If equal then they should print id with their family name or not equal then they should print their id with 'None' word.

I uploaded, File1 which contains uniprot Id.
File2 which contains uniprot Id and family name.
File3 is my desired output file.
I tried to write script for it and that is
#!/usr/bin/perl -w

use strict;



my $outfile = 'file3.txt';
open (OUTFILE, ">$outfile") or die "Cannot open $outfile for writing \n";







open (PM,"./file1.txt");
my @uniprot = <PM>;
close (PM);

my @col;


while (my $line = <>)
{
@col = split(/\s+/,$line);
print $col[1],"\n";
for (my $i=0; $i<@uniprot; $i++)
{
chomp $uniprot[$i];

print OUTFILE $uniprot[$i],"\t";
if ($uniprot[$i] eq $col[0]) {
print OUTFILE $col[1],"\n";
}
elsif ($uniprot[$i] ne $col[0]) {
print OUTFILE "None \n";
}
}
}

#print OUTFILE @uniprot;


close (OUTFILE);

Although its not working at all.

If anyone kindly help me I will be grateful to you.

Thank you in advance.

cheers
pallab

[RonB]

Use a HoA (hash of arrays) instead of individual arrays.

Process file1 first and use its content as the hash keys. As you process file2, split the line into its 2 fields and push field 2 onto the HoA, using field1 for the key.

Once the data is loaded into the HoA, loop over it and test if the key has a value, if it does, then output the data. If it doesn't have a value, then output the "None" line.

[pallabtrue]

@RonB
Thank you so much for your quick reply. I am not sure about this hash of array because I didn't use it before !! :( But if you kindly give some out structure of your idea in code language(perl) may be I will try to crack that.

[pallabtrue]

@RonB
I tried to write programme for HOA and its working for file2.txt only because I didn't get the idea about 2nd part of your suggestion, how to compare file1.txt and file2.txt.

#!/usr/bin/perl -w

use strict;




my @col;



my %HoA = (
$col[0] => [ $col[1] ],
);

while (my $line = <>)
{

#print OUTFILE $fam[$j],"\n";
@col = split(/\s+/,$line);

push @{ $HoA{$col[0]} },$col[1];


}

for my $family ( keys %HoA ) {
print "$family: @{ $HoA{$family} }\n";
}

----output-----

Q9ULV8: CBL
Use of uninitialized value in join or string at compare.pl line 28, <> line 10.
:
P22681: CBL GOLIATH IAP TRAF TRIM/RBCC
Q13191: CBL GOLIATH IAP PRAJA
---------------------
of course there is error which I am trying to fix it still now!!!

Thank you in advance for you further suggestion. :)

[pallabtrue]

@RonB
I wrote new programme and its working perfectly what I want but there is some error still now

#!/usr/bin/perl -w

use strict;



my %H;
my @col;
my %HoA = (
$col[0] => [ $col[1] ],
);


open (PN,"./file1.txt");
my @fam = <PN>;
close (PN);

for (my $i=0; $i<@fam; $i++) {
chomp $fam[$i];
%H = (
$fam[$i] => 'None',
);

}
while (my $line = <>)
{

@col = split(/\s+/,$line);

push @{ $HoA{$col[0]} },$col[1];

}

for my $family ( keys %HoA ) {
print "$family \t @{ $HoA{$family} }\n";
}



for ( keys %H ) {
unless ( exists $HoA{$_} ) {
print "$_ \t None \n";
next;
}
}


-----OUTPUT------
Use of uninitialized value in list assignment at compare.pl line 9.
Q9ULV8 CBL
Use of uninitialized value in join or string at compare.pl line 35, <> line 10.

P22681 CBL GOLIATH IAP TRAF TRIM/RBCC
Q13191 CBL GOLIATH IAP PRAJA
O00463 None

----------

Thank You again :)

[RonB]

#!/usr/bin/perl
 
use strict;
use warnings;
 
my %data;
 
# initialize the hash keys with data in file1
my $file1 = 'file1.txt';
open my $fh1, '<', $file1 or die "failed to open '$file1' $!";
while ( my $id = <$fh1> ) {
    chomp $id;
    $data{$id} = undef;
}
close $fh1;
 
# assign hash values with data in file2
my $file2 = 'file2.txt';
open my $fh2, '<', $file2 or die "failed to open '$file2' $!";
while ( my $line = <$fh2> ) {
    chomp $line;
    my ($id, $family) = split /\s+/, $line;
    next unless exists $data{$id};
    push @{$data{$id}}, $family;
}
close $fh2;
 
# output the data to file3
my $file3 = 'file3.txt';
open my $fh3, '>', $file3 or die "failed to open '$file3' $!";
foreach my $id ( sort keys %data ) {
    print $fh3 "$id ";
    if ( $data{$id} ) {
        print $fh3 join(',', @{$data{$id}}), "\n";
    }
    else {
        print $fh3 "None\n";
    }
}
close $fh3;
 

[pallabtrue]

@RonB
Thanks for your help and specially giving idea how to use HoA and which is really good for me and I will use it in future. :)