Not able to copy all the files using perl

[rajesh dogra]

Hi All,

i am trying to move a bunch of files in a newly created directory: here is what i am trying to do.

: i read my source dir.
: i search for a file which has the folder name information in it. This file is in the source folder.
: i create that folder.
: copy all the files from source dir in the new folder.

Now every thing goes fine except for the last piece which is copy. when i check the folder after running the script i get only one file which is the one i searched in the source folder.

i want to copy all the files in the source folder to the newly created folder. Kindly help.

this is what i have written so far, its not neat but i have tried :

 
#!/usr/bin/perl
use File::Find;
use File::Copy;
my $dir = "/ctm/ctms/ctm_server/tmp/";
my $myfile="cobrun_date.txt";
opendir(DIR, $dir) or die "Can't open $dir: $!";
my @files = grep {!/^\.+$/} readdir(DIR);
closedir DIR;
my @kill= grep(/cobrun_date\.txt/, @files);
if ($myfile == $kill[0])
{
print "the match is found\n";
open (FILE, $myfile) or die "Can't Open the file $myfile:$!";
my @filedata=<FILE>;
chomp($filedata[0]);
$path = $dir.$filedata[0];
print "$path \n";
mkdir($path, 0777) or die "Couldnt create dir $path : $!";
close FILE;
foreach $f (@files)
{
print "The file name is :$f\n";
if ( -f $f ){
copy("$f","$path") or die "Copy Failed : $!";
print "The file have been moved \n";
}}
}
else
{
print "the match is not found\n";
}
 
 

[miller]

I see one major flaw in your code, and that lies with this line:

if ($myfile == $kill[0]) {

You're using the numerical equality check '==' instead of string equality 'eq'. This will always evaluate as true because each of the strings will be treated as 0 for the equality test. Therefore you could end up processing a file that doesn't actually exist.

Anyway, the following is probably closer to what you want. I leave it to you to setup error checking for the case where the files you are moving already exist at their destination

#!/usr/bin/perl
 
use File::Copy;
use File::Spec;
 
use strict;
 
my $dir = "/ctm/ctms/ctm_server/tmp/";
my $myfile = 'cobrun_date.txt';
 
my $path = File::Spec->catfile($dir, $myfile);
 
if (! -e $path) {
    die "$path does not exist\n";
}
 
my $destdir = do {
    open my $ih, $path or die "Can't open file, $path: $!";
    my $subdir = <$ih>; # Only retrieves first line
    chomp($subdir);
    File::Spec->catpath($dir, $subdir);
};
 
if (! -e $destdir) {
    mkdir($destdir, 0777) or die "Can't mkdir $destdir: $!";
}
 
opendir my $dh, $dir or die "Can't opendir $dir: $!";
while (my $file = readdir $dh) {
    next if $file =~ /^\.+$/;
    my $fromfile = File::Spec->catfile($dir, $file);
    if (-f $fromfile) {
        my $tofile = File::Spec->catfile($destdir, $file);
        copy($fromfile, $tofile) or die "Copy failed $fromfile->$tofile: $!";
        print "$file copied $dir -> $destdir\n";
    }
}
closedir $dh;
 
1;
 
__END__
 

- Miller

[rajesh dogra]

Thanks Miller, for your reply to me. but the below section of the code doesnt do what it should do.

opendir my $dh, $dir or die "Can't opendir $dir: $!";
while (readdir $dh) {
    next if /^\.+$/;
print "$dh\n";
    my $fromfile = File::Spec->catpath($dir, $_);
    if (-f $fromfile) {
        my $tofile = File::Spec->catpath($destdir, $_);
        copy($fromfile, $tofile) or die "Copy failed $fromfile->$tofile: $!";
        print "$_ copied $dir -> $destdir\n";
    }
}
closedir $dh;
 

This is simply printing the following :

GLOB(0x91a83c8)
GLOB(0x91a83c8)
GLOB(0x91a83c8)
GLOB(0x91a83c8)
GLOB(0x91a83c8)
GLOB(0x91a83c8)
GLOB(0x91a83c8)
GLOB(0x91a83c8)
GLOB(0x91a83c8)
GLOB(0x91a83c8)


where as it should give the file names and copy them to the destination dir.

thanks.

Rajesh

[miller]

Sorry Rajesh, I've helped you as much as I can. It's up to you to take the time to learn what the code that I provided for you is doing so that you can debug it yourself or ask more intelligent questions than, "It doesn't work".

As for why it's printing out "GLOB(0x91a83c8)" repeatedly, well that's because you added a print statement for $dh, which is a directory handle. If you wanted to print out the filenames, you should use the in place variable $_.

Good luck, and we'll be here if you have specific problems, but it looks like you need to do some reading at http://perldoc.perl.org first.

- Miller