How to unzip and extract file in vb.net

[progvar]

Hi,
i want to know how to unzip a zip file and extract the files to a particular location

please help me

thanks in advance
varinder

[Curtis Rutland]

OK, this isn't my code, I found it as an example, so I haven't tested it.

It uses a 3rd party library called SharpZipLib. You will need to download it. It can be registered as an assembly.

Here's some code:

    Public Sub ExtractArchive(ByVal zipFilename As String, ByVal ExtractDir As String)
        Dim Redo As Integer = 1
        Dim MyZipInputStream As ZipInputStream
        Dim MyFileStream As FileStream
        MyZipInputStream = New ZipInputStream(New FileStream(zipFilename, FileMode.Open, FileAccess.Read))
        Dim MyZipEntry As ZipEntry = MyZipInputStream.GetNextEntry
        Directory.CreateDirectory(ExtractDir)
        While Not MyZipEntry Is Nothing
            If (MyZipEntry.IsDirectory) Then
                Directory.CreateDirectory(ExtractDir & "\" & MyZipEntry.Name)
            Else
                If Not Directory.Exists(ExtractDir & "\" & _
                Path.GetDirectoryName(MyZipEntry.Name)) Then
                    Directory.CreateDirectory(ExtractDir & "\" & _
                    Path.GetDirectoryName(MyZipEntry.Name))
                End If
                MyFileStream = New FileStream(ExtractDir & "\" & _
                  MyZipEntry.Name, FileMode.OpenOrCreate, FileAccess.Write)
                Dim count As Integer
                Dim buffer(4096) As Byte
                count = MyZipInputStream.Read(buffer, 0, 4096)
                While count > 0
                    MyFileStream.Write(buffer, 0, count)
                    count = MyZipInputStream.Read(buffer, 0, 4096)
                End While
                MyFileStream.Close()
            End If
            Try
                MyZipEntry = MyZipInputStream.GetNextEntry
            Catch ex As Exception
                MyZipEntry = Nothing
            End Try
        End While
        If Not (MyZipInputStream Is Nothing) Then MyZipInputStream.Close()
        If Not (MyFileStream Is Nothing) Then MyFileStream.Close()
    End Sub

[raids51]

you can also set a reference to VJSLIB, it has built in classes for zipping and unzipping files

[Manage2]

under XP you can use shell32 directly without 3rd Party software

you have to add the COM reference "Microsoft Shell Controls And Automation" into your Project

see following (handy) sample code:

Imports System.IO
Imports Shell32
 
---
 
Private Sub Button303_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button303.Click
 
        ' Unzip Variables
        Dim UserShell As Shell32.IShellDispatch2
        Dim ZipContent As Shell32.FolderItems
        Dim ExportLocation As Shell32.Folder
 
        ' -----------------------------------------------
        ' Unzip File  -> only XP ?!
        ' -----------------------------------------------
 
        If File.Exists("c:\temp\zipfile.zip") = False Then
            ' error mesage
        End If
 
        UserShell = CType(CreateObject("Shell.Application"), IShellDispatch2)
 
        ' if you like, you can get some properties of your content
        ' for ex. filenames?
 
        ZipContent = UserShell.NameSpace(("c:\temp\zipfile.zip")).Items
        Dim i As Integer
        Dim Filename As String
        For i = 0 To ZipContent.Count - 1
            Filename = ZipContent.Item(i).Name.ToString
        Next
 
        ' unpack the thing 
        ExportLocation = UserShell.NameSpace(("c:\temp\"))
        If ExportLocation IsNot Nothing Then
            ExportLocation.CopyHere(UserShell.NameSpace(("c:\temp\zipfile.zip")).Items)
        End If
    End Sub
 

this is it...

[Cheeso]

Here's some example code:

  Dim ZipToUnpack As String = "C1P3SML.zip"  
   Dim TargetDir As String = "C1P3SML"  
   Console.WriteLine("Extracting file {0} to {1}", ZipToUnpack, TargetDir)   
   Using zip1 As ZipFile = ZipFile.Read(ZipToUnpack)   
       AddHandler zip1.ExtractProgress, AddressOf MyExtractProgress   
       Dim e As ZipEntry   
       ' here, we extract every entry, but we could extract    
       ' based on entry name, size, date, etc.   
       For Each e In zip1   
           e.Extract(TargetDir, ExtractExistingFileAction.OverwriteSilently)   
       Next  
   End Using  
 

There are some nice options... Progress Events, ZIP passwords, renaming entries in Zip files, ZIP64, AES encryption, lots more. There's a good help file and forums, too.

Many more examples at: http://dotnetzip.codeplex.com/Wiki/V...le=VB-examples

Download DotNetZip at http://dotnetzip.codeplex.com
Free.

[Thorf]

Cheeso,
Your example works with .rar files too ???