How to activate hyperlink in text box

[dillneus]

Hello,

I have a problem with hyperlink.
I have a text box that contains link to the document. I enter the link by clicking on the button "add link". When I add link, the windows browser opens and i can search for exact document. But when I save the path in the Link text box, the link doent work. It is stored in News table and I changed it for hyperlink but still doesnt work. I noticed that when I am saving the path, it saves me the path as a link name that is shown in the text box, but the hyperlink path is empty.
How to make it works?
I would be grateful for help.


Greets

Greg

[ADezii]

Hello,

I have a problem with hyperlink.
I have a text box that contains link to the document. I enter the link by clicking on the button "add link". When I add link, the windows browser opens and i can search for exact document. But when I save the path in the Link text box, the link doent work. It is stored in News table and I changed it for hyperlink but still doesnt work. I noticed that when I am saving the path, it saves me the path as a link name that is shown in the text box, but the hyperlink path is empty.
How to make it works?
I would be grateful for help.


Greets

Greg

You cannot Add a Hyperlink to a Text Box on a Form, when you attempt this a Label containing the Hyperlink will be added to the Form, and clicking on it will Navigate to the Destination. It obviously will not be Bound or saved to a Table. If a Field in a Table is defined as Hyperlink and Links are added at the Table Level, you can then set the Control Source of a Text Box to this Field and you can activate the Hyperlink in this manner. You can also programmatically add a Hyperlink to a Text Box on a Form and Bind it to the underlying Field.

[dillneus]

You cannot Add a Hyperlink to a Text Box on a Form, when you attempt this a Label containing the Hyperlink will be added to the Form, and clicking on it will Navigate to the Destination. It obviously will not be Bound or saved to a Table. If a Field in a Table is defined as Hyperlink and Links are added at the Table Level, you can then set the Control Source of a Text Box to this Field and you can activate the Hyperlink in this manner. You can also programmatically add a Hyperlink to a Text Box on a Form and Bind it to the underlying Field.

thank you for reply. but i think i wasnt too clear.
actually i can store this hyperlink to the table field but then i cannot open hyperlink.

Maybe i will describe it more detailed:

i have News Table where there is a News.Link field (it is set as hyperlink).

then I have News Form where I have text box - Link - which has control soucre News.Link from the News Table.

Under that Link I have button which opens browser and then in the folders on the hard drive I can choose one document. I press save and the whole path is saved on this text box Link, which is bound to News.Link.

But this paths doesnt open a hyperlink, although I set hyperlink options in Form and in Table.

Now I want to be able to open document just by clicking on that text box field in Form. Now I am clicking and nothing happens.

Do you know how to do it?

[ADezii]

thank you for reply. but i think i wasnt too clear.
actually i can store this hyperlink to the table field but then i cannot open hyperlink.

Maybe i will describe it more detailed:

i have News Table where there is a News.Link field (it is set as hyperlink).

then I have News Form where I have text box - Link - which has control soucre News.Link from the News Table.

Under that Link I have button which opens browser and then in the folders on the hard drive I can choose one document. I press save and the whole path is saved on this text box Link, which is bound to News.Link.

But this paths doesnt open a hyperlink, although I set hyperlink options in Form and in Table.

Now I want to be able to open document just by clicking on that text box field in Form. Now I am clicking and nothing happens.

Do you know how to do it?

I answered a similar Question several weeks ago, referring to this Post should help you. The key point to remember is that a Hyperlink can consist of three Sections delimited by a '#' sign. Specifying only the URL will not work, it will simply be assigned to the Caption.
Inserting a Hyperlink into a Table

[dillneus]

I answered a similar Question several weeks ago, referring to this Post should help you. The key point to remember is that a Hyperlink can consist of three Sections delimited by a '#' sign. Specifying only the URL will not work, it will simply be assigned to the Caption.
Inserting a Hyperlink into a Table

Thx for link. It sounds like the answer for my question. but i dont know how to put it to my database. I quite begginer so some things i dont understand.

So:
What is this File Dialog: msoFileDialogFilePicker, msoFileDialogViewDetails
Is it module or sth like that?
I have to modules: openSavebrowser and basBrowseFiles for opening the browser and inserting the file path into the text box (but it put only the path in the text display part, not in path part).
Maybe I have wrong module (FileDialogFilePicer??). Do you have maybe codes for that FilesDialogs that are mentioned in the code from that link?

Where shall I insert that code that was in that link you gave me? I have button that is named link2. shall i put in into onclick option in Event Procedures?

greets

[ADezii]

Thx for link. It sounds like the answer for my question. but i dont know how to put it to my database. I quite begginer so some things i dont understand.

So:
What is this File Dialog: msoFileDialogFilePicker, msoFileDialogViewDetails
Is it module or sth like that?
I have to modules: openSavebrowser and basBrowseFiles for opening the browser and inserting the file path into the text box (but it put only the path in the text display part, not in path part).
Maybe I have wrong module (FileDialogFilePicer??). Do you have maybe codes for that FilesDialogs that are mentioned in the code from that link?

Where shall I insert that code that was in that link you gave me? I have button that is named link2. shall i put in into onclick option in Event Procedures?

greets

The Link that I provided for you also shows sample FileDialog code.

[dillneus]

The Link that I provided for you also shows sample FileDialog code.

I saw that code but i dont know exactly how to change it...
msoFileDialogFilePicker, msoFileDialogViewDetails - i dont know my equivalent of thos fields...
are there modules codes or sth else???...
I will follow that sample you gave on my example, and if you could check if this is correct i would be greatful:

What is the Field Name? Link

Is this Field defined as a Hyperlink Data Type in the Table? YES

What is the Table's Name? NEWS

What URL are you trying to Update the Field to? (Microsoft.com, Google.com, TheScripts.com, etc.)
I have text box: Link which is bound to [News].[Link] field.


Now what i need is to be able to add paths of files into Link field as a hyperlink path.

So where should i put this code:

Dim varItem As Variant
 
With Application.FileDialog(msoFileDialogFilePicker) what should i put into msoFileDialogPicker?? 
 
With .Filters
     .Clear
     .Add "Text Files", "*.txt"
     .Add "Database Files", "*.mdb"
     .Add "All Files", "*.*"
   End With
       'The Show Method returns True if 1 or more files are selected
       .AllowMultiSelect = True
       .FilterIndex = 2     'Database files
       .ButtonName = "Link2"
       .InitialFileName = vbNullString
       .InitialView = msoFileDialogViewDetails' (and what is that FiledDialogViewDetails?? )
 
       .Title = "Find the damn File!"
          If .Show Then
            For Each varItem In .SelectedItems     'There will only be 1
              Me![Link] = varItem
            Next varItem
          End If
End With

I am quite lost with that and i dont know how to proceed further...

greets
Greg

[ADezii]

I saw that code but i dont know exactly how to change it...
msoFileDialogFilePicker, msoFileDialogViewDetails - i dont know my equivalent of thos fields...
are there modules codes or sth else???...
I will follow that sample you gave on my example, and if you could check if this is correct i would be greatful:

What is the Field Name? Link

Is this Field defined as a Hyperlink Data Type in the Table? YES

What is the Table's Name? NEWS

What URL are you trying to Update the Field to? (Microsoft.com, Google.com, TheScripts.com, etc.)
I have text box: Link which is bound to [News].[Link] field.


Now what i need is to be able to add paths of files into Link field as a hyperlink path.

So where should i put this code:

Dim varItem As Variant
 
With Application.FileDialog(msoFileDialogFilePicker) what should i put into msoFileDialogPicker?? 
 
With .Filters
     .Clear
     .Add "Text Files", "*.txt"
     .Add "Database Files", "*.mdb"
     .Add "All Files", "*.*"
   End With
       'The Show Method returns True if 1 or more files are selected
       .AllowMultiSelect = True
       .FilterIndex = 2     'Database files
       .ButtonName = "Link2"
       .InitialFileName = vbNullString
       .InitialView = msoFileDialogViewDetails '(and what is that FiledDialogViewDetails?? )
 
       .Title = "Find the damn File!"
          If .Show Then
            For Each varItem In .SelectedItems     'There will only be 1
              Me![Link] = varItem
            Next varItem
          End If
End With

I am quite lost with that and i dont know how to proceed further...

greets
Greg

Don't have the time right now but I'll give you step-by-step detailed information as soon as I get the chance, hopefully tonight.

[dillneus]

Don't have the time right now but I'll give you step-by-step detailed information as soon as I get the chance, hopefully tonight.

ok no problem. i will check it tommorow then. thx

[ADezii]

ok no problem. i will check it tommorow then. thx

The following code, placed in the Click() Event of a Command Button named cmdPopulateHyperlink will:

1. Open a File Dialog Box, and allow you to select only 1 File of any type.
2. Allow you to customize the Button and Dialog Title Captions within the File Dialog Box.
3. Write the Hyperlink Caption and Address (both are required) to the Link Text Box on the Current Form. The Control Source for this Link Text Box is the [Link] Field.
4. The Record Source for the Form is the Table News.
5. The code has been thoroughly tested and is fully functional. I inserted Comments where I thought they may be needed.
6. Any questions, feel free to ask.

Private Sub cmdPopulateHyperlink_Click()
'First, set a Reference to the Microsoft Office XX.X Object Library
 
Dim strButtonCaption As String, strDialogTitle As String
Dim strHyperlinkFile As String
 
'Define your own Captions if necessary
strButtonCaption = "Save Hyperlink"
strDialogTitle = "Select File to Create Hyperlink to"
 
With Application.FileDialog(msoFileDialogFilePicker)
  With .Filters
    .Clear
    .Add "All Files", "*.*"     'Allow ALL File types
  End With
  'The Show Method returns True if 1 or more files are selected
    .AllowMultiSelect = False       'Critical Line
    .FilterIndex = 1 'Database files
    .ButtonName = strButtonCaption
    .InitialFileName = vbNullString
    .InitialView = msoFileDialogViewDetails     'Detailed View
    .Title = strDialogTitle
  If .Show Then
    For Each varItem In .SelectedItems 'There will only be 1
      'Caption and Address of Hyperlink will be the same (Caption#Address)
      strHyperlinkFile = varItem & "#" & varItem
        Me![Link] = strHyperlinkFile
    Next varItem
  End If
End With
End Sub
 

[dillneus]

The following code, placed in the Click() Event of a Command Button named cmdPopulateHyperlink will:

1. Open a File Dialog Box, and allow you to select only 1 File of any type.
2. Allow you to customize the Button and Dialog Title Captions within the File Dialog Box.
3. Write the Hyperlink Caption and Address (both are required) to the Link Text Box on the Current Form. The Control Source for this Link Text Box is the [Link] Field.
4. The Record Source for the Form is the Table News.
5. The code has been thoroughly tested and is fully functional. I inserted Comments where I thought they may be needed.
6. Any questions, feel free to ask.

Private Sub cmdPopulateHyperlink_Click()
'First, set a Reference to the Microsoft Office XX.X Object Library
 
Dim strButtonCaption As String, strDialogTitle As String
Dim strHyperlinkFile As String
 
'Define your own Captions if necessary
strButtonCaption = "Save Hyperlink"
strDialogTitle = "Select File to Create Hyperlink to"
 
With Application.FileDialog(msoFileDialogFilePicker)
  With .Filters
    .Clear
    .Add "All Files", "*.*"     'Allow ALL File types
  End With
  'The Show Method returns True if 1 or more files are selected
    .AllowMultiSelect = False       'Critical Line
    .FilterIndex = 1 'Database files
    .ButtonName = strButtonCaption
    .InitialFileName = vbNullString
    .InitialView = msoFileDialogViewDetails     'Detailed View
    .Title = strDialogTitle
  If .Show Then
    For Each varItem In .SelectedItems 'There will only be 1
      'Caption and Address of Hyperlink will be the same (Caption#Address)
      strHyperlinkFile = varItem & "#" & varItem
        Me![Link] = strHyperlinkFile
    Next varItem
  End If
End With
End Sub
 

Thank you very much for help. Now it is more clear for me how it works.
However i have a problem while clicking the button:
Compile error: Method or data member not found.

I pasted that code in VB in On click option. My button name is cmdPopulateHyperlink. And the other decribed option are the same. So i dont know what to do to work it out.
I also put references for Microsoft Office 12.0 Object Library
I dont know if its tell you sth but all the time i click button it shows me that error and then in the line : With Application.FileDialog(msoFileDialogFilePicker), the work FileDialog is selected (not in yellow like in the beggining but in blue, like selecting for copying). I know that maybe its sth simple and i have really stupid remark, but as i said in the beggining, this is my beggining with VB...

greets
Greg

[ADezii]

Thank you very much for help. Now it is more clear for me how it works.
However i have a problem while clicking the button:
Compile error: Method or data member not found.

I pasted that code in VB in On click option. My button name is cmdPopulateHyperlink. And the other decribed option are the same. So i dont know what to do to work it out.
I also put references for Microsoft Office 12.0 Object Library
I dont know if its tell you sth but all the time i click button it shows me that error and then in the line : With Application.FileDialog(msoFileDialogFilePicker), the work FileDialog is selected (not in yellow like in the beggining but in blue, like selecting for copying). I know that maybe its sth simple and i have really stupid remark, but as i said in the beggining, this is my beggining with VB...

greets
Greg

Just for verification, what Version of Access are you using?

[dillneus]

Just for verification, what Version of Access are you using?

I am using: MS Access 2000

[dillneus]

I am using: MS Access 2000

If it helps, before i was using module code for file browser like this (but it saved me only display text, not hyperlink):

'.=========================================================================
'.Browse Files Module
'.Copyright 1999 Tribble Software.  All rights reserved.
'.Phone        : [phone]
'.E-mail       : [e-mail]
'.=========================================================================
' DO NOT DELETE THE COMMENTS ABOVE.  All other comments in this module
' may be deleted from production code, but lines above must remain.
'--------------------------------------------------------------------------
'.Description  : This module calls directly into comdlg32.dll to allow user
'.               to select a filename using the Windows Common Dialog.  The
'.               user may browse for a file, or enter a file name directly.
'.Written By   : Carl Tribble
'.Date Created : 04/05/1999 09:56:31 AM
'.Rev. History :
' Comments     : Normally, to use the Common Dialog you need to physically
'                place the ActiveX control onto a form and then use code
'                behind the form to implement its functionality.  This
'                module allows you to incorporate the functionality of the
'                File Open/Save part of the Common Dialog without the
'                ActiveX control itself. This module is completely self-
'                contained.  Simply copy it into your database to use it.
'.-------------------------------------------------------------------------
'.
' ADDITIONAL NOTES:
'
'  This module only provides the Open/Save file dialog, not the other
'  CommonDialog interfaces (ColorChooser, Help, PrintDialog, etc.)
'
'  If you want your user to browse for folder names (paths) you must use
'  the module basBrowseFolders instead.
'
'  TO STREAMLINE this module for production programs, you should remove:
'     1) Unnecessary comments
'     2) Flag Constants which you do not intend to use.
'     3) The test procedure tsGetFileFromUserTest
'
'--------------------------------------------------------------------------
'
' INSTRUCTIONS:
'
'         ( For a working example, open the Debug window  )
'         ( and enter tsGetFileFromUserTest.              )
'
'.All the arguments for the function are optional.  You may call it with no
'.arguments whatsoever and simply assign its return value to a variable of
'.the Variant type.  For example:
'.
'.   varFileName = tsGetFileFromUser()
'.
'.The function will return:
'.   the full path and filename selected or entered by the user, or
'.   Null if an error occurs or if the user presses Cancel.
'.
'.Optional arguments may include any of the following:
'. rlngFlags      : one or more of the tscFN* constants (declared below)
'.                  Combine multiple constants like this:
'.                   tscFNHideReadOnly Or tscFNFileMustExist
'. strInitialDir : the directory to display when dialog opens
'. strFilter     : a string containing any filters you want to use. Each
'.                 part must be separated by the vbNullChar. -example below
'. lngFilterIndex: a 1-based index indicating which filter to start with.
'. strDefaultExt : Extension to use if user does not enter one.
'. strFileName   : Default File to display in the File Name text box.
'. strDialogTitle: Caption to display in the dialog's title bar.
'. fOpenFile     : Boolean-True for the Open dialog, False for Save dialog.
'
' FILTER EXAMPLE: The filter must be a string containing two parts for each
'  filter.  The first part is the Description, it is what the user will see
'  in the Files of Type box, e.g. "Text Files (*.txt)".  The second part is
'  the actual filter, e.g. "*.txt".  Each part and each filter must be
'  separated by the vbNullChar.  For example, to provide two filters, one for
'  *.mdb files, and one for all files, use a statement like this:
'
'  strFilter = "Access (*.mdb)" & vbNullChar & "*.mdb" _
'   & vbNullChar & "All Files (*.*)" & vbNullChar & "*.*"
'
'  Then pass your strFilter variable as the strFilter argument for the call
'  to tsGetFileFromUser()
'
'.--------------------------------------------------------------------------
'.
 
Private Declare Function ts_apiGetOpenFileName Lib "comdlg32.dll" _
 Alias "GetOpenFileNameA" (tsFN As tsFileName) As Boolean
 
Private Declare Function ts_apiGetSaveFileName Lib "comdlg32.dll" _
 Alias "GetSaveFileNameA" (tsFN As tsFileName) As Boolean
 
Private Declare Function CommDlgExtendedError Lib "comdlg32.dll" () As Long
 
Private Type tsFileName
   lStructSize As Long
   hwndOwner As Long
   hInstance As Long
   strFilter As String
   strCustomFilter As String
   nMaxCustFilter As Long
   nFilterIndex As Long
   strFile As String
   nMaxFile As Long
   strFileTitle As String
   nMaxFileTitle As Long
   strInitialDir As String
   strTitle As String
   Flags As Long
   nFileOffset As Integer
   nFileExtension As Integer
   strDefExt As String
   lCustData As Long
   lpfnHook As Long
   lpTemplateName As String
End Type
 
' Flag Constants
Public Const tscFNAllowMultiSelect = &H200
Public Const tscFNCreatePrompt = &H2000
Public Const tscFNExplorer = &H80000
Public Const tscFNExtensionDifferent = &H400
Public Const tscFNFileMustExist = &H1000
Public Const tscFNPathMustExist = &H800
Public Const tscFNNoValidate = &H100
Public Const tscFNHelpButton = &H10
Public Const tscFNHideReadOnly = &H4
Public Const tscFNLongNames = &H200000
Public Const tscFNNoLongNames = &H40000
Public Const tscFNNoChangeDir = &H8
Public Const tscFNReadOnly = &H1
Public Const tscFNOverwritePrompt = &H2
Public Const tscFNShareAware = &H4000
Public Const tscFNNoReadOnlyReturn = &H8000
Public Const tscFNNoDereferenceLinks = &H100000
 
Public Function tsGetFileFromUser( _
 Optional ByRef rlngflags As Long = 0&, _
 Optional ByVal strInitialDir As String = "", _
 Optional ByVal strFilter As String = "All Files (*.*)" & vbNullChar & "*.*", _
 Optional ByVal lngFilterIndex As Long = 1, _
 Optional ByVal strDefaultExt As String = "", _
 Optional ByVal strFileName As String = "", _
 Optional ByVal strDialogTitle As String = "", _
 Optional ByVal fOpenFile As Boolean = True) As Variant
 
   On Error GoTo tsGetFileFromUser_Err
   Dim tsFN As tsFileName
   Dim strFileTitle As String
   Dim fResult As Boolean
 
   ' Allocate string space for the returned strings.
   strFileName = Left(strFileName & String(256, 0), 256)
   strFileTitle = String(256, 0)
 
   ' Set up the data structure before you call the function
   With tsFN
      .lStructSize = Len(tsFN)
      .hwndOwner = Application.hWndAccessApp
      .strFilter = strFilter
      .nFilterIndex = lngFilterIndex
      .strFile = strFileName
      .nMaxFile = Len(strFileName)
      .strFileTitle = strFileTitle
      .nMaxFileTitle = Len(strFileTitle)
      .strTitle = strDialogTitle
      .Flags = rlngflags
      .strDefExt = strDefaultExt
      .strInitialDir = strInitialDir
      .hInstance = 0
      .strCustomFilter = String(255, 0)
      .nMaxCustFilter = 255
      .lpfnHook = 0
   End With
 
   ' Call the function in the windows API
   If fOpenFile Then
      fResult = ts_apiGetOpenFileName(tsFN)
   Else
      fResult = ts_apiGetSaveFileName(tsFN)
   End If
 
   ' If the function call was successful, return the FileName chosen
   ' by the user.  Otherwise return null.  Note, the CancelError property
   ' used by the ActiveX Common Dialog control is not needed.  If the
   ' user presses Cancel, this function will return Null.
   If fResult Then
      rlngflags = tsFN.Flags
      tsGetFileFromUser = tsTrimNull(tsFN.strFile)
   Else
      tsGetFileFromUser = Null
   End If
 
tsGetFileFromUser_End:
   On Error GoTo 0
   Exit Function
 
tsGetFileFromUser_Err:
   Beep
   MsgBox Err.Description, , "Error: " & Err.Number _
    & " in function basBrowseFiles.tsGetFileFromUser"
   Resume tsGetFileFromUser_End
 
End Function
 
' Trim Nulls from a string returned by an API call.
 
Private Function tsTrimNull(ByVal strItem As String) As String
 
   On Error GoTo tsTrimNull_Err
   Dim I As Integer
 
   I = InStr(strItem, vbNullChar)
   If I > 0 Then
       tsTrimNull = Left(strItem, I - 1)
   Else
       tsTrimNull = strItem
   End If
 
tsTrimNull_End:
   On Error GoTo 0
   Exit Function
 
tsTrimNull_Err:
   Beep
   MsgBox Err.Description, , "Error: " & Err.Number _
    & " in function basBrowseFiles.tsTrimNull"
   Resume tsTrimNull_End
 
End Function

[dillneus]

Everything is ok now.
Inspired by your code, i have simply copied "#" & into following line:

Me![Link] = "#" & varFileName

and now its working :)

it was so easy solution that now i am embaressed by posting that question :)

Thx very much for help and inspiration :)


Greg

[ADezii]

Everything is ok now.
Inspired by your code, i have simply copied "#" & into following line:

Me![Link] = "#" & varFileName

and now its working :)

it was so easy solution that now i am embaressed by posting that question :)

Thx very much for help and inspiration :)


Greg

You are quite welcome. Many Users are confused when it comes to programmatically adding Hyperlinks to a Form Field Bound to a HyperLink Data Type. As a matter of fact, this will probably be the Subject of the next Tip of the Week.