One checkbox fills other checkboxes

[martin DH]

I've seen similar posts to what I am looking for but have not been able to successfully use what I have read.
I have a form with 4 checkboxes:

CkQ1
CkJan
CkFeb
CkMar

I would like to be able to select CkQ1, and in doing so, Access would select the other three checkboxes (sort of an "all of the above" option). These checkboxes are not in an option group because multiple boxes could be selected (eg a user might only select CkJan and CkFeb). I am using Access 2003 on XP. I have attached a snapshot of the form in case that helps.

Is this sort of checkbox "filling" possible, especially for a user with limited vba knowledge (me). Thanks for any help!
martin

[lee123]

you coulkd do an if statement like this

if ckq1 = true then
   ckjan=true
   ckfeb=true
   ckmar= true
else
   ckq1=false
end if

lee123

[martin DH]

Thanks, I was sure it could be done simply through an If statement. Now some follow-up questions:

I altered the code using ElseIf statements to uncheck the three month checkboxes when the CkQ1 was unchecked. My code now looks like:

Private Sub CkQ1_Click()
If CkQ1 = True Then
   CkJan = True
   CkFeb = True
   CkMar = True
ElseIf CkQ1 = False Then
   CkJan = False
   CkFeb = False
   CkMar = False
End If
End Sub

Question: After checking CkQ1, the other three checkboxes check. Now if I uncheck some of those other three boxes (eg I uncheck CkJan), I would like the CkQ1 to uncheck as well. I think that this is getting a little more complicated - but maybe only to me! Thank you for your help.

martin

[NeoPa]

Let's clarify a little.
What do you want CkQ1 to be if chkJan is set but the others are cleared?

BTW To replace what you currently have try :

Private Sub CkQ1_AfterUpdate()
  With Me
    .CkJan = .CkQ1
    .CkFeb = .CkQ1
    .CkMar = .CkQ1
  End With
End Sub

[martin DH]

Let's clarify a little.
What do you want CkQ1 to be if chkJan is set but the others are cleared?

Clarification is good. CkQ1 should ONLY be set if the user sets it specifically (another option if possible and not too difficult: CkQ1 could also be set if the three month checkboxes are all also set...).

If CkJan is set but the other two month checkboxes are cleared, CkQ1 should also be cleared.
Hope that helps!

Also, as I novice I don't know these things, why is the code you supplied a better choice than what I posted above. Thanks!

martin

[NeoPa]

Thanks for the clarification.
I would say that code of the form :

B = A

is better (more succinct & readable) than :

If A = True Then
  B = True
Else
  B = False
EndIf

The Me. stuff (With Me etc) is just making the code more explicit. It is usually used when referring to controls on a form even though it's not, strictly speaking, necessary.

[martin DH]

Thanks NeoPa, that makes perfect sense. KISS methodology is great.

Do you know how I can clear CkQ1 if any of the three subsequent checkboxes are cleared (eg if all three month checkboxes are set but then CkJan is cleared, CkQ1 should also clear). Thank you!

Martin

[NeoPa]

Sure Martin.
Try something like :

Private Sub CkQ1_AfterUpdate()
  With Me
    .CkJan = .CkQ1
    .CkFeb = .CkQ1
    .CkMar = .CkQ1
  End With
End Sub
 
Private Sub CkJan_AfterUpdate()
  Call UpdateCkQ1()
End Sub
 
Private Sub CkFeb_AfterUpdate()
  Call UpdateCkQ1()
End Sub
 
Private Sub CkMar_AfterUpdate()
  Call UpdateCkQ1()
End Sub
 
Private Sub UpdateCkQ1()
  With Me
    .CkQ1 = (.CkJan And .CkFeb And .CkMar)
  End With
End Sub

This may not be exactly what you want as it also sets .CkQ1 if they are all individually set.

[martin DH]

NeoPa,
Thank you very much. That is actually exactly what I was looking for. I appreciate your guidance!
martin

[NeoPa]

No problem Martin :)
Glad you liked it.