Lock Form Question Access

[Peader]

Hi,

A quick question here on how to prevent my mouse scroll wheel from being able to track through all previously saved records in my table. Any idea's?

Peader

[missinglinq]

If you're running Access 2007, you already have a function that addresses this issue! Just check with Help.

For all other versions, you'll need some outside help. A gentleman by the name of Stephen Lebans has a sample database that does this and can be downloaded at:

http://www.lebans.com/mousewheelonoff.htm

First, download and unzip the db and take a look. Go into your db and goto File > External Data > Import and import the module modMouseHook from the sample database. Next make sure you have the included file, MouseHook.dll, in the same folder your database resides in. The following code needs to run before the mousewheel will be locked:

Private Sub Form_Load()
 ' Turn off Mouse Scroll
 blRet = MouseWheelOFF
   End Sub

If you have one form that always loads first in your db, place the code there. If the first form to load varies, place the same code in each form. You should now be set!

Linq ;0)>

[Rabbit]

I developed this method recently so I didn't have to use Leban's dll.
It's definitely more work to incorporate than his dll.
It's a more hardcore approach in that it locks all methods of navigating records except for custom buttons. This means the default navigation buttons don't work. The mousewheel doesn't work. Tabbing through to the next record doesn't work. Although I suppose the code could be modified to allow tabbing to work.

Edit: Now that I think about it, it's probably possible to lock only the mousewheel using a similar concept.

Option Compare Database
Option Explicit
Dim BkMk As Variant
Dim AllowMove As Boolean
Dim IsNewRec As Boolean
 
Private Sub but_MoveNext_Click()
On Error GoTo Err_but_MoveNext_Click
 
    AllowMove = True
    DoCmd.GoToRecord , , acNext
    BkMk = Me.Bookmark
    IsNewRec = False
 
Exit_but_MoveNext_Click:
    AllowMove = False
    Exit Sub
 
Err_but_MoveNext_Click:
    If Err.Number = 3021 Then
        IsNewRec = True
    Else
        If Err.Number <> 2105 Then MsgBox Err.Number & ": " & Err.Description
    End If
    Resume Exit_but_MoveNext_Click
 
End Sub
 
Private Sub Form_Current()
    If Not AllowMove Then
        If IsNewRec Then
            DoCmd.GoToRecord , , acNewRec
        Else
            Me.Bookmark = BkMk
        End If
    End If
End Sub
 
Private Sub Form_Load()
    BkMk = Me.Bookmark
    AllowMove = False
    IsNewRec = False
End Sub
 
Private Sub but_MovePrior_Click()
On Error GoTo Err_but_MovePrior_Click
 
    AllowMove = True
    DoCmd.GoToRecord , , acPrevious
    BkMk = Me.Bookmark
    IsNewRec = False
 
Exit_but_MovePrior_Click:
    AllowMove = False
    Exit Sub
 
Err_but_MovePrior_Click:
    If Err.Number <> 2105 Then MsgBox Err.Number & ": " & Err.Description
    Resume Exit_but_MovePrior_Click
 
End Sub
 
Private Sub but_AddNew_Click()
On Error GoTo Err_but_AddNew_Click
 
    AllowMove = True
    DoCmd.GoToRecord , , acNewRec
    IsNewRec = True
 
Exit_but_AddNew_Click:
    AllowMove = False
    Exit Sub
 
Err_but_AddNew_Click:
    If Err.Number <> 2105 Then MsgBox Err.Number & ": " & Err.Description
    Resume Exit_but_AddNew_Click
 
End Sub
 

[Peader]

Thanks Lads,

Problem solved. I used Lebans method.

Peader

[missinglinq]

Glad we could help!

Linq ;0)>

[Tazmanian Devil]

Hi all,

Just tried the Lebans one and it doesn't work for me...don't know what I'm doing wrong. Unless using the scroller on my laptop's trackpad isn't covered by the code??

I put the .dll in the same folder as the sample db (desktop)

Any advice..?

Thanks
Taz

[missinglinq]

Never seen a scroller on a trackpad, but the most common mistake people make is forgetting to import the module modMouseHook from the sample database into their own database.

Welcome to TheScripts!

Linq ;0)>