problems with sending email

[vinodkvee]

i am a newbie to asp
i wrote the following asp code to send email

<%
Set objCDOMessage = Server.CreateObject("CDO.Message")
'creates the object
objCDOMessage.From = "[e-mail]"
objCDOMessage.To = "[e-mail]"

objCDOMessage.Subject = "blah blah"

objCDOMessage.Body = "Thanks for taking the time blah blah....."

'now send the message
objCDOMessage.Send
'wrap things up
Set objCDOMessage = Nothing
%>


this is not working,
should i configure any other stuffs

plz help me...............

[sashi]

Hi there,

i have attached some sample code segment below.. give it a try.. it works fine for me and hope it works ok for you too.. take care..

Const cdoSendUsingPickup = 1 'Send message using the local SMTP service pickup directory. 
Const cdoSendUsingPort = 2 'Send the message using the network (SMTP over the network). 
 
Const cdoAnonymous = 0 'Do not authenticate
Const cdoBasic = 1 'basic (clear-text) authentication
Const cdoNTLM = 2 'NTLM
 
Set objMessage = CreateObject("CDO.Message") 
objMessage.Subject = "Example CDO Message" 
objMessage.From = """Me"" <[e-mail]>" 
objMessage.To = "[e-mail]" 
objMessage.TextBody = "This is some sample message text.." & vbCRLF & "It was sent using SMTP authentication."
 
'==This section provides the configuration information for the remote SMTP server.
 
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2 
 
'Name or IP of Remote SMTP Server
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "mail.your.com"
 
'Type of authentication, NONE, Basic (Base64 encoded), NTLM
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = cdoBasic
 
'Your UserID on the SMTP server
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendusername") = "youruserid"
 
'Your password on the SMTP server
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "yourpassword"
 
'Server port (typically 25)
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25 
 
'Use SSL for the connection (False or True)
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = False
 
'Connection Timeout in seconds (the maximum time CDO will try to establish a connection to the SMTP server)
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60
 
objMessage.Configuration.Fields.Update
 
'==End remote SMTP server configuration section==
 
objMessage.Send
 

[vinodkvee]

Thanx its working!!!

[menon]

Hi Guys!

Use CDONTS instead of CDO Message Sending, Here is the sample code for sending CDONTS HTML Mails!

'Code Begins

Dim objCDOMail

'Create the e-mail server object
Set objCDOMail = Server.CreateObject("CDONTS.NewMail")

objCDOMail.From = Request.Form("email")
objCDOMail.To = "[e-mail]"
objCDOMail.Subject ="Enquiry From yourdomain.com"

objCDOMail.BodyFormat = 0 'Set the e-mail body format (0=HTML 1=Text)
objCDOMail.MailFormat = 0 'Set the mail format (0=MIME 1=Text)

'Set the main body of the e-mail
objCDOMail.Body = " "& vbNewLine & _
"<p><font size=""2"" face=""Verdana"">Enquiry From Website</font></p>"& vbNewLine

objCDOMail.Importance = 1 'Importance of the e-mail (0=Low, 1=Normal, 2=High)
objCDOMail.Send 'Send the e-mail

Set objCDOMail = Nothing 'Close the server object

'Code Ends

best regards,
Kalipurayath Sanal Menon

[waylabot]

hi guys.. i know this reply is quite late for this topic. but im desperate. i need to get my project done ASAP.

here goes..

i used CDO technology to send html-format emails using asp. everything works fine but the problem is when the email is received by the recepient, some tags are broken e.g </tr> -- < /tr> causing this tag to display in the browser. and worst there are some double spaces created between tags making my layout totally destroyed.. my page is a dynamic page with lots of queries from a mssql2005 DB. i tried displaying first the html value to the browser and it looks fine. but when it appeared in an email, its the exact opposite.

please help me. i badly need it. ive been looking for help anywhere.. havent found one yet. i would really appreciate your help guys...

regards,
richard