MS Access Calendar

[MyWaterloo]

Admin Note

This thread has been closed as it has gotten just too big.

If you have any questions about the application discussed in this thread please start a new thread in MS Access by clicking on the Start a Discussion button and link to the this thread in your question.

Original Question

Just wondering...Am I the only one in the access universe that would like an Outlook like calendar option? Is there such a thing as a calendar that can be used for data entry? You know...double click the day and "POP" up comes the event screen to enter data into. I have spent countless hours searching for such a phantom. Any thoughts or sites with a template/example/download?

Admin Edit

For ease of usage I will include a link here to the post in this thread with the latest version of the solution database.

Currently this is at Post #298.

Alternatively, if the attachment is all you require, then you'll find it here (Calendar.zip).

A wide angled version (for wider screen real-estate) has also been posted now at Post #327. The attachment there is Wide Calendar with Switchboard.zip.

[ADezii]

kashif73, You are quite welcome.

I'm helping someone out with a Project similar to yours and which also includes some functionality similar to what you had requested. Check in from time to time, since I feel I can further enhance your Project with a little modification of my current work. I'll Attach what I have developed for you at that time.

[ADezii]

@kashif73
Download the Attachment and see if you can use the new functionality, if not, then nothing was lost. I intentionally did not Comment the New Code for the sake of brevity. Should you have any questions whatsoever, please do not hesitate to ask.

[kashif73]

Thank you very much Azedii. It looks great.This is exactly what I wanted. You've solved my problem. A real big THANKS for this.

[ADezii]

@kashif73
You are quite welcome, kashif73. I'm glad that it all worked out for you. Remember to peeriodically Compact/Repair the Database because of the nature of it.

[yiwen]

Hello Adezii,
Could you please post a link for a generic functionnality of the calendar.
There is no attachement on post 59 and 60 like mentionned in some posts.

Thanx

[ADezii]

Are we talking about a Single Date (Date) or Date Range (Between Date1 And Date2)?

[yiwen]

Hi
I am looking for the version wich could be better for managing appointements for each day. (it should be one date).

[ADezii]

Try this for a Single-Date Demo:

[mahogg]

Hi, I'm looking for a calander to sit in an Acc 2007 database. I was reading through this thread with interest, but cannot actually find a link or download for ADezii's calander. I'd love to take a look and see if it would fit my needs, assuming of course, you can still share the project?
regards,
mike.

[MMcCarthy]

mahogg

Can you see the attachment in ADezii's last post.

http://bytes.com/topic/access/answer...ar#post3535204

[NeoPa]

Msquared is referring to post #189 of course. It may be that this particular one, doctored for the needs of the previous poster, is not what you're after. If so, then please indicate which version you're having trouble with and we can check to see what the problem may be.

[ADezii]

Hello Mike, if you clearly state exactly what your needs are, along with the relevant information and sample data, then I will be happy to retrofit the Calendar for a simple demo, and Attach it for you to view. It's up to you.

[mahogg]

Thanks for the prompt replies and your kind offer of help, Adezil.
I'm new to Access and have been learning on the hoof. I've adapted the Northwind sample in Acc2007, adding several tables, queries & forms of my own. I wanted to add a calendar to the 'Northwind Home' page, replacing the chart they use in the sample form. I'd like to be able to enter text representing events, tasks, reminders etc. and have either a daily, weekly or monthly view option. Your zip file in #189 looks like it might fit the bill. Would it be possible to link it to a separate tbls/qrys/subfrm's for Events, Meetings and Tasks? Excuse my rather shallow knowledge of databases so far, as I say, I'm learning on the go but I 'plateau' round about the level of amending pre written macro's . . .
I'm struggling to attach anything meaningful as there are so many underlying objects linked to the home page. Hopefully you can open the sample in Acc2007 and see what I'm referring to?
Thanks again guys.
Mike.

[ADezii]

Sorry Mike, not running Access 2007. The Calendar is an Unbound Access Form and as such cannot be Embedded or Linked To the Northwind Home Page. It can, however, be Opened in any manner from the Opening Form. It appears as though you are asking for a full blown Task Manager/Scheduler which the Calendar is not. It is simply used as a monthly, graphical display of limited data with full Navigation capabilities. Provide me with some simple data such as [Start Date], [End Date], [Event Name], [Originator], etc. and I'll see what I can do for you.

[nerd4access]

ADezii,

I must say I love the Calendar_SingleDate demo you posted. I have incorporated it into a database that I am building. I ran into a small issue in doing so. I am using an Access front end and a SQL 2005 backend. The code worked fine before upsizing the backend to SQL.

My current issue occurs when I click on a day in the calendar, the list box shows data for a date two days after the chosen date. For instance, if I click on January 3, 2010, the list box shows data for January 5, 2010. The list box consistently shows data for a date two days in the future regardless of the day chosen on the calendar. Do you have any idea why I am experiencing this issue?

[ADezii]

If you are using the Demo DB to base your case on, the actual Date Used (Criteria) to populate the List Box is [ReviewDate] as indicated in Lines 7 and 8, whereas the other Dates ([QIPStartDate], [QIPEndDate]), are simple for display purposes only as indicated in Lines 5 and 6.

Private Sub PopulateEventsList(ctlDayBlock As Control)
On Error GoTo Err_PopulateEventsList
Dim strSQL2 As String
 
strSQL2 = "SELECT tblReviews.[ClientName] As [Client Name], tblReviews.[QIPStartDate] As [QIP Start Date], " & _
          "tblReviews.[QIPEndDate] As [QIP End Date]" & _
           "FROM tblReviews WHERE tblReviews.[ReviewDate] = " & _
           ctlDayBlock.Tag & " ORDER BY tblReviews.[ReviewDate];"
 
lstEvents.RowSource = strSQL2
 
lblEventsOnDate.Caption = Format(ctlDayBlock.Tag, "m-dd-yyyy")
lstEvents.Visible = True
lblEventsOnDate.Visible = True
 
Exit_PopulateEventsList:
  Exit Sub
 
Err_PopulateEventsList:
  MsgBox Err.Description, vbExclamation, "Error in PopulateEventsList()"
  Resume Exit_PopulateEventsList
End Sub

P.S. - Place the following Line off code anywhere within the PopulateEventsList() Procedure. It should accurately reflect the selected Day in the Calendar.

MsgBox CDate(ctlDayBlock.Tag)

[nerd4access]

The unbound textboxes that create the calendar display the data accurately. If I click on any one of the days of the month, the label next to the list box at the bottom of the form displays the chosen date; however, the list box does not list the data accurately. The list box displays data that is two days in the future. I have attached a screen shot to provide a better picture.

The code below is what I have listed to populate the list box:

Private Sub PopulateEventsList(ctlDayBlock As Control)
On Error GoTo Err_PopulateEventsList
Dim strSQL2 As String
 
strSQL2 = "SELECT dbo_tblEvents.[EventID] As [Event ID], dbo_tblEvents.[EventName] As [Event Name], dbo_tblEvents.[Location] As [Meeting Room], " & _
          "dbo_tblEvents.[StartDate] As [Start Date], dbo_tblEvents.[EndDate] As [End Date]" & _
           "FROM dbo_tblEvents WHERE dbo_tblEvents.[Status] <> 'Cancelled' And dbo_tblEvents.[StartDate] = " & _
           ctlDayBlock.Tag & " ORDER BY dbo_tblEvents.[StartDate];"
 
lstEvents.RowSource = strSQL2
 
lblEventsOnDate.Caption = Format(ctlDayBlock.Tag, "m-dd-yyyy")
lstEvents.Visible = True
lblEventsOnDate.Visible = True
 
Exit_PopulateEventsList:
  Exit Sub
 
Err_PopulateEventsList:
  MsgBox Err.Description, vbExclamation, "Error in PopulateEventsList()"
  Resume Exit_PopulateEventsList
End Sub

[ADezii]

Do you do what I requested in Post #197 and what did you come up with?

P.S. - Place the following Line off code anywhere within the PopulateEventsList() Procedure. It should accurately reflect the selected Day in the Calendar.

MsgBox CDate(ctlDayBlock.Tag)

Also, try (Re: Line 4):

strSQL2 = "SELECT dbo_tblEvents.[EventID] As [Event ID], dbo_tblEvents.[EventName] As [Event Name], dbo_tblEvents.[Location] As [Meeting Room], " & _ 
          "dbo_tblEvents.[StartDate] As [Start Date], dbo_tblEvents.[EndDate] As [End Date]" & _ 
           "FROM dbo_tblEvents WHERE dbo_tblEvents.[Status] <> 'Cancelled' And dbo_tblEvents.[StartDate] = " & _ 
           CDate(ctlDayBlock.Tag) & " ORDER BY dbo_tblEvents.[StartDate];"

[nerd4access]

Thanks for your help thus far. I have been working on this for quite some time.

The screen shot below is what I get when I added the following code:

MsgBox CDate(ctlDayBlock.Tag) 

The MsgBox pops up and displays the date for the textbox that I have chosen; however the information in the listbox is still not accurate. In this example I chose 1/3/2010. The data is displayed correctly in the calendar, but the data for 1/5/2010 is displayed in the listbox at the bottom of the form.

The screen shot below is what I get when I added the following code:

strSQL2 = "SELECT dbo_tblEvents.[EventID] As [Event ID], dbo_tblEvents.[EventName] As [Event Name], dbo_tblEvents.[Location] As [Meeting Room], " & _  
          "dbo_tblEvents.[StartDate] As [Start Date], dbo_tblEvents.[EndDate] As [End Date]" & _  
           "FROM dbo_tblEvents WHERE dbo_tblEvents.[Status] <> 'Cancelled' And dbo_tblEvents.[StartDate] = " & _  
           CDate(ctlDayBlock.Tag) & " ORDER BY dbo_tblEvents.[StartDate];" 

After adding this code, the listbox is not populated at all. In this example I chose 1/5/2010. The data is displayed in the calendar correctly, but no data was displayed in the list box.

[ADezii]

Try the following SQL Statement removing the Data Type Converter and adding the Date Delimiters (Reference Lines 4 and 5):

strSql2 = "SELECT dbo_tblEvents.[EventID] As [Event ID], dbo_tblEvents.[EventName] As [Event Name], & _
           dbo_tblEvents.[Location] As [Meeting Room], " & _
          "dbo_tblEvents.[StartDate] As [Start Date], dbo_tblEvents.[EndDate] As [End Date]" & _
           "FROM dbo_tblEvents WHERE dbo_tblEvents.[Status] <> 'Cancelled' And dbo_tblEvents.[StartDate] = #" & _
           ctlDayBlock.Tag & "# ORDER BY dbo_tblEvents.[StartDate];"

[nerd4access]

When I change the code to include lines 4 and 5 from the code snippet you provided, the listbox does not populate. It remains empty regardless of the date selection.

[ADezii]

What is the Data Type of [StartDate] in dbo_tblEvents within the SQL Server DB?

[nerd4access]

The datatype for StartDate is datetime in the SQL Server DB.

[ADezii]

I am actually at my wits end on this one. Since the correct Date is being returned by Access in ctlDayBlock.Tag, my only assumption is that SQL Server is incorrectly interpreting the Date. This is my only Option at this point, and the choice is yours. Send to me as an Attachment the Form containing the Calendar as well as dbo_tblEvents as an Access Table. I'll verify the code in Access, then attempt to Upgrade to SQL Server and see what happens. If you are willing to go this route, and patient, then send me the above requested items. I can do nothing else at this point.

[nerd4access]

I have attached a sample version of my database. The code works fine when using an access table. Wires seemed to get crossed when using SQL Server 2005 as the backend.

Again, thanks for all the time you have spent on this.

[ADezii]

As previously indicated in Post #195, I am not running Access 2007. If you can, convert the DB to Access 2003 where I can work with it then Upgrade to SQL Server 2000 where hopefully the problem may still exist. Be advised that this will take a little time.

[ADezii]

This Band-aide should work until I find out what is actually going on here (Line 4 change):

strSQL2 = "SELECT dbo_tblEvents.[EventID] As [Event ID], dbo_tblEvents.[EventName] As [Event Name], dbo_tblEvents.[Location] As [Meeting Room], " & _ 
          "dbo_tblEvents.[StartDate] As [Start Date], dbo_tblEvents.[EndDate] As [End Date]" & _ 
           "FROM dbo_tblEvents WHERE dbo_tblEvents.[Status] <> 'Cancelled' And dbo_tblEvents.[StartDate] = " & _ 
           (ctlDayBlock.Tag - 2) & " ORDER BY dbo_tblEvents.[StartDate];" 
 
lstEvents.RowSource = strSQL2 

[nerd4access]

My apologies...I have uploaded the database in an earlier version. I will try the code from the last post to see if it works.

Again, thanks for your help on this.

[nerd4access]

The Band-aid listed in post #208 worked. The list box at the bottom of the screen populates correctly...matching the date chosen in the calendar.

[ADezii]

I actually duplicated the problem with Access 2003/SQL Server 2000 and the Northwind.dbf Database. I'll look into it when I get the chance.

[ADezii]

Hello nerd4access. I hope you don't mind but I made some cosmetic as well as a single functional modification to your Calendar Form to make it more visually appealing. You can either accept some/all of them, or disregard, the choice is yours. The major problem I'll look at later.

1. Eliminated the Vertical Scroll Bar which is not needed, and is not visually appealing.
2. Set the Border Style of frmCalendar to Dialog.
3. The sequence of Events in the Events List Box should be in the same order as they are displayed in the Calendar. I simple added another Order By to the existing one.
4. Set the Moveable Property to No.
5. Changed the Foreground/Background Properties of the System Date Block to make it stand out more.
6. All these changes are reflected in the Attachment.

[nerd4access]

I like the cosmetic changes. I would agree that they are more appealing to the eye. Thanks for those touch ups.

[edsuk]

I have been asked to provide a calendar facility within an Access database. I have looked at a number of threads on this subject and Adezii has included a database as an attachment.

If an Access 2000 or 2002 version could be attached it would really be appreciated.

Thanks in advance for any help you are able to provide.

[ADezii]

Will your Database be displaying info for a Single Date Field as in [Review Date], or within a Date Range as in [Start Date] ==> [End Date]? There are actually 2 Calendar Databases, one for each scenario.

[nerd4access]

It will display info for a single date.

[ADezii]

I'm confused, are nerd4access and edsuk one and the same? Oh well:

[nerd4access]

We are not one in the same, but it's okay. I will view the attachment in your last post. Thank you so much for your help! :-)

[edsuk]

Hi ADezii

We are definitely not the same !

Thanks for replying on this subject. I have spent ages trying to find a solution like this. Actually the calendar option I would prefer is the 'Date Range' option where the task can span a number of days or even may be just the one day.

As mentioned a version in Access 2000 or 2002 would be so much appreciated.

Once again, thanks.

[ADezii]

Let me explain how the Date Range Calendar works. Let's suppose you have an Event named Event A and the Start Date for Event A is 1/10/2010 while the End date is 1/20/2010. Info relating to Event A will be displayed linearly on the Calendar for each Day of the Range. Why not give me your Start and End Date Field Names, as well as additional Field Names, and I'll construct a simple Demo for you. Include your Table name also. Keep in mind that the actual info than can be displayed in the Calendar itself is very limited, which is why it incorporates a List Box for expanded info.

[ADezii]

As soon as I get the details from edsuk as previously requested in Post #219, I'll post a simple Demo for both of you to Download. In the meantime, yoou can download the Single-Date Calendar that I attached in Post #217.

[edsuk]

Hi ADezii

Missed your earlier reply due to time difference, UK vs USA.

Anyway, really appreciate your offer to help, the data is held in only two tables, I have only included relevant columns:

T_Job:
JobID PK
JobNo
EmpID FK
StartDate
ReqDate

T_Emp
EmpID PK
EmpName


T_Job
24 'JN132' 204 '10/01/2010' '15/01/2010'
25 'JN135' 207 '11/01/2010' '11/01/2010'

T_Emp
204 Bob Smith
207 Will Jones

Only one employee can be assigned to a job.

I am use to working with recordsets, so the additional data requirements I can probably sort once I have the example Db, as well as populating the listbox - and I fully understand the requirement for this - to supplement the info displayed in the calendar iteself. As mentioned previously a calendar with this type of functionalty is so hard to find/let alone code. And I am so thankful for your help.

edsuk...

[ADezii]

Hello edsuk. It is not that simple a Task to recode the Calendar to conform exactly to specific requirements. I'll start the process in my spare time, but you must be patient. I'll also generate additional Dummy Data for display purposes. See Ya when I see Ya or I'll Be Back! (LOL)

[edsuk]

ADezii

Thanks for the update, I am not asking you to do my coding for me, you have done the 'hard work' already in providing the calendar/schedule functionality.

I can modify the code for populating the calendar controls and the list box myself.

I have been searching for a long time for an Access calendar like this and am so grateful that you have provided this for others to use.

Once done I will be glad to attach my slightly modified sample Db in another post for reference.

So if you could attach the 'Date Range' calendar in your next post I will get on and do my small bit.

You must realize how useful this calendar form is from the number of posts on this subject, which continue to grow.

Cheers buddy.

[ADezii]

Will send a Demo as soon as I can. Just as a side not, edsuk, it is rarely a good idea to store a Full Name in a single Field as in [EmpName].

[edsuk]

ADezii

Totally agree and I don't. The table actually has EmployeeFirstName and EmployeeLastName as columns. Plus the full name which is not displayed in the form but gets updated when either of these two records get data entered/modified.

Having the full name in addition does make displaying the information easier when it comes to combo boxes, list boxes etc as saves having to concatenate the data every time I write a query [I'm just a bit lazy LOL].

Space is not an issue so the additional column is not a problem.

Cheers

[ADezii]

Download the Attachment for what I feel is a workable Demo which you can tweak to your own needs. Be advised that you may have to swap Code Lines 21 and 26, since you are in the UK. Only you can make that determination. Good Luck and let me know how you make out.

Private Sub PopulateCalendar()
On Error GoTo Err_PopulateCalendar
Dim strFirstOfMonth As String, bytFirstWeekdayOfMonth As Byte, bytBlockCounter As Byte
Dim bytBlockDayOfMonth As Byte, lngBlockDate As Long, ctlDayBlock As Control
Dim bytDaysInMonth As Byte, bytEventDayOfMonth As Byte, lngFirstOfMonth As Long
Dim lngLastOfMonth As Long, lngFirstOfNextMonth As Long, lngLastOfPreviousMonth As Long
Dim lngEventDate As Long, bytBlankBlocksBefore As Byte, bytBlankBlocksAfter As Byte
Dim astrCalendarBlocks(1 To 42) As String, db As Database, rstEvents As Recordset
Dim strSelectEvents As String, strEvent As String, strPlatoons As String
Dim lngSystemDate As Long  'CFB added 1-25-08
Dim ctlSystemDateBlock As Control, blnSystemDateIsShown As Boolean  'CFB added 1-25-08
Dim strSQL As String    'Added 4/16/2008
Dim blnRetVal, intNumOfRecs As Integer
 
lngSystemDate = Date    'CFB added 1-25-08
intMonth = objCurrentDate.Month
intYear = objCurrentDate.Year
lstEvents.Visible = False
lblEventsOnDate.Visible = False
lblMonth.Caption = MonthAndYear(intMonth, intYear)
strFirstOfMonth = Str(intMonth) & "/1/" & Str(intYear)
 
'*************************************************************************
  'ADezii
  'NOTE: Will work in the UK (United Kingdom) and other European Nations
  'strFirstOfMonth = "1/" & Str(intMonth) & Str(intYear)
'*************************************************************************
 
bytFirstWeekdayOfMonth = WeekDay(strFirstOfMonth)
lngFirstOfMonth = DateSerial(intYear, intMonth, 1)
lngFirstOfNextMonth = DateSerial(intYear, intMonth + 1, 1)
lngLastOfMonth = lngFirstOfNextMonth - 1
lngLastOfPreviousMonth = lngFirstOfMonth - 1
bytDaysInMonth = lngFirstOfNextMonth - lngFirstOfMonth
bytBlankBlocksBefore = bytFirstWeekdayOfMonth - 1
bytBlankBlocksAfter = 42 - (bytBlankBlocksBefore + bytDaysInMonth)
 
Set db = CurrentDb
strSQL = "Select * From tbl_employees_TEMP Where tbl_employees_TEMP.[LeaveDateFrom] Between " & _
          lngFirstOfMonth & " And " & lngLastOfMonth & " ORDER BY tbl_employees_TEMP.[LeaveDateFrom], " & _
          "tbl_employees_TEMP.[FullName];"
 
Set rstEvents = db.OpenRecordset(strSQL)    'Added 4/16/2008
 
Do While Not rstEvents.EOF
  strEvent = rstEvents![FullName]
  bytEventDayOfMonth = (rstEvents![LeaveDateFrom] - lngLastOfPreviousMonth)
  bytBlockCounter = bytEventDayOfMonth + bytBlankBlocksBefore
    If astrCalendarBlocks(bytBlockCounter) <> "" Then
      astrCalendarBlocks(bytBlockCounter) = _
      astrCalendarBlocks(bytBlockCounter) & vbNewLine & strEvent
    Else
      astrCalendarBlocks(bytBlockCounter) = strEvent
    End If
    rstEvents.MoveNext
Loop
 
For bytBlockCounter = 1 To 42                       'blank blocks at start of month
  Select Case bytBlockCounter
    Case Is < bytFirstWeekdayOfMonth
      astrCalendarBlocks(bytBlockCounter) = ""
      ReferenceABlock ctlDayBlock, bytBlockCounter
      ctlDayBlock.BackColor = 12632256
      ctlDayBlock = ""
      ctlDayBlock.Enabled = False
      ctlDayBlock.Tag = ""
    Case Is > bytBlankBlocksBefore + bytDaysInMonth 'blank blocks at end of month
      astrCalendarBlocks(bytBlockCounter) = ""
      ReferenceABlock ctlDayBlock, bytBlockCounter
      ctlDayBlock.BackColor = 12632256
      ctlDayBlock = ""
      ctlDayBlock.Enabled = False
      ctlDayBlock.Tag = ""
        If bytBlankBlocksAfter > 6 And bytBlockCounter > 35 Then
          ctlDayBlock.Visible = False
        End If
    Case Else   'blocks that hold days of the month
      bytBlockDayOfMonth = bytBlockCounter - bytBlankBlocksBefore
      ReferenceABlock ctlDayBlock, bytBlockCounter
      lngBlockDate = lngLastOfPreviousMonth + bytBlockDayOfMonth 'block's date
        If bytBlockDayOfMonth < 10 Then
          ctlDayBlock = Space(2) & bytBlockDayOfMonth & _
                        vbNewLine & astrCalendarBlocks(bytBlockCounter)
        Else
          ctlDayBlock = bytBlockDayOfMonth & _
                        vbNewLine & astrCalendarBlocks(bytBlockCounter)
        End If
 
        'If this block is the system date, change its color (CFB 1-25-08)
        If lngBlockDate = lngSystemDate Then
          ctlDayBlock.BackColor = QBColor(13)
          ctlDayBlock.ForeColor = QBColor(15)
          Set ctlSystemDateBlock = ctlDayBlock
          blnSystemDateIsShown = True
        Else
          ctlDayBlock.BackColor = 16777215
          ctlDayBlock.ForeColor = 8388608 '====> Added by ADezii on 1/28/2008 (Date
        End If                                  'Text was essentially invisible without it for
          ctlDayBlock.Visible = True            'Block representing current day position)
          ctlDayBlock.Enabled = True
          ctlDayBlock.Tag = lngBlockDate
  End Select
Next
 
'If the system date is in this month, show its events (CFB added 1-25-08)
If blnSystemDateIsShown Then
  PopulateEventsList ctlSystemDateBlock
End If
 
Call PopulateYearListBox    'Added by ADezii on 1/28/2008 - suggested by CFB
 
Exit_PopulateCalendar:
  Exit Sub
Err_PopulateCalendar:
  MsgBox Err.Description, vbExclamation, "Error inPopulateCalendar()"
  Resume Exit_PopulateCalendar
End Sub

[NeoPa]

Space is not an issue so the additional column is not a problem.

If that's your opinion, then I strongly recommend checking out Normalisation and Table structures. You won't find many experienced database professionals who agree with you.

[edsuk]

ADezii

Thanks for the Calendar Db, exactly what was required. Really appreciate all your help.

And regarding the comments from NeoPa, thanks and yes I do understand Normalisation and Table Structures and agree that this goes against the grain, but the EmployeeTbl has less than 20 records - so I stand by my comment that space is not an issue in this particular Db.

Cheers and thanks ADezii once again.

[edsuk]

hi ADezii

I have made one very insignifficant mod to the populateCalendar sub.

Which you may like or not to include in the future.

the mod is at line 74

Currently:

If bytBlankBlocksAfter > 6 And bytBlockCounter > 35 Then
   ctlDayBlock.Visible = False
End If

Amended To:

If bytBlankBlocksAfter > 6 And bytBlockCounter > 35 Then
   ctlDayBlock.Visible = False
Else
   ctlDayBlock.Visible = True
End If

If you scroll through the months, say to May 2010, we get an incomplete row at the bottom as only the first two textboxes are visible. This mod just makes the whole of the bottom row visible to complete the grid.

I did say it was insignifficant.

this sample DB is great - thanks.

[NeoPa]

As an alternative (same effect - different code) you could say :

ctlDayBlock.Visible = ((bytBlankBlocksAfter < 7) Or (bytBlockCounter < 36))