how to process text and numbers seperately in a given element?

[Ankush]

Hi,
I want to process numbers in a different fashion:

My input is something like:
<A>Ankush 123 Singhal 23 man</A>

I want output as:
<Doc>Ankush <num>123</num> Singhal <num>23> man</Doc>

How can we achieve this functionality using XSLT. I am using xalan
2.4.1

Thanks in advance,
Ankush

[Ankush]

I want output as:
<Doc>Ankush <num>123</num>Singhal <num>23</num>man</Doc>

[Martin Honnen]

Ankush wrote:

I want to process numbers in a different fashion:

My input is something like:
<A>Ankush 123 Singhal 23 man</A>

I want output as:
<Doc>Ankush <num>123</num> Singhal <num>23> man</Doc>

How can we achieve this functionality using XSLT. I am using xalan
2.4.1

That is difficult to achieve with pure XSLT and XPath 1.0. You have to
write a named template with parameters passing in the complete string
and recursively call it splitting the string as necessary.
--

Martin Honnen
http://JavaScript.FAQTs.com/

[George Bina]

As Martin said, you can use a stylesheet like the one below:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
version="1.0">

<xsl:template match="A">
<Doc>
<xsl:call-template name="markNumbers">
<xsl:with-param name="value" select="normalize-space(.)"/>
</xsl:call-template>
</Doc>
</xsl:template>

<xsl:template name="markNumbers">
<xsl:param name="value" select="''"/>
<xsl:choose>
<xsl:when test="contains($value, ' ')">
<xsl:call-template name="markNumber">
<xsl:with-param name="value" select="substring-before($value,
' ')"/>
</xsl:call-template>
<xsl:text> </xsl:text>
<xsl:call-template name="markNumbers">
<xsl:with-param name="value" select="substring-after($value,
' ')"/>
</xsl:call-template>
</xsl:when>
<xsl:otherwise>
<xsl:call-template name="markNumber">
<xsl:with-param name="value" select="$value"/>
</xsl:call-template>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template name="markNumber">
<xsl:param name="value" select="''"/>
<xsl:choose>
<xsl:when test="translate($value, '0123456789', '')=''">
<num><xsl:value-of select="$value"/></num>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="$value"/>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
</xsl:stylesheet>

It will give the following output when applied on your sample input:

<?xml version="1.0" encoding="UTF-8"?><Doc>Ankush <num>123</num>
Singhal <num>23</num> man</Doc>

Best Regards,
George
---------------------------------------------------------------------
George Cristian Bina
<oXygen/> XML Editor, Schema Editor and XSLT Editor/Debugger
http://www.oxygenxml.com

[Ankush]

Thanks that helps a lot!!----In fact that was exactly what I was
looking for!!

Thanks
Ankush

George Bina wrote:

As Martin said, you can use a stylesheet like the one below:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
version="1.0">

<xsl:template match="A">
<Doc>
<xsl:call-template name="markNumbers">
<xsl:with-param name="value" select="normalize-space(.)"/>
</xsl:call-template>
</Doc>
</xsl:template>

<xsl:template name="markNumbers">
<xsl:param name="value" select="''"/>
<xsl:choose>
<xsl:when test="contains($value, ' ')">
<xsl:call-template name="markNumber">
<xsl:with-param name="value" select="substring-before($value,
' ')"/>
</xsl:call-template>
<xsl:text> </xsl:text>
<xsl:call-template name="markNumbers">
<xsl:with-param name="value" select="substring-after($value,
' ')"/>
</xsl:call-template>
</xsl:when>
<xsl:otherwise>
<xsl:call-template name="markNumber">
<xsl:with-param name="value" select="$value"/>
</xsl:call-template>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template name="markNumber">
<xsl:param name="value" select="''"/>
<xsl:choose>
<xsl:when test="translate($value, '0123456789', '')=''">
<num><xsl:value-of select="$value"/></num>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="$value"/>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
</xsl:stylesheet>

It will give the following output when applied on your sample input:

<?xml version="1.0" encoding="UTF-8"?><Doc>Ankush <num>123</num>
Singhal <num>23</num> man</Doc>

Best Regards,
George
---------------------------------------------------------------------
George Cristian Bina
<oXygen/> XML Editor, Schema Editor and XSLT Editor/Debugger
http://www.oxygenxml.com