MS Access Mouse Over Event

[nihassanali]

Can anyone assist me with creating a mouse over event for objects on an Access form? I am trying to create customized tooltips for users of a database application I created. I am using MSAccess 2000.

[missinglinq]

Using the MouseMove event (which is commonly referred to as Mouse Over) basically consists of two parts, setting up the action to be taken if the cursor travels across an object, such as a label or text box, and re-setting that action to the neutral state, if you will.

The following example changes the text color to red on a label (MyLabel) when the cursor passes over it, then changes the text color back to black when the cursor leaves the label.

Private Sub MyLabel_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
MyLabel.ForeColor = vbRed 'Sets the text color to Red on MouseMove over label
End Sub

Private Sub Detail_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
MyLabel.ForeColor = vbBlack 'Sets the text color back to Black on MouseMove over Detail Section of Form
End Sub

The action would be repeated for each individual object's MouseMove event, with the re-setting statement added to the shared Detail_MouseMove sub.

This is basically how it is done. You can substitute whatever events you want to occur in place of the above text color changing. One idea would be to have a label (ToolTipLabel) on your form and to change the caption depending on which object the cursor was on. Set the alignment property for the label to "Centered" so that the text will always look balanced.
Assuming the object we're dealing with is a label named MyLabel:

Private Sub MyLabel_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
ToolTipLabel.Caption = "This is a tool Tip" 'Place your tool tip here
End Sub

Private Sub Detail_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
ToolTipLabel.Caption = "" 'Replace the tool tip with a blank string here
End Sub

As I said, these are just two examples of what you can do with MouseMove. Have at it!

[MMcCarthy]

Can anyone assist me with creating a mouse over event for objects on an Access form? I am trying to create customized tooltips for users of a database application I created. I am using MSAccess 2000.

What help exactly do you need?

1. Do you know where to put a mouse over event?
2. Do you know how you want to display the tooltips?
3. Do you want to know what code to use to do it?

[NeoPa]

Excellent answer (Not your's THIS time Mary).

[MMcCarthy]

Excellent answer (Not your's THIS time Mary).

Yes I've been noticing Missinglinq

Not that many posts so far but what there is, is good and to the point.

Keep it up Missinglinq and welcome to the forum.

Mary

[Jhon Doen]

I have been using a Public function for a while that covers mouse over effects for just about everything you can put on a form.

I am attaching the code here, you can also find my article on how to do this on EE. Here:
** Edit ** <Snip>

Here is my new code for MOE in Access:

Put this at the very top of your VB editor for your form.

Private Function Hover(Optional pstrName As String)
 
    Static sstrHover As String
 
    If sstrHover = pstrName Then Exit Function
    If Len(sstrHover) Then
        ' remove hover effect
        With Me(sstrHover)
            Select Case .ControlType
            Case acTextBox
                .ForeColor = vbBlack
                .FontSize = 11
                .FontBold = True
                If .Controls.Count Then .Controls(0).ForeColor = vbBlack
            Case acRectangle
                .BorderColor = vbBlack
            Case acLabel
                .ForeColor = vbBlack
                .FontSize = 11
                'If .Controls.Count Then .Controls(0).ForeColor = vbBlack
            Case acCommandButton
                .ForeColor = vbBlack
                .FontSize = 11
                .FontBold = True
            End Select
        End With
    End If
    sstrHover = pstrName
    If Len(sstrHover) Then
        ' set hover effect, change font color
        With Me(sstrHover)
            Select Case .ControlType
            Case acTextBox
                .ForeColor = vbRed
                .FontSize = 14
                If .Controls.Count Then .Controls(0).ForeColor = vbRed
            Case acRectangle
                .BorderColor = vbRed
            Case acLabel
                .FontSize = 14
                .ForeColor = vbRed
                'If .Controls.Count Then .Controls(0).ForeColor = vbRed
            Case acCommandButton
                .ForeColor = vbRed
                .FontSize = 14
            End Select
        End With
    End If
 
End Function

Then to get your control to show the effects use this code:

Private Sub myControl_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
Hover myControl.Name
End Sub

Works like a charm.

Have fun.

TLH

[NeoPa]

Thanks for posting TLH. As a newbie to the forum you may not yet be aware of our rules so I've had to edit your post to comply.

Welcome to Bytes!