How to use a wildcard when opening an executable file with StrProg

[Nick Cooper]

I am using the following code to open up Acrobat Reader:

strProg = "C:\Program Files (x86)\Adobe\Reader 9.0\Reader\AcroRd32.exe"
 

which works fine, but on non-Windows7 computers the route is slighty different, also it is possible that a user may have an earlier version of Adobe. Is it possible to insert a wildcard in either or both of the 1st and 3rd directories to make display of a PDF independent of operating system and program version?

Nick

[Oralloy]

Nick,

What would the system do, if it encountered conflicting versions of Acrobat on the system? Pick one, and hope it was the correct version?

You might look, instead, in the Windows registry under one of the adobe entries to find the current version.

On my system, I searched for acrobat and found the following handle, from which you might be able to extract the executable name.

HKEY_CLASSES_ROOT\acrobat\shell\open\command

Again, on later version Windows systems, if you want to display a .PDF (or other acrobat) file, and the "reader" is registered, you should be able to just "execute" the file, and the system will do the rest for you. Mind, I haven't tested this, but you might want to give it a quick test.

On non-windows systems, I'm not certain what you'll need to do.

Luck!

[NeoPa]

If you'd like to access Registry Values from your database code there is some code for that available in Module to Read From the Windows Registry.

[Nick Cooper]

This routine opens Acrobat Reader and then the stored PDF of the invoice report applying to the selected record. As the paths to AcroRd32.exe vary (ie "\Program Files (x86)\" for Windows 7 and "\Program Files\" for XP and Vista) then I want the database to be able to function on different operating systems without the user having to amend the path to suit. Making the first directory (or even the last part of it) a wildcard would achieve that, if it's possible.

[ADezii]

I feel as though Oralloy had the right idea in Post #2. If your sole purpose is to Open *.pdf Files, and Adobe is the Registered Application for that File Type Extension (*.pdf), you can bypass executing the Adobe Executable and Execute the actual File or Path to the file itself. If you would like to see how this is done, just let me know.

[Oralloy]

Nick,

Were you using Perl, I'd say "glob the path"; however, this is in VBA.

You can still write the code to do path searches, but it's really not the happy way to go.

Also, there are folks (like me) who have tools mostly installed on a secondary "software" disk as part of their management technique.

So, if you're sticking with Windows systems, just execute the .PDF file. If you have to deal with Macintosh or Linux/Unix, then just execute the program name and trust that the user has his path set up correctly.

Cheers!

[Nick Cooper]

Thanks ADezii. Yes please!

Nick

[NeoPa]

Nick,

It's not clear that you've read the two posts prior to your response. Certainly you seem to revert to a position which is incompatible with the information posted therein.

In post #2 it is made clear that using a wildcard would make no sense. You need to get your head around this before proceeding. It's not that we have no code for it. It simply makes no sense.

Moving to post #3, there is information there that will enable you to discover exactly where the executable is found by accessing the registry. Without the facility of a wildcard in the name (which we now know is a done deal), this appears to be the next logical step, assuming you bypass the even simpler one of simply executing the PDF file itself and relying on the PC's Association setup to find and execute the reader.

If there is something we are not aware of that makes this inappropriate for some reason, then you should share that (technically it should have been part of the original question of course). Merely repeating your original position as if no-one had responded already, just gives the impression you haven't bothered to read the replies.

[ADezii]

The Demo Code that I am going to post is the most basic, simplest, 4-step approach for Opening/Executing a File based solely on its Extension (*.XXX). Is you wish to expand on this basic concept, we can at a later time.

1. Copy-N-Paste the following API Declaration into a 'Standard Code Module':
   

   Public Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" ( _
   ByVal hwnd As Long, ByVal lpOperation As String, ByVal lpFile As String, _
   ByVal lpParameters As String, ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long

2. Copy-N-Paste the following Code to wherever you deem appropriate:
   

   Dim strFile As String
   Dim lngErr As Long
    
   'Edit this:
   strFile = "C:\Dezii\KC Benefits.pdf"  ' the file you want to open/etc.
    
   lngErr = ShellExecute(0, "OPEN", strFile, "", "", 0)
    
   'Optionally, add code to test Value of the lngErr Return Value

3. Substitute your own Absolute Path to the *.pdf to be opened for "C:\Dezii\KC Benefits.pdf". This Value can be a Constant, Literal, pointer to a Control on your Form, etc.
4. Execute the Code - The File specified in strFile will be opened.
5. Any questions, feel free to ask.

[Oralloy]

Dezii,

Thanks for providing a good, working example. I think that'll get Nick over the hump for windows.

[ADezii]

Your welcome, at least for Windows! (LOL) Any non-Windows based OS, old Nick is on his own! (LOL)

[Oralloy]

Nahhh, not really

std::string command("acrobat ");
command = command + "/usr/local/Oralloy/mydoc.pdf";
system(command.c_str());

[Nick Cooper]

My apologies NeoPa, but you are attributing greater knowledge and experience to me than I merit. That is why it was not apparent to me prior to my #4 that the wildcard option was dead in the water. I know nothing about Registries and have alway been advised to steer clear of them if I'm not sure what I'm doing.

I did open up your recommended module in #3 but did not understand enough from it to proceed. Yes I should have replied to that effect but, as you no doubt gather, I'm new to these messaging systems and the protocol that applies, although I have every reason to be grateful for the things I have learned from this one (and you) so far.

I will hang slack for a day or two now and try to get my head around the further additions that have come along. For sure, executing the pdf directly is the way to go and many thanks to ADeziiall and Oralloy for their inputs too.
Regards - Nick

[NeoPa]

A perfect response Nick :-)

For what it's worth, I think you've made a wise choice going with the associated application approach.

As for the Registry Reading code, and also the reliable advice you've received concerning playing with the registry, I would make two points that may help, and may even put things in a clearer perspective for you.

1. The code linked to need not be understood to be used. Copy it wholesale into a module and it will be available to use, regardless of how it works. You would only need to understand how to call the RegRead() function. I've only just realised that I haven't explained that very well in the article and it could do with an update (Ooops).
2. Reading Registry values is not dangerous. Updating them in any way is definitely to be avoided unless you really know what you're doing, but reading them is pretty harmless (I can't think of any scenario where that may cause any problem).

PS. The article has now been updated so may be more use for those previously couldn't even see where to start.

[Nick Cooper]

Thanks Oralloy. Are you saying that if I place this code directly into the class module for the form from which I want to be able to double-click the chosen record, it will execute the PDF? The path that I currently use is:
"C:\Wheelbase\Invoices\" & Me!Account & "-" & Me![Inv No] & ".pdf"
which you will note also imports two other variables from that record into the filename. How would that map into your middle line of code, forward slashes, etc?
Thanks
Nick

[Oralloy]

Nick,

Sorry for the long delay, I've been out of the office for the last three days.

Here is a bit of documentation on ShellExecuteA, that you might want to breeze through.

Anyway, I forgot this was a VBA forum when I posted my bit for Linux/Unix type systems.

So, to make a comprehensive windows solution (I am using Excel for testing), what I did was create a "Module" named "Code Test", which contained my test code, as follows:

''====================================================================
''====================================================================
''====================================================================
''
''  Code Test
''    Module with various prepared code tests and use examples
''
''====================================================================
''====================================================================
''====================================================================
 
 
Option Compare Database
Option Explicit
 
 
''====================================================================
''====================================================================
''====================================================================
 
Public Sub TEST_showPDF()
  Dim wi As Object
  Set wi = New [Windoze Interface]
  Call wi.showPDF("C:\tmp\IRON File Systems (vijayan-thesis).pdf")
End Sub
 
'=====================================================================
'=====================================================================
'=====================================================================

And then, I created a "Class Module" with the actual launch code, as follows:

''====================================================================
''====================================================================
''====================================================================
''
''  Windoze Interface
''    Code to interface to µsWindows DLLs
''
''====================================================================
''====================================================================
''====================================================================
 
 
Option Compare Database
Option Explicit
 
 
''====================================================================
''====================================================================
''====================================================================
 
 
Private Type Body
  database As DAO.database      ''--database object
  databaseFile As String        ''--local database file
 
  EOL As String                 ''--end of line
 
  lastPDF As String             ''--last launched PDF file [diagnostic]
End Type
 
Private Const moduleName = "Windoze Support"
 
 
''====================================================================
''====================================================================
''====================================================================
 
 
Private this As Body
 
 
''====================================================================
''====================================================================
''====================================================================
 
 
Private Declare Function ShellExecute _
  Lib "shell32.dll" _
  Alias "ShellExecuteA" _
    (ByVal hwnd As Long, _
     ByVal lpOperation As String, _
     ByVal lpFile As String, _
     ByVal lpParameters As String, _
     ByVal lpDirectory As String, _
     ByVal nShowCmd As Long) As Long
 
 
''====================================================================
''====================================================================
''====================================================================
 
 
Private Sub Class_Initialize()
  Set this.database = Application.CurrentDb
  this.databaseFile = this.database.name
  this.EOL = VBA.vbCrLf  'ASCII.CRLF
  this.lastPDF = "<invalid>"
End Sub
 
 
Private Sub Class_Terminate()
  'MsgBox ("Terminating module: " & moduleName)
End Sub
 
 
''====================================================================
''====================================================================
''====================================================================
 
 
Property Get databaseFile() As String
''
''  accessor for this.databaseFile
''
  databaseFile = this.databaseFile
End Property
 
 
Property Let databaseFile(ByVal value As String)
''
''  accessor for this.databaseFile
''
  this.databaseFile = value
End Property
 
 
Property Get lastPDF() As String
  lastPDF = this.lastPDF
End Property
 
 
''====================================================================
''====================================================================
''====================================================================
 
 
Public Sub showPDF(ByVal fileName As String)
''
''  shows the given PDF file using acrobat
''
''  inputs:
''    fileName - fully qualified file name to show
''               (ex: C:/tmp/my.PDF)
''  raises:
''    true  - unqualified success
''    false - otherwise
''
  ''--local variables and definitions
  Dim pdf As String
  Dim run As Boolean
  Dim seResult As Long
 
  ''--initialize
  pdf = fileName
  run = True
 
  ''--slight diagnostic here...
  this.lastPDF = fileName
 
  ''--attempt liftoff
  If (run) Then
    seResult = ShellExecute(0, "OPEN", pdf, "", "", 0)
 
    If (32 >= seResult) Then
      run = False
      Err.Raise 0, moduleName, "ShellExecute failed with code: " & seResult
    End If
  End If
 
  ''--end of compilation unit with implicit return
End Sub
 
 
''====================================================================
''====================================================================
''====================================================================

IMPORTANT: the first is a "Module", and the second a "Class Module".

Then, in the "Immediate" window of the VBA interface window, I typed the following to demonstrate my code launch.

CALL [Code Test].TEST_showPDF

I sure hope this helps.

Luck!

[Nick Cooper]

Thanks Oralloy and ADezii, for spending your valuable time on this. My problem (or at least one of them!) is that I really don't understand how and where to put this code. I am using Access 2007 and enter code by going into form design and then 'view code' so whilst I can generate code in 'Class' modules, I'm not clear on where to create a Standard Module, which I guess is why I had no joy with your suggestion at #9, ADezii. It just stopped me opening the form with the error 'No Current Record'. This is the code I used:

Public Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" ( _
ByVal hwnd As Long, ByVal lpOperation As String, ByVal lpFile As String, _
ByVal lpParameters As String, ByVal lpDirectory As String, ByVal ShowCmd As Long) As Long
 
Option Compare Database
 
Private Sub Form_DblClick(Cancel As Integer)
Dim strFile As String
Dim lngErr As Long
strFile = "C:\Wheelbase\Invoices\" & Me!Account & "-" & Me![Inv No] & ".pdf"  
lngErr = ShellExecute(0, "OPEN", strFile, "", "", 0)
 

Unless you can see an obvious problem then I think it's only fair on you both that I do some more reading up before I waste any more of your time.
Nick

[Oralloy]

Nick,

When you are editing your VB code, there should be a "Project Explorer" window.

If not, you can show it by using the "View|Project Explorer" menu option.

It should show several folders, of which two are "Modules" and "Class Modules". You'll see your application's modules under these folders.

To create a new module, just right mouse ("click") anywhere in the window, and select the "Insert" option from the pop-up menu. From the "Insert" menu, you can insert a "Module" or "Class Module", depending on what you need todo.

Generally anything you insert will be given a generic (and fairly worthless) name like "Module1". You can change the name through the properties window.

If the properties window isn't showing, you can show it by using the "View|Properties Window" menu option.

BTW, my examples are often wordy, as I tend to build support skeletons around my code, or I steal some of my existing code and delete meat from the bones (the support skeleton). If you don't want the baggage, just remove it - after all, it's your code now, and I'm not proud.

Luck!

[ADezii]

The best thing that I can do at this point is to create a simple Demo for you, parallelling your situation as much as possible. In this manner, you can see exactly what is going on, and how it is accomplished. I'll have one for you in a day or two. Stay tuned...

Scratch the above! I just created a Demo for you in World Record Time.

1. Download the Attachment
2. Copy the *.pdf Files to the C:\Wheelbase\Invoices\ Directory
3. Open the Demo Database
4. There are 3 Dummy Records, click on the Command Button to Open any 1 of the 3 corresponding .pdfs
5. Play with the Code, and if you have any questions, please feel free to ask.

[Nick Cooper]

Bravo! Oralloy, your advice on where to put a standard module has enabled me to use ADezii's original code in #9 which now works a treat. Sorry A for the extra work you put in last night. This question about standard modules has baffled me for many months despite searching high and low in Access Help for advice. So I am most grateful to you both for solving this particular problem and must divide the credit equally. Is it allowed for me to tick 'best answer' for both of you? Thanks also to NeoPa for his inputs along the way, which I am now better equipped to take on board.
Cheers
Nick

[ADezii]

Oralloy deserves most of the credit, kindly allot him the Best Answer.

[NeoPa]

ADezii is generous to a fault. It's a long term affliction he's had since I first knew him :-D

@Nick:
Anyway, it's quite gratifying to see how much you've progressed in a single thread. Good for you :-)

PS. I'm afraid it's not possible to assign Best Answer to more than one post. I know both have been very helpful, but I suggest you look at the original question, and try to determine which single post goes furthest towards answering that. Think in terms of others following in your footsteps and wanting an answer for a similar problem.