calculating age from DOB and adding to table via a query

[johng45]

simple age calculation from DOB and adding to table via a query

[cactusdata]

The function:

Public Function AgeSimple( _
  ByVal datDateOfBirth As Date) _
  As Integer
 
' Returns the difference in full years from datDateOfBirth to current date.
'
' Calculates correctly for:
'   leap years
'   dates of 29. February
'   date/time values with embedded time values
'
' DateAdd() is used for check for month end of February as it correctly
' returns Feb. 28. when adding a count of years to dates of Feb. 29.
' when the resulting year is a common year.
' After an idea of Markus G. Fischer.
'
' 2007-06-26. Cactus Data ApS, CPH.
 
  Dim datToday  As Date
  Dim intAge    As Integer
  Dim intYears  As Integer
 
  datToday = Date
  ' Find difference in calendar years.
  intYears = DateDiff("yyyy", datDateOfBirth, datToday)
  If intYears > 0 Then
    ' Decrease by 1 if current date is earlier than birthday of current year
    ' using DateDiff to ignore a time portion of datDateOfBirth.
    intAge = intYears - Abs(DateDiff("d", datToday, DateAdd("yyyy", intYears, datDateOfBirth)) > 0)
  End If
 
  AgeSimple = intAge
 
End Function

The query:

Select *, AgeSimple([DOB]) As Age
From YourTable

Don't "add" an age to a table; calculate it when needed using the query.