How to access an element in a hash of references?

[traravind]

Hi ,
I am new to Perl and have some trouble in accessing elements stored in a hash. For example, if I have a has structure with the following data elements

rank_filename = (
    '535.714285714286' => [
        [2,'535.714285714286','3','5','rep_Ara_2','Arav'],
        [3,'535.714285714286','4','5','rep_Ara_12','Ara']
    ],
    '642.857142857143' => [
        [1,'642.857142857143','3','6','rep_Ara_1','Ara']
    ]
);
 

how do I access the elements in the list stored in the hash? Can I access the array inside each key in the hash and store them into another array?

Thanks in advance!

[KevinADC]

assuming rank_filename is a reference itself, here is how you could loop through the whole data structure:

foreach my $key ( keys %{ $rank_filename } ) {
   foreach my $i ( @{ $rank_filename{$key} } ) {
      print $i,"\n";
   }
} 

this link should help also:

http://perldoc.perl.org/index-tutorials.html

the first three tutorials discuss references.

[traravind]

assuming rank_filename is a reference itself, here is how you could loop through the whole data structure:

foreach my $key ( keys %{ $rank_filename } ) {
   foreach my $i ( @{ $rank_filename{$key} } ) {
      print $i,"\n";
   }
} 

this link should help also:

http://perldoc.perl.org/index-tutorials.html

the first three tutorials discuss references.

Hi, thanks for the reply but when I try to print the whole array it just prints the array addresses. This is the output I get when I printed it out

ARRAY(0x9936f48)
ARRAY(0x9e6a760)

I need to access the arrays inside the array which is stored as a value for the key in the hash. Typecasting it to an array gives me compilation errors. Is there any other way?
Thanks.

[miller]

You should spend some time studying the perldoc tutorial on complex data structures:

perldoc Perl Data Structures Cookbook

However, expanding on Kevin's example a little bit, and assuming rank_filename is actually a hash (you're missing the type cast prefix), then a way to toggle through all of this structure would be like this:

my %rank_filename = (
    '535.714285714286' => [
        [2,'535.714285714286','3','5','rep_Ara_2','Arav'],
        [3,'535.714285714286','4','5','rep_Ara_12','Ara']
    ],
    '642.857142857143' => [
        [1,'642.857142857143','3','6','rep_Ara_1','Ara']
    ]
);
 
foreach my $key ( keys %rank_filename ) {
    for (my $i=0; $i < @{ $rank_filename{$key} }; $i++) {
        for (my $j = 0; $j < @{ $rank_filename{$key}[$i] }; $j++) {
            print "$key, $i, $j = $rank_filename{$key}[$i][$j]\n";
        }
    }
}
 

The output is as follows:

535.714285714286, 0, 0 = 2
535.714285714286, 0, 1 = 535.714285714286
535.714285714286, 0, 2 = 3
535.714285714286, 0, 3 = 5
535.714285714286, 0, 4 = rep_Ara_2
535.714285714286, 0, 5 = Arav
535.714285714286, 1, 0 = 3
535.714285714286, 1, 1 = 535.714285714286
535.714285714286, 1, 2 = 4
535.714285714286, 1, 3 = 5
535.714285714286, 1, 4 = rep_Ara_12
535.714285714286, 1, 5 = Ara
642.857142857143, 0, 0 = 1
642.857142857143, 0, 1 = 642.857142857143
642.857142857143, 0, 2 = 3
642.857142857143, 0, 3 = 6
642.857142857143, 0, 4 = rep_Ara_1
642.857142857143, 0, 5 = Ara
 

Note, there are plenty of more efficient ways to traverse this data structure using each and foreach. But this method demonstrates how to travel deeply into a structure and still dereference and array both in its entirety and by element.

- Miller

[KevinADC]

I see I missed one level of the arrays, the structure you posted is a hash of arrays of arrays. Assuming like MIller it's a hash instead of a reference to a hash, here is a simplifid version of printing the arrays:

%rank_filename = (
    '535.714285714286' => [
        [2,'535.714285714286','3','5','rep_Ara_2','Arav'],
        [3,'535.714285714286','4','5','rep_Ara_12','Ara']
    ],
    '642.857142857143' => [
        [1,'642.857142857143','3','6','rep_Ara_1','Ara']
    ]
);
 
foreach my $key ( keys %rank_filename ) {
   foreach my $i ( @{ $rank_filename{$key} } ) {
      print join(',',@$i),"\n";
   }
} 
 

output:

2,535.714285714286,3,5,rep_Ara_2,Arav
3,535.714285714286,4,5,rep_Ara_12,Ara
1,642.857142857143,3,6,rep_Ara_1,Ara

[traravind]

I see I missed one level of the arrays, the structure you posted is a hash of arrays of arrays. Assuming like MIller it's a hash instead of a reference to a hash, here is a simplifid version of printing the arrays:

%rank_filename = (
    '535.714285714286' => [
        [2,'535.714285714286','3','5','rep_Ara_2','Arav'],
        [3,'535.714285714286','4','5','rep_Ara_12','Ara']
    ],
    '642.857142857143' => [
        [1,'642.857142857143','3','6','rep_Ara_1','Ara']
    ]
);
 
foreach my $key ( keys %rank_filename ) {
   foreach my $i ( @{ $rank_filename{$key} } ) {
      print join(',',@$i),"\n";
   }
} 
 

output:

2,535.714285714286,3,5,rep_Ara_2,Arav
3,535.714285714286,4,5,rep_Ara_12,Ara
1,642.857142857143,3,6,rep_Ara_1,Ara

Thank you for the reply. I think this is what I was looking for. Does @$ mean type casting the scalar variable to an array? Thank you once again.

[KevinADC]

it means dereferencing the array reference. I guess you could think of it either way though.