writing in notepad through through shell command

[ravipanand]

Hi;

I m using following code for writing system IP in notepad from shell command

shell("ipconfig > c:\ipfile.txt")

but it do nothing( no errors comes also)

please solve this problem

Thanx
Ravi

[FishVal]

Hello, Ravi.

I'm not sure whether stdout could be directed to text file using command line parameter, but you can easily get it by Access (did you mean this ?) application. Read the following - Waiting for Shell to Finish.

Regards,
Fish.

[ADezii]

Something very similar can easily be implemented within a Batch File, and even opened within Access if you so desire:

@Echo Off
cls
IPConfig.exe > C:\Windows\IP_Config.txt
Notepad.exe C:\Windows\IP_Config.txt

[NeoPa]

Firstly, using parentheses to surround the Shell() parameters is only correct if you Call the function :

Call Shell("IPConfig >C:\IPFile.Txt")

Also, check out ShellWait() Function for synchronous execution of commands.

[ADezii]

Firstly, using parentheses to surround the Shell() parameters is only correct if you Call the function :

Call Shell("IPConfig >C:\IPFile.Txt")

Also, check out ShellWait() Function for synchronous execution of commands.

That's not exactly True, is it NeoPa? Since the Shell Function returns a Variant (Double) representing the Program's task ID if successful, otherwise 0. Call can only be used on a Function when you wish to ignore the Return Value. All this is applicable especially in the Thread's context, otherwise, aside from opening the actual Text File, how would you know if it executed correctly?

Dim RetVal As Variant
RetVal = Shell("C:\WINDOWS\SYSTEM32\CALC.EXE", vbNormalFocus)
 
If RetVal <> 0 Then
  MsgBox "Shell executed successfully!"
Else
  MsgBox "Command did not execute"
End If

[NeoPa]

You're absolutely right ADezii.

What I should have said is that using parentheses to surround the Shell() parameters is only correct if you are using the function as a function rather than as a subroutine. That is to say that a value is returned. This can be done by assigning the value to something, using it in some evaluation or using Call to state explicitly to ignore the resultant value.

Functions are allowed (VBA is rather stupid that way) to be called as subroutines in code. This has a similar effect to using Call but it is less obvious what the coder is dealing with. The parentheses are not used whan calling a function as a subroutine.

[FishVal]

Just out of curiosity.

Did anybody get that

IPConfig >C:\IPFile.Txt
 

work as expected?

[NeoPa]

I don't understand the question Fish?

What are you not sure about?

[FishVal]

I don't understand the question Fish?

What are you not sure about?

Does that put stdout stream to text file?
That is basically what I'm not sure about.

Did anybody get IPConfig output to text file via Shell() function or even Start>Run... ?

[NeoPa]

Aah. I see you mean did anybody get to work, the code :

Call Shell("IPConfig >C:\IPFile.Txt")

Trying to work out what you were asking I tried it and it didn't work. The redirection characters' functionality must be provided by the interpreter. I will work out a replacement version that should invoke the standard interpreter and work. Give me a minute.

[NeoPa]

Did anybody get IPConfig output to text file via Shell() function or even Start>Run... ?

No. It doesn't work from either method.

I'm just preparing a version that should work.

[FishVal]

From command line it works well, BTW. From batch file too. ADezii has made a good point.

[NeoPa]

The following code can be run from the Immediate Pane :

strCmd = """%C"" /C IPConfig >C:\IPFile.Txt" : _
strCmd = Replace(strCmd, "%C", Environ("ComSpec")) : _
Call Shell(strCmd)

This is a bit different from the code you would use if you want it in a module, but the basics are all there.

[ADezii]

The following code can be run from the Immediate Pane :

strCmd = """%C"" /C IPConfig >C:\IPFile.Txt" : _
strCmd = Replace(strCmd, "%C", Environ("ComSpec")) : _
Call Shell(strCmd)

This is a bit different from the code you would use if you want it in a module, but the basics are all there.

@NeoPa & FishVal, I was able to handle the entire process within Access, namely:

1. Execute the Batch File (IP.Bat) listed below:
   

   @echo off
   cls
   IPConfig.exe > C:\Windows\IP_Config.txt

2. Display the results of IP_Config.txt in a Text Box [txtIP]:
   

   Dim blnRetVal As Boolean
   Dim strTextLine As String
   Dim strBig As String
   Const con_BATCH_FILE_PATH As String = "C:\IP.bat"
   Const con_Text_FILE_PATH As String = "C:\Windows\IP_Config.txt"
    
   blnRetVal = Execute_Program(con_BATCH_FILE_PATH, "", "")
    
   Open con_Text_FILE_PATH For Input As #1
    
   Do While Not EOF(1)             'Loop until end of file.
     Line Input #1, strTextLine    'Read line into variable.
     If Len(strTextLine) > 0 Then
       strBig = strBig & Trim$(strTextLine) & vbCrLf
     End If
   Loop
   Close #1                        'Close file.
    
   Me![txtIP] = strBig             'Assign String to Text Box

3. OUTPUT in txtIP:
   

   Windows IP Configuration
   Ethernet adapter Local Area Connection:
   Connection-specific DNS Suffix  . :
   IP Address. . . . . . . . . . . . : 192.168.1.102
   Subnet Mask . . . . . . . . . . . : 255.255.255.0
   Default Gateway . . . . . . . . . : 192.168.1.1

4. Just let me know if this is a little extreme, I do this occasionally! (LOL)! I'll Post the Declarations and Function only if anyone is actually interested.

[FishVal]

Here is an example using Windows Script Host Model library.

Private Sub btnIPConfig_Click()
 
    Dim objWshShell As New IWshRuntimeLibrary.WshShell
    Dim objApp As IWshRuntimeLibrary.WshExec
 
    Set objApp = objWshShell.Exec("IPConfig")
    While objApp.Status = WshRunning
    Wend
    Me.txbStdOut = objApp.StdOut.ReadAll
 
    Set objApp = Nothing
    Set objWshShell = Nothing
 
End Sub
 

[NeoPa]

Hi
it is also not creating IPFile in c:

This was found in a report from the OP. It was submitted roughly 5 1/2 hours ago (before this post).

[NeoPa]

Unfortunately, as there is no reference to what you're talking about (there are after all, many suggestions in this thread), it's hard to know how to respond.

@ADezii & Fish
Although these ideas may be interesting in their own right, as the (fairly) simple command can be run directly from within Access it does seem a little overkill.

It does make me wonder if what I posted was understood clearly. Maybe I overcomplicated it somewhat, but I wanted a copy / pastable solution that would enable anyone to test the theory for themselves. It certainly produces the required results (Referring to post #13).

[ADezii]

Unfortunately, as there is no reference to what you're talking about (there are after all, many suggestions in this thread), it's hard to know how to respond.

@ADezii & Fish
Although these ideas may be interesting in their own right, as the (fairly) simple command can be run directly from within Access it does seem a little overkill.

It does make me wonder if what I posted was understood clearly. Maybe I overcomplicated it somewhat, but I wanted a copy / pastable solution that would enable anyone to test the theory for themselves. It certainly produces the required results (Referring to post #13).

Perhaps I was the one who misinterpreted the OP's request. Redirecting the Output of the IPConfig Command was only half the equation, displaying the Output within the context of Access was the other. That's why the logic in Post Numbers 3 and 14. Oh well, it wasn't the first, and it surely won't be the last time, that I was wrong (LOL).

[NeoPa]

Not at all ADezii. You may well be right. I simply interpreted the "in Notepad" as meaning in a (the) format that Notepad uses (IE .Txt).

Your psychic powers may well be more sensitive than mine on this issue ;)

[NeoPa]

Ravi,

I notice you have just tried again to post the same message as you tried before. When you want to post you need to click on the Reply button rather than the Report one.

Reporting merely sends a private message to the moderators letting them know you feel something is wrong with that post.

I hope you are more successful in future.