Custom Record Navigation Buttons

[Dan2kx]

Hello again,

I have a new problem to tackle,

I Have a form which is used for adding staff members, and because i like to reuse forms, i have set it to open in add mode or in edit mode using a simple string from my custom switchboard. so when it is in edit mode the forms record source is a parameter query that forces the user to search by surname (and forces a wildcard), if the query returns more than one result (which is possible obviously) i want the user to be able to cycle the available records,

i have to buttons: next and previous with the:
docmd.gotorecord, , acnext / ac previous.

i dont want the user to be able to add new users (which is possible) and i want to stop the error (which i can do myseff with an on error statement,)

how would i go about this then?
i am thinking along the lines of

if first record then
msgbox "no more records"

etc

Thanks to any that can help me!
Dan

[missinglinq]

Obviously, you need to goto Properties - Data for the form and set AllowAdditions to No. Then

Private Sub Go2Next_Click()
On Error GoTo Err_Go2Next_Click
 
   DoCmd.GoToRecord , , acNext
 
Exit_Go2Next_Click:
    Exit Sub
 
Err_Go2Next_Click:
If Err.Number = 2105 Then
   MsgBox "This is the Last Record"
Else
    MsgBox Err.Description
    Resume Exit_Go2Next_Click
End If
End Sub
 
Private Sub Go2Prev_Click()
On Error GoTo Err_Go2Prev_Click
 
DoCmd.GoToRecord , , acPrevious
 
Exit_Go2Prev_Click:
    Exit Sub
 
Err_Go2Prev_Click:
If Err.Number = 2105 Then
    MsgBox "This is the First Record"
Else
    MsgBox Err.Description
    Resume Exit_Go2Prev_Click
End If
End Sub

Linq ;0)>

[Dan2kx]

Doh, i knew it would be a simple fix.

Thanks alot

[ADezii]

Hello again,

I have a new problem to tackle,

I Have a form which is used for adding staff members, and because i like to reuse forms, i have set it to open in add mode or in edit mode using a simple string from my custom switchboard. so when it is in edit mode the forms record source is a parameter query that forces the user to search by surname (and forces a wildcard), if the query returns more than one result (which is possible obviously) i want the user to be able to cycle the available records,

i have to buttons: next and previous with the:
docmd.gotorecord, , acnext / ac previous.

i dont want the user to be able to add new users (which is possible) and i want to stop the error (which i can do myseff with an on error statement,)

how would i go about this then?
i am thinking along the lines of

if first record then
msgbox "no more records"

etc

Thanks to any that can help me!
Dan

These Buttons should not be Enabled under these conditions, and the User should not have the Option of clicking on them. If the User is on the First Record, the Previous Button should be disabled, if he is on the Last, the Next Button should be disabled. Placing this code in the Form's Current() Event will set this up for you, if you wish to:

Private Sub Form_Current()
Dim recClone As DAO.Recordset
 
Set recClone = Me.RecordsetClone
 
recClone.Bookmark = Me.Bookmark    'must synchronize
 
recClone.MovePrevious
  Me![cmdPrevious].Enabled = Not (recClone.BOF)
recClone.MoveNext
 
recClone.MoveNext
  Me![cmdNext].Enabled = Not (recClone.EOF)
recClone.MovePrevious
End Sub

[Dan2kx]

Yeah that works well to, nice work

[missinglinq]

And since this thread has such a descriptive title, and people researching the topic may end up here, I'll list code for a suite of navigation buttons I usually use. As with the other code listed here, the form's AllowAdditions Property has to be set to No.

Rather than disabling the appropriate nav button when reaching the beginning or end of the record set, the Next and Previous buttons here causes the user to "wrap" around. If on the first record and Previous is hit, it "wraps" around to the last record; if on the last recrord and Next is hit, it "wraps" around to the first record.

Private Sub Go2First_Click()  
On Error GoTo Err_Go2First_Click
 
DoCmd.GoToRecord , , acFirst    
 
Exit_Go2First_Click:
 
Exit Sub     
 
Err_Go2First_Click:        
 
MsgBox Err.Description
 
Resume Exit_Go2First_Click
 
End Sub    
 
Private Sub Go2Last_Click()
On Error GoTo Err_Go2Last_Click
 
DoCmd.GoToRecord , , acLast     
 
Exit_Go2Last_Click:        
 
Exit Sub
 
Err_Go2Last_Click:
 
MsgBox Err.Description      
 
Resume Exit_Go2Last_Click
 
End Sub
 
Private Sub Go2Next_Click()
 
On Error GoTo Err_Go2Next_Click
 
DoCmd.GoToRecord , , acNext
 
Exit_Go2Next_Click:
 
Exit Sub
 
Err_Go2Next_Click:
 
  If Err.Number = 2105 Then
 
   DoCmd.GoToRecord , , acFirst
 
  Else
 
   MsgBox Err.Description
   Resume Exit_Go2Next_Click
 
  End If
 
End Sub
 
Private Sub Go2Prev_Click()
On Error GoTo Err_Go2Prev_Click
 
DoCmd.GoToRecord , , acPrevious 
 
Exit_Go2Prev_Click:
 
Exit Sub
 
Err_Go2Prev_Click:
 
If Err.Number = 2105 Then
 
  DoCmd.GoToRecord , , acLast
 
Else
 
  MsgBox Err.Description
  Resume Exit_Go2Prev_Click
 
  End If
 
End Sub

Linq ;0)>