asp page to html

[woony]

I'm working on a webapplication that is running asp with vbscript. I made a function that prints the current page to a pdf. I needed to add everything that I write to the browser into a string and give that string to the component. Not a hard task but quite annoying thou. I was wondering if there is an easy way to get the full generated html code into a string easier.
Now I make a new page and instead of response.write etc. I just add it to the string. This lowers performance and recalculates everything that was needed.

So it would be handy if I could have a button that just copys the current html page into a string. Any help or suggestions are highly appreciated.

Greetings woony

[Nicodemas]

You could use the XML HTTP Request COM to retrieve the response from the executed page.

I've written a little script for one of my own app's that will help you. The function will pass back the response text from the retrieved URL in string format. Just dump that into your PDF.

<%
'//===========================================
'//
'// Author: Robert "Nicodemas" Simpson
'//
'// Website: http:nicodemas.com
'//
'// Function [Boolean] XmlHttpRequest([in] string: sOperation,
'//                                   [in] string: URL,
'//                                   [in] string: XML,
'//                                   [out]string: ResponseText)
'//
'// This function:
'//      - executes a request to a remote URL, and
'//      - returns the response thru arg. list.
'//===========================================
 
function XmlHttpRequest(sOperation, URL, DataToSend, ResponseText)
   dim oXml
 
   '//----------------------------------------------------
   '// by default, function result is false
   '//----------------------------------------------------
   XmlHttpRequest = false
 
   sOperation = ucase(trim(sOperation))
 
   if sOperation = "" or (sOperation <> "GET" or sOperation <> "POST") then sOperation = "GET"
   if URL = "" then exit function
 
   set oXml = server.createobject("microsoft.xmlhttp")
 
   oXml.open sOperation, URL, false
   oXml.send DataToSend
 
   ResponseText = oXml.responsetext
 
   set oXml = nothing
 
   XmlHttpRequest = true
end function
 
if XmlHttpRequest("GET", "http://url/to/the/page", "", theResponse) then
   '// dump [theResponse] into your PDF
end if
%>

[woony]

thank u, I'll try it out