Sort function

[yjulien]

Hi,

I'm trying to use the sort function without success up to now. I'm opening a file and wish to reverse sort on the first field "$users_fields[0]" and then print the output found in the IF statement.

Can you help?

Thanks,

Here is the code, which print the entire file not sorted:

open (VENTE_DATABASE, "<$path/data/a_a_vendre.data");
 
 while (<VENTE_DATABASE>) {
  $primeurs = $_;
   chop $primeurs;
   @users_fields = split (/\|/, $primeurs);
 
 if ($users_fields[10] > "0") {    print  "$users_fields[10]<br> $users_fields[24]<br> $users_fields[16], $users_fields[15], $users_fields[14]<br> $users_fields[28] $users_fields[143]<p>" ;  }
 
 }   # End of while (<VENTE_DATABASE>)
 
close (VENTE_DATABASE);

[miller]

A few thoughts concerning your script first. You should always use chomp instead of chop unless there's a specific reason why you need chop.

Second, you really need use strict; and use warnings; Yes it requires a little more time at the start, but it's always worth the investment.

Anyway, if you want to sort your results, you'll need to cache them so you can apply sort at the end. Here's how I would modify your script:

use strict;
use warnings;
 
my $vdfile = "$path/data/a_a_vendre.data";
 
open my $fh, $vd or die "Can't open $vdfile: $!";
 
my @matched;
 
while (<$fh>) {
    chomp;
    my @users_fields = split /\|/;
 
    if ($users_fields[10] > "0") {
        push @matched, \@users_fields;
    }
}   # End of while (<$fh>)
 
close $fh;
 
for (sort {$a->[0] <=> $b->[0]} @matched) {
    print  <<"END_PRINT";
<p>$_->[10]<br>
$_->[24]<br>
$_->[16], $_->[15], $_->[14]<br>
$_->[28] $_->[143]</p>
END_PRINT
 

Note, concerning your html, it looks like your using <p> to denote the end of a paragraph. This isn't proper. Instead use <p> ... </p> to enclose the paragraph, and you can use <br> within those tags for extra formatting.

- Miller

[yjulien]

Thanks again Miller !

I did not use strick and warning because this script is already part of a much bigger one.

I will try this and let you know.

Thanks you again.

yves

[yjulien]

Hi again Miller,

You wrote :

my $vdfile = "$path/data/a_a_vendre.data";
 
open my $fh, $vd or die "Can't open $vdfile: $!"; 
 

Should it not be:

my $vdfile = "$path/data/a_a_vendre.data";
 
open my $fh, $vdfile or die "Can't open $vdfile: $!"; 
 

[yjulien]

Hi Miller,

I got the code working. There was a " } " missing at the end.

One more question, how can we sort on more then 1 field? Say I want to sort on field $a->[0] & on field $a->[1]? Is it possible to double sort without modifying the code too much? Is there some kind of loop within a loop strategy possible?

Thanks,

Yves

[yjulien]

@yjulien
Never mind Miller, I found it! :D

for (sort {$b->[11] <=> $a->[11] or $b->[0] <=> $a->[0]} @matched) {
    print  <<"END_PRINT";
<p>$_->[10]<br>
$_->[24]<br>
$_->[16], $_->[15], $_->[14]<br>
$_->[28] $_->[143]</p>
END_PRINT

Quite neat and simple!

[miller]

Good job mate, that looks right.

Sorry I didn't respond to your earlier posts, but I was on a vacation myself.

Until next time,
- Miller